ale51_spmd3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ale51_spmd3            ../engine/source/ale/ale51/ale51_spmd3.F
!||--- called by ------------------------------------------------------
!||    afluxt                 ../engine/source/ale/ale51/afluxt.f
!||--- calls      -----------------------------------------------------
!||    sysfus2                ../engine/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.F
!||====================================================================
      SUBROUTINE ale51_spmd3(IXS      ,FLUX   ,ALE_CONNECT,
     .                       FLUX_VOIS,N4_VOIS,ITABM1,NV46)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE ale_connectivity_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "spmd_c.inc"
#include      "com04_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXS(NIXS,NUMELS), N4_VOIS(NUMELS+NSVOIS,8),ITABM1(*),NV46
      my_real flux(6,*), flux_vois(numels+nsvois,nv46)
      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,II,K,KK,L,IV,NN,IPERM(4,6),TAG(0:NUMNOD), NI(4), IAD2
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER SYSFUS2
C-----------------------------------------------
      DATA iperm/3,1,2,4,
     .           7,4,3,8,
     .           6,8,7,5,
     .           2,5,6,1,
     .           7,2,6,3,
     .           8,1,4,5/
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------
      DO i=lft,llt
        ii = i+nft
        DO l=1,8
          tag(ixs(1+l,ii)) = 0
        ENDDO
      ENDDO
 
      DO i=lft,llt
        ii = i+nft
        iad2 = ale_connect%ee_connect%iad_connect(ii)
        DO k=1,6
         iv = ale_connect%ee_connect%connected(iad2 + k - 1)
          IF(iv > numels)THEN
            DO kk=1,6
             IF(n4_vois(iv,1) /= 0.AND.
     .          flux_vois(iv,kk) /= -ep20)THEN
              nn =0
              DO l=1,4
                ni(l) = sysfus2(n4_vois(iv,iperm(l,kk)),itabm1,numnod)
                tag(ni(l)) = 1
              ENDDO
              DO l=1,4
                nn=nn+tag(ixs(1+iperm(l,k),ii))
              ENDDO
              DO l=1,4
                tag(ni(l)) = 0                    
              ENDDO
              IF(nn==4)THEN
                flux(k,i)=-flux_vois(iv,kk)
                EXIT !KK
              ENDIF
             ENDIF
            ENDDO
          ENDIF
        enddo!nextK
      enddo!next I
C-----------------------------------------------
      RETURN
      END
C