alesub2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    alesub2      ../engine/source/ale/subcycling/alesub2.F
!||--- called by ------------------------------------------------------
!||    resol        ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    bcs3v        ../engine/source/ale/inter/bcs3v.F
!||    my_barrier   ../engine/source/system/machine.F
!||--- uses       -----------------------------------------------------
!||    ale_mod      ../common_source/modules/ale/ale_mod.F
!||====================================================================
      SUBROUTINE alesub2(
     1   NALE   ,V    ,DSAVE ,ICODT  ,ISKEW  ,
     2   SKEW   ,ASAVE,A     ,D      ,NELTST ,
     3   ITYPTST,ITASK,NODFT ,NODLT  ,DT2SAVE,
     4   DT2T   ,NELTSA,ITYPTSA,NELTS  ,
     5   WEIGHT ,FSKY ,FSKYV )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE ale_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
C /ALESUB is an obsolete option
C Multidomain computation (/SUBDOMAIN) is now used instead.
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "scr06_c.inc"
#include      "units_c.inc"
#include      "task_c.inc"
#include      "parit_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NALE(*),ICODT(*),ISKEW(*), WEIGHT(*), NELTST ,ITYPTST,
     .        ITASK,NODFT,NODLT,NELTSA ,ITYPTSA, NELTS
      my_real V(3,NUMNOD),DSAVE(3,*),SKEW(LSKEW,*),ASAVE(3,*),A(3,NUMNOD),D(3,NUMNOD),
     .         DT2SAVE,DT2T,FSKY(8,LSKY),FSKYV(LSKY,8)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER N,LCOD, INDX2(1024), I,IPRI,NINDX2, K, NISKFT, NISKLT
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------      
C
C--------------------------------------------------------
C       ALE SUB-CYCLING (PART 2)
C--------------------------------------------------------
      IF(itask == 0) THEN
          dt2=dt2*ale%SUB%DTFSUB
          IF(dt2s /= zero)dt2=min(dt2,onep1*dt2s)
          IF(tt > zero)THEN
           dt12s=half*(dt1+int(dt2/ale%SUB%DT1SAVE)*ale%SUB%DT1SAVE)
          ELSE
           dt12s=half*dt2
          ENDIF
          dt2s=dt2
          dt1=ale%SUB%DT1SAVE
          ipri=mod(ncycle,iabs(ncpri))
          IF(ipri == 0.AND.ispmd == 0)THEN
            WRITE(iout,1000) ' FLUID TIME STEP ',dt2s,' SOLID',nelts
            IF(ncpri < 0)
     &        WRITE(istdo,1000)' FLUID TIME STEP ',dt2s
 1000       FORMAT(a,1pe11.4,a,i10)
          ENDIF
      ENDIF
C
      CALL my_barrier
C
      dt2t=min(dt2,dt2save)
      neltst =neltsa
      ityptst=ityptsa
C RESET LAGRANGIAN VELOCITIES
      DO n=nodft,nodlt
       IF(nale(n) == 0)THEN
        v(1,n)=dsave(1,n)
        v(2,n)=dsave(2,n)
        v(3,n)=dsave(3,n)
       ENDIF
      ENDDO
      DO i=nodft,nodlt,1024
        nindx2 = 0
        DO n = i,min(nodlt,i+1023)
          lcod=icodt(n+numnod+numnod)
          IF(nale(n)*lcod /= 0)THEN
            nindx2 = nindx2 + 1
            indx2(nindx2) = n
          ENDIF
        ENDDO
        IF (nindx2 /= 0)THEN
          CALL bcs3v(nindx2,indx2,iskew,icodt(2*numnod+1),v,dsave ,skew)
        ENDIF
      ENDDO
C
C DISPLACEMENT BACKUP
C
      DO n=nodft,nodlt
          dsave(1,n)=d(1,n)
          dsave(2,n)=d(2,n)
          dsave(3,n)=d(3,n)
      ENDDO
 
      IF(iparit > 0)THEN
C forces from solid elements are stored in fsky
C they are reused in subcycles
C + same strategy as P/off => use of ASAVE
          DO n=nodft,nodlt
            asave(1,n)=a(1,n)
            asave(2,n)=a(2,n)
            asave(3,n)=a(3,n)
          ENDDO
        niskft =  1+itask*lsky/nthread
        nisklt = (itask+1)*lsky/nthread
          IF(ivector == 1) THEN
            DO k=1,8
              DO i=niskft,nisklt
                fskyv(i,k)=zero
              ENDDO
            ENDDO
          ELSE
            DO k=1,8
              DO i=niskft,nisklt
                fsky(k,i)=zero
              ENDDO
            ENDDO
          ENDIF
C Parith/OFF
      ELSE
          DO n=nodft,nodlt
            a(1,n)=a(1,n)*weight(n)
            a(2,n)=a(2,n)*weight(n)
            a(3,n)=a(3,n)*weight(n)
            asave(1,n)=a(1,n)
            asave(2,n)=a(2,n)
            asave(3,n)=a(3,n)
          ENDDO
      ENDIF
C
      RETURN
      END