aturbn.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    aturbn   ../engine/source/ale/turbulence/aturbn.F
!||--- called by ------------------------------------------------------
!||    mmain    ../engine/source/materials/mat_share/mmain.F90
!||====================================================================
      SUBROUTINE aturbn(PM,OFF  ,RHO  ,RK   ,RE   ,GEO  , 
     2               EINC ,DVOL ,VNEW ,PTURB ,TMU  ,VIS  ,
     3               VD2  ,MAT  ,NGEO,
     5               LFT, LLT,   JPOR,   JCLOSE)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER MAT(*),NGEO(*)
      INTEGER, INTENT(IN) ::   LFT, LLT,   JPOR,   JCLOSE
 
      my_real pm(npropm,nummat), off(*), rho(*), rk(*), re(*),geo(npropg,numgeo)
      my_real einc(*), dvol(*), vnew(*), tmu(*), vis(*), vd2(*)
      my_real,intent(inout) :: pturb(1:llt) ! turbulent pressure (additional term)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real EI, XFAC, ARK, C1, C2, C3, SGSL, CMU, SE, FAC, RESGS     
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
C
      IF(jpor /= 2)THEN
      
       DO i=lft,llt
         xfac=tmu(i)/vis(i)
         pturb(i)=two*rk(i)/(vnew(i)*three)
         ei  =xfac*einc(i)-dvol(i)*pturb(i)
         ei  =max(zero,ei)
         rk(i)  =rk(i)+(ei-re(i)*dt1)*off(i)
         ark= max(rk(i),em15)
         c1 =pm(82,mat(i))/ark
         c2 =pm(83,mat(i))/ark
         c3 =pm(84,mat(i))
         re(i)=re(i)*(one +(c1*ei-c2*re(i)*dt1+c3*dvol(i)/vnew(i))*off(i))
         rk(i)= max(em15,rk(i)/vnew(i))
         re(i)= max(em15,re(i)/vnew(i))
       ENDDO
       IF(jclose == 0)THEN
        DO i=lft,llt
          sgsl=pm(46,mat(i))
          cmu=pm(81,mat(i))
          c1 =pm(82,mat(i))
          c2 =pm(83,mat(i))
          se =pm(86,mat(i))
          fac=sqrt(cmu/(se*(c2-c1)))/sgsl
          resgs=rho(i)*fac*(rk(i)/rho(i))**three_half
          re(i)= max(re(i),resgs)
        ENDDO
       ELSE
        DO i=lft,llt
          sgsl=max(2.*geo(130,ngeo(i)),pm(46,mat(i)))
          cmu=pm(81,mat(i))
          c1 =pm(82,mat(i))
          c2 =pm(83,mat(i))
          se =pm(86,mat(i))
          fac=sqrt(cmu/(se*(c2-c1)))/max(sgsl,em15)
          resgs=rho(i)*fac*(rk(i)/rho(i))**three_half
          re(i)= max(re(i),resgs)
        ENDDO
       ENDIF
      ELSE
      !POROUS MEDIA : IMPOSED TURBULENCY
       DO i=lft,llt
         ! W (GRID/MESH VELOCITY) SUPPOSED TO BE LOW REGARDING MATERIAL VELOCITY V (QUASI EULERIAN)
         rk(i)=rho(i)*geo(22,ngeo(i))**2*vd2(i)
         re(i)=(rk(i)**3/rho(i))**half/geo(23,ngeo(i))
       ENDDO
       
      endif! (JPOR /= 2)
C
      RETURN
      END