afimp2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    afimp2                 ../engine/source/ale/ale2d/afimp2.F
!||--- called by ------------------------------------------------------
!||    atherm                 ../engine/source/ale/atherm.F
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.F
!||====================================================================
      SUBROUTINE afimp2(
     1                  PM  ,X           ,IXQ  ,T  ,GRAD  ,
     2                  COEF,ALE_CONNECT ,FV)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE ale_connectivity_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "vect01_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
! SPMD CASE : SIXQ >= NIXQ*NUMELQ    (SIXQ = NIXQ*NUMELQ_L+NIXQ*NQVOIS_L)
! IXQ(1:NIXQ, 1:NUMELQ) local elems
!    (1:nixq, numelq+1:) additional elems(also on adjacent domains but connected to the boundary of the current domain)
!
! SPMD CASE : SX >= 3*NUMNOD    (SX = 3*(NUMNOD_L+NRCVVOIS_L))
! X(1:3,1:NUMNOD) : local nodes
!  (1:3, NUMNOD+1:) additional nodes (also on adjacent domains but connected to the boundary of the current domain)
!
      INTEGER IXQ(NIXQ,SIXQ/NIXQ)
      my_real PM(NPROPM,NUMMAT), X(3,SX/3), T(*), GRAD(4,*), COEF(*), FV(*)
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER JFACE(MVSIZ), JVOIS(MVSIZ), NC1(MVSIZ), NC2(MVSIZ), IPERM(2,4),
     .        IFIMP, I,II, MAT, IFQ, J, IAD2, LGTH
      my_real y1(mvsiz)  , y2(mvsiz), z1(mvsiz) , z2(mvsiz) ,
     .        tflu(mvsiz), xf(mvsiz), n1y(mvsiz), n1z(mvsiz),
     .        area
C-----------------------------------------------
      DATA iperm / 1,2,
     .             2,3,
     .             3,4,
     .             4,1/
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
C---------------------------------------------------------------------
C     CALCULATION OF IMPOSED FLUXES
C---------------------------------------------------------------------
      ifimp=0
      DO i=lft,llt
        ii =nft+i
        mat=ixq(1,ii)
        ifq=nint(pm(44,mat))
        IF(ifq /= 0)THEN
          tflu(i)=pm(60,mat)*fv(ifq)
          xf(i)=one
          ifimp=1
        ELSE
          tflu(i)=zero
          xf(i)=zero
        ENDIF
      ENDDO
      
      IF(ifimp == 0)RETURN
C---------------------------------------------------------------------
C     FINDING RELATED FACE
C---------------------------------------------------------------------
      DO i=lft,llt
        ii =nft+i
        iad2 = ale_connect%ee_connect%iad_connect(ii)
        lgth = ale_connect%ee_connect%iad_connect(ii+1) - iad2
        DO j=1,lgth
          jface(i)=j
          jvois(i)=ale_connect%ee_connect%connected(iad2 + j - 1)
          IF(jvois(i) <= 0)cycle
          mat=ixq(1,jvois(i))
          mtn=nint(pm(19,mat))
          IF(mtn /= 11)EXIT
        enddo!next J
      enddo!next I
      
C-----------------------------------------------
C     SURFACE CALCULATION
C-----------------------------------------------
      DO i=lft,llt
        ii =nft+i
        nc1(i) = ixq(1+iperm(1,jface(i)),ii)
        nc2(i) = ixq(1+iperm(2,jface(i)),ii)
 
        y1(i)  = x(2,nc1(i))
        z1(i)  = x(3,nc1(i))
 
        y2(i)  = x(2,nc2(i))
        z2(i)  = x(3,nc2(i))
 
        n1y(i) = (z2(i)-z1(i))
        n1z(i) = -(y2(i)-y1(i))
      ENDDO
 
      IF(n2d == 1)THEN
        DO i=lft,llt
          n1y(i) = n1y(i)*(y1(i)+y2(i))*half
          n1z(i) = n1z(i)*(y1(i)+y2(i))*half
        ENDDO
      ENDIF
      
C------------------------------------------
C     NORMAL VECTOR CALCULATION
C------------------------------------------
      DO i=lft,llt
        ii    = nft+i
        area  = sqrt(n1y(i)**2+n1z(i)**2)
        t(ii) = (one-xf(i))*t(ii) + xf(i)*t(jvois(i)) - area*tflu(i)*half*(coef(ii)+coef(jvois(i))) /
     .   max(em20,coef(ii)*coef(jvois(i))*grad(jface(i),i))
      ENDDO
 
      RETURN
      END