alew1.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    alew1                  ../engine/source/ale/grid/alew1.F
!||--- called by ------------------------------------------------------
!||    alewdx                 ../engine/source/ale/grid/alewdx.F
!||--- calls      -----------------------------------------------------
!||    spmd_xvois             ../engine/source/mpi/fluid/spmd_cfd.f
!||--- uses       -----------------------------------------------------
!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.F
!||    ale_mod                ../common_source/modules/ale/ale_mod.F
!||====================================================================
      SUBROUTINE alew1( 
     1   D              ,V       ,W       ,
     2   ALE_NN_CONNECT ,NALE    ,NODFT   ,NODLT   ,
     3   NBRCVOIS       ,NBSDVOIS,LNRCVOIS,LNSDVOIS)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------      
      USE ale_connectivity_mod
      USE ale_mod
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C Compute Grid for /ALE/GRID/DISP
C
C     X,D,V are allocated to SX,SD,DV=3*(NUMNOD_L+NUMVVOIS_L)
C      in grid subroutine it may needed to access nodes which
C      are connected to a remote elem. They are sored in X(1:3,NUMNOD+1:)
C      Consequently X is defined here X(3,SX/3) instead of X(3,NUMNOD) as usually
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "tabsiz_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
! SPMD CASE : SX >= 3*NUMNOD    (SX = 3*(NUMNOD_L+NRCVVOIS_L))
! X(1:3,1:NUMNOD) : local nodes
!  (1:3, NUMNOD+1:) additional nodes (also on adjacent domains but connected to the boundary of the current domain)
!      idem with D(SD), and V(SV)
C-----------------------------------------------
      INTEGER NALE(NUMNOD), NODFT, NODLT,
     .        NBRCVOIS(*),NBSDVOIS(*),
     .        LNRCVOIS(*),LNSDVOIS(*)
      my_real d(3,sd/3), v(3,sv/3), w(3,sw/3)
      TYPE(t_connectivity), INTENT(IN) :: ALE_NN_CONNECT
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, LENCOM
      my_real DX, DY, DZ,FAC
      INTEGER :: IAD, IAD1, IAD2, NODE_ID
      my_real :: dx_max, dx_min
      my_real :: dy_max, dy_min
      my_real :: dz_max, dz_min
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
C  SPMD : COMM D
      IF(nspmd > 1)THEN
!$OMP SINGLE
         lencom = nbrcvois(nspmd+1)+nbsdvois(nspmd+1)
         CALL spmd_xvois(d,nbrcvois,nbsdvois,lnrcvois,lnsdvois,lencom)
!$OMP END SINGLE
      END IF
      fac=one/dt2/three
      DO i = nodft, nodlt
         IF(iabs(nale(i)) == 1) THEN
            iad1 = ale_nn_connect%IAD_CONNECT(i)
            iad2 = ale_nn_connect%IAD_CONNECT(i + 1) - 1
            dx_max = -huge(zero)
            dx_min = huge(zero)
            dy_max = -huge(zero)
            dy_min = huge(zero)
            dz_max = -huge(zero)
            dz_min = huge(zero)
            DO iad = iad1, iad2
               node_id = ale_nn_connect%CONNECTED(iad)
               dx_max = max(dx_max, d(1, node_id))
               dx_min = min(dx_min, d(1, node_id))
               dy_max = max(dy_max, d(2, node_id))
               dy_min = min(dy_min, d(2, node_id))
               dz_max = max(dz_max, d(3, node_id))
               dz_min = min(dz_min, d(3, node_id))
            ENDDO
            dx = fac * (dx_max + dx_min - two * d(1, i))
            dy = fac * (dy_max + dy_min - two * d(2, i))
            dz = fac * (dz_max + dz_min - two * d(3, i))
            w(1,i)=sign(one,dx)*min(abs(dx),ale%GRID%ALPHA)
            w(2,i)=sign(one,dy)*min(abs(dy),ale%GRID%ALPHA)
            w(3,i)=sign(one,dz)*min(abs(dz),ale%GRID%ALPHA)
         ELSEIF(nale(i) == 0)THEN
            w(1,i)=v(1,i)
            w(2,i)=v(2,i)
            w(3,i)=v(3,i)
         ELSE
            w(1,i)=zero
            w(2,i)=zero
            w(3,i)=zero     
         ENDIF
C     
      ENDDO
C     
      RETURN
      END