alefvm_gravity_int22.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    alefvm_gravity_int22   ../engine/source/ale/alefvm/alefvm_gravity_int22.F
!||--- called by ------------------------------------------------------
!||    sforc3                 ../engine/source/elements/solid/solide/sforc3.f
!||--- uses       -----------------------------------------------------
!||    alefvm_mod             ../common_source/modules/ale/alefvm_mod.F
!||    i22bufbric_mod         ../common_source/modules/interfaces/cut-cell-search_mod.F
!||====================================================================
      SUBROUTINE alefvm_gravity_int22 (VOLN, IXS , RHO , IAD22 )
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C 'alefvm' is related to a collocated scheme (built from FVM and based on Godunov scheme)
C  which was temporarily introduced for experimental option /INTER/TYPE22 (FSI coupling with cut cell method)
C This cut cell method is not completed, abandoned, and is not an official option.
C There is no other use for this scheme which is automatically enabled when /INTER/TYPE22 is defined (INT22>0 => IALEFVM=1).
C
C This subroutine is treating an uncut cell.
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE alefvm_mod
      USE i22bufbric_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
#include      "com01_c.inc"
#include      "inter22.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D e s c r i p t i o n
C----------------------------------------------- 
C This subroutines computes gravity forces for
C finite volume scheme (IALEFVM==1)
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: IXS(NIXS,*)
      my_real :: voln(mvsiz),rho(mvsiz),iad22(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I, J, K, IB, MNOD
      INTEGER :: NVERTEX,INOd,II, NIN
      my_real :: m_cell(mvsiz),accel(3,mvsiz)
      LOGICAL :: debug_outp
      INTEGER :: idbf,idbl , MCELL
C-----------------------------------------------
C   P r e - C o n d i t i o n s
C-----------------------------------------------      
      IF(alefvm_param%IEnabled==0)RETURN
      IF(int22==0)  RETURN
C-----------------------------------------------
C   S o u r c e   L i n e s 
C-----------------------------------------------
 
      nin = 1
 
      !-------------------------------------------------------------!
      ! GRAVITY COMPUTED FOR CELL CENTROIDS                         !
      !-------------------------------------------------------------!      
      DO i=lft,llt
        ib            = nint(iad22(i))
        IF(ib<=0)cycle
        ii            = i+nft
        nvertex       = 0
        accel(1:3,i)  = zero
        alefvm_buffer%FCELL(1:3,ii) = zero
        !loop on main cell vertexes
        mcell         = brick_list(nin,ib)%MainID
        mnod          = brick_list(nin,ib)%POLY(mcell)%NumNOD 
        DO k=1,mnod
          j           = brick_list(nin,ib)%POLY(mcell)%ListNodID(k)
          inod        = ixs(1+j,i+nft)
          IF(alefvm_buffer%VERTEX(4,inod)==zero) cycle
          nvertex     = nvertex + 1
          accel(1,i)  = accel(1,i) + alefvm_buffer%VERTEX(1,inod)
          accel(2,i)  = accel(2,i) + alefvm_buffer%VERTEX(2,inod)
          accel(3,i)  = accel(3,i) + alefvm_buffer%VERTEX(3,inod) 
        ENDDO        
        IF(nvertex>0)THEN
          accel(1,i) = accel(1,i) / nvertex
          accel(2,i) = accel(2,i) / nvertex
          accel(3,i) = accel(3,i) / nvertex 
        ENDIF                   
      enddo!next I
      
      DO i=lft,llt
        m_cell(i)   = rho(i)*voln(i) !Check if VOLN is the supercell volume. Should be unchanged since december 2015
      enddo!next I
 
      DO i=lft,llt
        ib          = nint(iad22(i))
        IF(ib<=0)cycle      
        ii          = i + nft
        alefvm_buffer%FCELL(1,ii) = alefvm_buffer%FCELL(1,ii) + m_cell(i) * accel(1,i)
        alefvm_buffer%FCELL(2,ii) = alefvm_buffer%FCELL(2,ii) + m_cell(i) * accel(2,i)
        alefvm_buffer%FCELL(3,ii) = alefvm_buffer%FCELL(3,ii) + m_cell(i) * accel(3,i)                
      enddo!next I
 
        !DEBUG-OUTPUT---------------!
        if(alefvm_param%IOUTP_GRAV /= 0)then
          debug_outp = .false.
          if(alefvm_param%IOUTP_GRAV>0)then
            do i=lft,llt
              ii = nft + i
              if(ixs(11,ii)==alefvm_param%IOUTP_GRAV)THEN
                debug_outp = .true.
                idbf   = i
                idbl   = i
                EXIT
              endif
             enddo
          elseif(alefvm_param%IOUTP_GRAV==-1)then
            debug_outp=.true.
                idbf   = lft
                idbl   = llt          
          endif
!#!include "lockon.inc"  
          if(debug_outp)then     
!#!include "lockon.inc"       
          print *, "    |----alefvm_gravity.F----|"
          print *, "    |   THREAD INFORMATION   |"
          print *, "    |------------------------|" 
          print *, "     NCYCLE =", ncycle
          do i=idbf,idbl
            ii = nft + i
            ib = nint(iad22(i))
            IF(ib<=0)cycle            
            print *,                    "      brique=", ixs(11,nft+i)
            write(*,fmt='(A24,1A26)')   "                        ",             
     .                                  "#--------- cell----------#"          
            write (*,fmt='(A,1E26.14)') "            Rho  =", rho(i)
            write (*,fmt='(A,1E26.14)') "            vol  =", VOLN(I)
            write (*,FMT='(A,1E26.14)') "           mass  =", M_CELL(I)
            write (*,FMT='(A,1E26.14)') "        accel-x  =", ACCEL(1,I)           
            write (*,FMT='(A,1E26.14)') "        accel-y  =", ACCEL(2,I)          
            write (*,FMT='(A,1E26.14)') "        accel-z  =", ACCEL(3,I) 
            write(*,FMT='(A24,8A26)')   "                        ",    
     .                                  "#--------- nod_1 ---------","#--------- nod_2 ---------",
     .                                  "#--------- nod_3 ---------","#--------- nod_4 ---------",
     .                                  "#--------- nod_5 ---------","#--------- nod_6 ---------",
     .                                  "#--------- nod_7 ---------","#--------- nod_8 --------#"     
            write (*,fmt='(A,8E26.14)') "           acc-X =", alefvm_buffer%VERTEX(1,ixs(2:9,i))          
            write (*,fmt='(A,8E26.14)') "           acc-Y =", alefvm_buffer%VERTEX(2,ixs(2:9,i))
            write (*,fmt='(A,8E26.14)') "           acc-Z =", alefvm_buffer%VERTEX(3,ixs(2:9,i))                       
            print *, "      "          
          enddo
!#!include "lockoff.inc"       
        endif
        endif
      !-----------------------------------------!
 
 
 
      RETURN
      END