atur17.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    atur17   ../engine/source/ale/turbulence/atur17.F
!||--- called by ------------------------------------------------------
!||    mmain    ../engine/source/materials/mat_share/mmain.F90
!||--- calls      -----------------------------------------------------
!||    a17yl2   ../engine/source/ale/turbulence/a17yl2.F
!||    a17yl3   ../engine/source/ale/turbulence/a17yl3.F
!||====================================================================
      SUBROUTINE atur17(
     1   PM,      OFF,     RHO,     RK,
     2   RE,      GEO,     VOLN,    MAT,
     3   DELTAX,  NGEO,
     4   VD2,     DVOL,    AIRE,    EINC,
     5   PTURB,    ALOGEY,  NEL,
     6   LFT,     LLT,     JPOR)
 
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NEL, LFT,     LLT,     JPOR
      my_real PM(NPROPM,NUMMAT), OFF(*), RHO(*), RK(*), RE(*),GEO(NPROPG,NUMGEO),VOLN(MVSIZ),
     .        DELTAX(*), VD2(*), DVOL(*), AIRE(*), EINC(*), ALOGEY(*)
      my_real,INTENT(INOUT) :: PTURB(1:LLT)
      INTEGER MAT(*),NGEO(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real ei(mvsiz), yl(mvsiz), gf, cmu, ax, a, gm, xk
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
C-----------------
C     YL CALCULATION
C-----------------
      IF(jpor /= 2)THEN
        IF(n2d == 0)THEN
          CALL a17yl3(
     1   deltax,  yl,      nel)
        ELSE
          CALL a17yl2(
     1   deltax,  yl,      aire,    nel)
        ENDIF
        DO i=lft,llt
          gf=pm(50,mat(i))
          cmu=pm(81,mat(i))
          ax=pm(47,mat(i))
          a=pm(49,mat(i))
          gm=one -gf+gf*alogey(i)
          pturb(i)=two*rk(i)/(voln(i)*three)
          ei(i)=gm*einc(i)/alogey(i)-dvol(i)*pturb(i)
          ei(i)=max(zero,ei(i))
          rk(i)=rk(i)+(ei(i)-re(i)*dt1)*off(i)
          rk(i)= max(em15,rk(i)/voln(i))
          xk=rk(i)/rho(i)
          re(i)=rho(i)*sqrt(xk*sqrt(cmu))**3*sqrt(sqrt(gm))/(ax*yl(i))
          re(i)=max(em15,re(i))
        enddo! next I
      ELSE
       DO i=lft,llt
        ! MESH VELOCITY SUPPOSED LOW REGARDING MATERIALVELOCITY V(QUASI EULERIAN)
        rk(i)=rho(i)*geo(22,ngeo(i))**2*vd2(i)
        re(i)=(rk(i)**3/rho(i))**half/geo(23,ngeo(i))
       ENDDO
      ENDIF
      RETURN
      END