boltst.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    boltst       ../engine/source/elements/solid/solide/boltst.F
!||--- called by ------------------------------------------------------
!||    s10forc3     ../engine/source/elements/solid/solide10/s10forc3.F
!||    s4forc3      ../engine/source/elements/solid/solide4/s4forc3.F
!||    s8cforc3     ../engine/source/elements/thickshell/solide8c/s8cforc3.F
!||    s8eforc3     ../engine/source/elements/solid/solide8e/s8eforc3.F
!||    s8zforc3     ../engine/source/elements/solid/solide8z/s8zforc3.F
!||    sforc3       ../engine/source/elements/solid/solide/sforc3.F
!||    szforc3      ../engine/source/elements/solid/solidez/szforc3.F
!||--- uses       -----------------------------------------------------
!||    sensor_mod   ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE boltst(IP      ,BPRELD   ,SIG       ,TT        ,        
     .                  NEL     ,NPT      ,NSENSOR   ,SENSOR_TAB,
     .                  FUN_ID  ,SENS_ID  )
C-----------------------------------------------  
C   M o d u l e s
C-----------------------------------------------  
      USE sensor_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NPT,NSENSOR,NEL,IP,FUN_ID,SENS_ID
      my_real
     .   tt
      my_real
     .   bpreld(nel,*),sig(nel,6)
      TYPE (SENSOR_STR_) ,DIMENSION(NSENSOR) ,INTENT(IN) :: SENSOR_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,ISENS 
      my_real
     .   ts,te,sfac
C-----------------------------------------------
!!! see preload_solid_ini.F90
      
       DO i=1,nel
        ts = bpreld(i,1)
        te = bpreld(i,2)
        IF(bpreld(i,3) == zero)THEN
          isens = sens_id
        
          IF (isens > 0) THEN
           ts = ts+sensor_tab(isens)%TSTART
           te = te+sensor_tab(isens)%TSTART
          ENDIF
        ENDIF
 
        IF(bpreld(i,3) < one)THEN
          IF(tt >= ts )THEN
           sfac = bpreld(i,10)
           sig(i,1) = sfac*bpreld(i,4) !SIG(I,1)+BPRELD(I,4)
           sig(i,2) = sfac*bpreld(i,5) !SIG(I,2)+BPRELD(I,5)
           sig(i,3) = sfac*bpreld(i,6) !SIG(I,3)+BPRELD(I,6)
           sig(i,4) = sfac*bpreld(i,7) !SIG(I,4)+BPRELD(I,7)
           sig(i,5) = sfac*bpreld(i,8) !SIG(I,5)+BPRELD(I,8)
           sig(i,6) = sfac*bpreld(i,9) !SIG(I,6)+BPRELD(I,9)
           bpreld(i,3) = real(ip)/real(npt)
           
!          Added to shift all the preloading duration in case of sensor use        
           bpreld(i,1) = ts
           bpreld(i,2) = te
          ENDIF
        ENDIF
       ENDDO
      
! Added to compensate loss of stress when filling the gap
       IF(bpreld(1,3) == one)THEN
         ts = bpreld(1,1)
         te = bpreld(1,2)
         IF(fun_id == 0)THEN
           IF (tt <= (ts+em01*(te-ts))) THEN
            DO i=1,nel
              sig(i,1) = bpreld(i,4)
              sig(i,2) = bpreld(i,5)
              sig(i,3) = bpreld(i,6)
              sig(i,4) = bpreld(i,7)
              sig(i,5) = bpreld(i,8)
              sig(i,6) = bpreld(i,9)
            ENDDO
           ELSE IF (tt >= te) THEN
            DO i=1,nel
              bpreld(i,3) = two
            ENDDO
           ENDIF
         ELSE ! ramping inital stress need more time to reach the pick
           IF (tt < te) THEN
             sfac = bpreld(1,10)
             sig(1:nel,1:6) = sfac*bpreld(1:nel,4:9)
           ELSE 
             bpreld(1:nel,3) = two
           ENDIF
         ENDIF
       END IF !(BPRELD(1,3) == ONE)THEN
 
       
      RETURN
      END