ani_segquadfr.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ani_segquadfr1   ../starter/source/output/anim/ani_segquadfr.F
!||--- called by ------------------------------------------------------
!||    lectur           ../starter/source/starter/lectur.F
!||====================================================================
      SUBROUTINE ani_segquadfr1(IXQ ,SEGTAG ,KNOD2ELQ ,NOD2ELQ ,X ,NSEG)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
C     REAL
      INTEGER  
     .   NSEG,
     .   IXQ(NIXQ,*),SEGTAG(4,*),KNOD2ELQ(*),NOD2ELQ(*)
      my_real
     .   x(3,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER JQ,JJ,K,NQQ,N1,N2,ISEG,KK,KQ,N,L1,L2,L, TRUEAXE, NQQ1,NQQ2
      INTEGER NODTAG(4),LINES(2,4),NQ(4)
      DATA lines/1,2,
     .           2,3,
     .           3,4,
     .           4,1/
C     REAL
C-----------------------------------------------
C
        DO jq=1,numelq
           nodtag(1:4)=1
           DO l=1,4
              nq(l) = ixq(l+1,jq)
              l1 = lines(1,l)
              l2 = lines(2,l) 
              nqq1 = ixq(l1+1,jq)         
              nqq2 = ixq(l2+1,jq)
              DO k=knod2elq(nqq1)+1,knod2elq(nqq1+1)            
                kq=nod2elq(k)
                IF(kq==jq .OR. kq > numelq)cycle
                DO kk=1,4
                  IF(ixq(lines(1,kk)+1,kq)==nqq1.AND.ixq(lines(2,kk)+1,kq)==nqq2) THEN
                     nodtag(l)=0
                  ELSEIF(ixq(lines(1,kk)+1,kq)==nqq2.AND.ixq(lines(2,kk)+1,kq)==nqq1) THEN
                     nodtag(l)=0
                  ENDIF
                ENDDO
             ENDDO
          ENDDO
C
          DO l=1,4
             l1 = lines(1,l)
             l2 = lines(2,l)
             trueaxe= 1
             n1 = nq(l1)
             n2 = nq(l2)
             IF(n2d==1.AND.x(2,n1)<=em10.AND.x(2,n2)<=em10) THEN ! Case Axi omit nodes of revolution axe z ( y=0)
                trueaxe= 0
             ENDIF
 
             IF(trueaxe==1)THEN
               IF(nodtag(l)==1) THEN ! nodes of external lines
                  nseg=nseg+1  
                  segtag(l,jq) = 1
               ENDIF
             ENDIF
         ENDDO
      ENDDO
C     
      RETURN
      END
!||====================================================================
!||    ani_segquadfr2   ../starter/source/output/anim/ani_segquadfr.F
!||--- called by ------------------------------------------------------
!||    lectur           ../starter/source/starter/lectur.F
!||====================================================================
      SUBROUTINE ani_segquadfr2(SEGTAG  ,SEGQUADFR )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER  
     .   SEGTAG(4,*), SEGQUADFR(2,*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER N,JJ,LL
C     REAL
C-----------------------------------------------
C
      nsegquadfr=0
      DO n=1,numelq
        DO jj=1,4
          IF(segtag(jj,n)==1)THEN
            nsegquadfr=nsegquadfr+1
            segquadfr(1,nsegquadfr)=n
            segquadfr(2,nsegquadfr)=jj
          END IF
        END DO
      END DO    
      RETURN
      END