alefvm_grav_init.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    alefvm_grav_init      ../engine/source/ale/alefvm/alefvm_grav_init.F
!||--- called by ------------------------------------------------------
!||    alemain               ../engine/source/ale/alemain.f
!||--- calls      -----------------------------------------------------
!||    finter                ../engine/source/tools/curve/finter.F
!||--- uses       -----------------------------------------------------
!||    alefvm_mod            ../common_source/modules/ale/alefvm_mod.f
!||    python_funct_mod      ../common_source/modules/python_mod.F90
!||    sensor_mod            ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE alefvm_grav_init(PYTHON, 
     1                          AGRV, IGRV, LGRAV, NSENSOR, SENSOR_TAB,
     2                          ITASK, NPC , TF    ,SKEW )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C 'alefvm' is related to a collocated scheme (built from FVM and based on Godunov scheme)
C  which was temporarily introduced for experimental option /INTER/TYPE22 (FSI coupling with cut cell method)
C This cut cell method is not completed, abandoned, and is not an official option.
C There is no other use for this scheme which is automatically enabled when /INTER/TYPE22 is defined (INT22>0 => IALEFVM=1).
C
C This subroutine is treating an uncut cell.
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE python_funct_mod
      USE alefvm_mod
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "param_c.inc"
#include      "task_c.inc"
C-----------------------------------------------
C   D e s c r i p t i o n
C----------------------------------------------- 
C This subroutines computes gravity forces for
C finite volume scheme (IALEFVM==1)
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE(python_) , INTENT(IN) :: PYTHON
      INTEGER ,INTENT(IN) :: NSENSOR
      INTEGER :: IGRV(NIGRV,*), ITASK,LGRAV(*),NPC(*)
      my_real :: agrv(lfacgrv,*),tf(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER          :: J, K, K1, K2, K3, NL, NN, ISK, IFUNC, N2
      INTEGER          :: IADF,IADL,ISENS,N1
      my_real          :: ts,aa,fcx,fcy,a0,dydx,gama,wfextt
      my_real          :: skew(lskew,*)
      my_real,EXTERNAL :: finter      
      INTEGER          :: ISMOOTH
      TYPE (SENSOR_STR_) ,DIMENSION(NSENSOR) :: SENSOR_TAB
C-----------------------------------------------
C   P r e - C o n d i t i o n s
C-----------------------------------------------      
C      IF(IALEFVM==0)RETURN
      IF(ngrav==0)  RETURN !no there is Call_my barrier
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------
 
      !-------------------------------------------------------------!
      ! GRAVITY COMPUTED FOR CELL VERTEXES                          !
      !-------------------------------------------------------------!   
      wfextt = zero
  
      DO nl=1,ngrav
        fcy   = agrv(1,nl)
        fcx   = agrv(2,nl)
        nn    = igrv(1,nl)
        isk   = igrv(2,nl)/10
        n2    = igrv(2,nl)-10*isk
        ifunc = igrv(3,nl)
        iad   = igrv(4,nl)
        iadf  = iad+itask*nn/nthread
        iadl  = iad-1+(itask+1)*nn/nthread
 
        isens=0
        DO k=1,nsensor
          IF(igrv(6,nl)==sensor_tab(k)%SENS_ID) isens=k  
        ENDDO
        IF(isens==0)THEN
          ts  = tt
        ELSE
          ts  = tt-sensor_tab(isens)%TSTART
          IF(ts<0.0)cycle
        ENDIF
        ismooth = 0
        IF (ifunc > 0) ismooth = npc(2*nfunct+ifunc+1)
 
        IF (ifunc > 0) THEN
          IF(ismooth >= 0) THEN
            a0    = fcy*finter(ifunc,(ts-dt1)*fcx,npc,tf,dydx)
            gama  = fcy*finter(ifunc,ts*fcx,npc,tf,dydx)
          ELSE IF (ismooth < 0) THEN
            ismooth = -ismooth ! the id the python function is saved in the position of ISMOOTH in the NPC array 
            CALL python_call_funct1d(python, ismooth,(ts-dt1)*fcx, a0)
            CALL python_call_funct1d(python, ismooth,ts*fcx, gama)
            a0 = fcy*a0
            gama = fcy*gama
          ENDIF
        ELSE
          a0   = fcy
          gama = fcy
        ENDIF
        aa    = gama
 
        k1    = 3*n2-2
        k2    = 3*n2-1
        k3    = 3*n2
        
        IF(nl == 1)THEN
         !initialisation
#include "vectorize.inc"
          DO j=iadf,iadl
            !Acceleration on FVM vertexes
            n1=iabs(lgrav(j))
            alefvm_buffer%VERTEX(1,n1) =  skew(k1,isk)*aa
            alefvm_buffer%VERTEX(2,n1) =  skew(k2,isk)*aa
            alefvm_buffer%VERTEX(3,n1) =  skew(k3,isk)*aa
            alefvm_buffer%VERTEX(4,n1) = one
            !--- TODO : WFEXTT
            ! VV = SKEW(K1,ISK)*V(1,N1)+SKEW(K2,ISK)*V(2,N1)+SKEW(K3,ISK)*V(3,N1)
            ! IF(LGRAV(J)>0)WFEXTT=WFEXTT+HALF*(A0+AA)*MS(N1)*VV*DT1*WEIGHT(N1)
           ENDDO !next J
         ELSE
          !cumul
#include "vectorize.inc"
          DO j=iadf,iadl
            !Acceleration on FVM vertexes
            n1=iabs(lgrav(j))
            alefvm_buffer%VERTEX(1,n1) = alefvm_buffer%VERTEX(1,n1)+skew(k1,isk)*aa
            alefvm_buffer%VERTEX(2,n1) = alefvm_buffer%VERTEX(2,n1)+skew(k2,isk)*aa
            alefvm_buffer%VERTEX(3,n1) = alefvm_buffer%VERTEX(3,n1)+skew(k3,isk)*aa
            alefvm_buffer%VERTEX(4,n1) = one
            !--- TODO : WFEXTT
            ! VV = SKEW(K1,ISK)*V(1,N1)+SKEW(K2,ISK)*V(2,N1)+SKEW(K3,ISK)*V(3,N1)
            ! IF(LGRAV(J)>0)WFEXTT=WFEXTT+HALF*(A0+AA)*MS(N1)*VV*DT1*WEIGHT(N1)
           ENDDO !next J
         ENDIF
 
      END DO !next NL
 
 
 
      RETURN
      END