c3coor3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    c3coor3       ../engine/source/elements/sh3n/coque3n/c3coor3.F
!||--- called by ------------------------------------------------------
!||    c3forc3       ../engine/source/elements/sh3n/coque3n/c3forc3.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||====================================================================
      SUBROUTINE c3coor3(JFT      ,JLT      ,X       ,IXTG     ,
     .                   OFFG     ,OFF      ,DT1C    ,
     .                   V        ,VR       ,VL1     ,VL2      ,VL3      ,
     .                   VRL1     ,VRL2     ,VRL3    ,SIGY     ,
     .                   X1       ,X2       ,X3      ,Y1       ,Y2       ,
     .                   Y3       ,Z1       ,Z2      ,Z3       ,XDP      )
      use element_mod , only : nixtg
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "scr05_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT
      INTEGER IXTG(NIXTG,*)
      my_real
     .   OFFG(*), OFF(*),DT1C(*),X(3,*),
     .   V(3,*),VR(3,*),VL1(MVSIZ,3),VL2(MVSIZ,3),VL3(MVSIZ,3),
     .   vrl1(mvsiz,3),vrl2(mvsiz,3),vrl3(mvsiz,3),sigy(*)
!       SP issue :
      REAL(kind=8), dimension(3,*), INTENT(in) :: xdp
      REAL(kind=8), dimension(mvsiz), INTENT(out) ::x1,x2,x3
      REAL(kind=8), dimension(mvsiz), INTENT(out) ::y1,y2,y3
      REAL(kind=8), dimension(mvsiz), INTENT(out) ::z1,z2,z3
 
 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, NC1, NC2, NC3
      my_real OFF_L    
C=======================================================================
      IF(IRESP == 1)then
       DO i=jft,jlt
        nc1     = ixtg(2,i) 
        nc2     = ixtg(3,i) 
        nc3     = ixtg(4,i) 
C----------------------------
C       COORDONNEES
C----------------------------
        x1(i)=xdp(1,nc1)
        y1(i)=xdp(2,nc1)
        z1(i)=xdp(3,nc1)
        x2(i)=xdp(1,nc2)
        y2(i)=xdp(2,nc2)
        z2(i)=xdp(3,nc2)
        x3(i)=xdp(1,nc3)
        y3(i)=xdp(2,nc3)
        z3(i)=xdp(3,nc3)
        vl1(i,1)=v(1,nc1)
        vl1(i,2)=v(2,nc1)
        vl1(i,3)=v(3,nc1)
        vl2(i,1)=v(1,nc2)
        vl2(i,2)=v(2,nc2)
        vl2(i,3)=v(3,nc2)
        vl3(i,1)=v(1,nc3)
        vl3(i,2)=v(2,nc3)
        vl3(i,3)=v(3,nc3)
        vrl1(i,1)=vr(1,nc1)
        vrl1(i,2)=vr(2,nc1)
        vrl1(i,3)=vr(3,nc1)
        vrl2(i,1)=vr(1,nc2)
        vrl2(i,2)=vr(2,nc2)
        vrl2(i,3)=vr(3,nc2)
        vrl3(i,1)=vr(1,nc3)
        vrl3(i,2)=vr(2,nc3)
        vrl3(i,3)=vr(3,nc3)
       ENDDO
      ELSE
       DO i=jft,jlt
        nc1     = ixtg(2,i) 
        nc2     = ixtg(3,i) 
        nc3     = ixtg(4,i) 
C----------------------------
C       COORDONNEES
C----------------------------
        x1(i)=x(1,nc1)
        y1(i)=x(2,nc1)
        z1(i)=x(3,nc1)
        x2(i)=x(1,nc2)
        y2(i)=x(2,nc2)
        z2(i)=x(3,nc2)
        x3(i)=x(1,nc3)
        y3(i)=x(2,nc3)
        z3(i)=x(3,nc3)
        vl1(i,1)=v(1,nc1)
        vl1(i,2)=v(2,nc1)
        vl1(i,3)=v(3,nc1)
        vl2(i,1)=v(1,nc2)
        vl2(i,2)=v(2,nc2)
        vl2(i,3)=v(3,nc2)
        vl3(i,1)=v(1,nc3)
        vl3(i,2)=v(2,nc3)
        vl3(i,3)=v(3,nc3)
        vrl1(i,1)=vr(1,nc1)
        vrl1(i,2)=vr(2,nc1)
        vrl1(i,3)=vr(3,nc1)
        vrl2(i,1)=vr(1,nc2)
        vrl2(i,2)=vr(2,nc2)
        vrl2(i,3)=vr(3,nc2)
        vrl3(i,1)=vr(1,nc3)
        vrl3(i,2)=vr(2,nc3)
        vrl3(i,3)=vr(3,nc3)
       ENDDO
      END if!(IRESP == 1)THEN
C
      off_l = zero
      DO i=jft,jlt
        dt1c(i) = dt1
        off(i) = min(one,abs(offg(i)))
        off_l  = min(off_l,offg(i))
        sigy(i) = ep30
      ENDDO
      IF (off_l < zero) THEN
        DO i=jft,jlt
         IF (offg(i) < zero) THEN
           vl1(i,1)=zero
           vl1(i,2)=zero
           vl1(i,3)=zero
           vl2(i,1)=zero
           vl2(i,2)=zero
           vl2(i,3)=zero
           vl3(i,1)=zero
           vl3(i,2)=zero
           vl3(i,3)=zero
           vrl1(i,1)=zero
           vrl1(i,2)=zero
           vrl1(i,3)=zero
           vrl2(i,1)=zero
           vrl2(i,2)=zero
           vrl2(i,3)=zero
           vrl3(i,1)=zero
           vrl3(i,2)=zero
           vrl3(i,3)=zero
         ENDIF
        ENDDO
      ENDIF
C-----------
      RETURN
      END
!||====================================================================
!||    c3coort3      ../engine/source/elements/sh3n/coque3n/c3coor3.F
!||--- called by ------------------------------------------------------
!||    c3forc3       ../engine/source/elements/sh3n/coque3n/c3forc3.F
!||--- uses       -----------------------------------------------------
!||    element_mod   ../common_source/modules/elements/element_mod.F90
!||====================================================================
      SUBROUTINE c3coort3(JFT    ,JLT    ,X     ,IXTG   ,OFFG   ,
     1                    DR     ,XL2    ,XL3   ,YL2    ,YL3    ,
     2                    E1X    ,E1Y    ,E1Z   ,E2X    ,E2Y    ,
     3                    E2Z    ,E3X    ,E3Y   ,E3Z    ,NEL    ,
     5                    V21X   ,V31X   ,V21Y  ,V31Y   ,RZ13   ,
     6                    RZ23   ,X2_T   ,X3_T  ,Y2_T   ,Y3_T   ,
     7                    AREA   ,SMSTR  ,ISROT )
      use element_mod , only : nixtg
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT,ISROT,NEL
      INTEGER IXTG(NIXTG,*)
      my_real
     .   X(3,*), OFFG(*), DR(3,*),
     .   E1X(*), E1Y(*), E1Z(*),
     .   E2X(*), E2Y(*), E2Z(*),E3X(*), E3Y(*), E3Z(*),
     .   XL2(*),XL3(*),YL2(*),YL3(*),AREA(*),
     .   V21X(*),V31X(*),V21Y(*),V31Y(*),RZ13(*),RZ23(*),
     .   X2_T(*),X3_T(*),Y2_T(*),Y3_T(*)
      DOUBLE PRECISION 
     .   SMSTR(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,II(6),NN(3)
      my_real 
     .   X0G2(MVSIZ),X0G3(MVSIZ),Y0G2(MVSIZ),Y0G3(MVSIZ),OFF_L,
     .   Z0G2(MVSIZ),Z0G3(MVSIZ),AXYZ(MVSIZ,3,3),
     .   E01X(MVSIZ), E01Y(MVSIZ), E01Z(MVSIZ),
     .   E02X(MVSIZ), E02Y(MVSIZ), E02Z(MVSIZ),E03X(MVSIZ), 
     .   e03y(mvsiz), e03z(mvsiz),x0l2(mvsiz), x0l3(mvsiz),
     .   y0l2(mvsiz),y0l3(mvsiz),sum(mvsiz),norm,xl,yl,vr1_12,vr1_21,
     .   rlz1,rlz2,rlz3,areai,x0g32,y0g32,z0g32,dirz(mvsiz,2)
C-----------------------------------------------
      DO i=1,6
        ii(i) = nel*(i-1)
      ENDDO
C
       DO i=jft,jlt
          IF(abs(offg(i))==one)offg(i)=sign(two,offg(i))
          axyz(i,1:3,1:3)= zero
C            
           IF (isrot > 0  ) THEN
            nn(1)     = ixtg(2,i) 
            nn(2)     = ixtg(3,i) 
            nn(3)     = ixtg(4,i) 
            axyz(i,1,1) = dr(1,nn(1))
            axyz(i,2,1) = dr(2,nn(1))
            axyz(i,3,1) = dr(3,nn(1))
            axyz(i,1,2) = dr(1,nn(2))
            axyz(i,2,2) = dr(2,nn(2))
            axyz(i,3,2) = dr(3,nn(2))
            axyz(i,1,3) = dr(1,nn(3))
            axyz(i,2,3) = dr(2,nn(3))
            axyz(i,3,3) = dr(3,nn(3))
           END IF !(ISROT > 0  ) THEN
            
            x0g2(i) = smstr(ii(1)+i)
            y0g2(i) = smstr(ii(2)+i)
            z0g2(i) = smstr(ii(3)+i)
            x0g3(i) = smstr(ii(4)+i)
            y0g3(i) = smstr(ii(5)+i)
            z0g3(i) = smstr(ii(6)+i)
        ENDDO
C--       normal in initial conf. 
      DO i=jft,jlt
        e01x(i)= x0g2(i)
        e01y(i)= y0g2(i)
        e01z(i)= z0g2(i)
        sum(i) = sqrt(e01x(i)*e01x(i)+e01y(i)*e01y(i)+e01z(i)*e01z(i))
        e01x(i)=e01x(i)/sum(i)
        e01y(i)=e01y(i)/sum(i)
        e01z(i)=e01z(i)/sum(i)
      ENDDO
C
      DO i=jft,jlt
        x0g32=x0g3(i)-x0g2(i)
        y0g32=y0g3(i)-y0g2(i)
        z0g32=z0g3(i)-z0g2(i)
        e03x(i)=y0g3(i)*z0g32-z0g3(i)*y0g32
        e03y(i)=z0g3(i)*x0g32-x0g3(i)*z0g32
        e03z(i)=x0g3(i)*y0g32-y0g3(i)*x0g32
        sum(i) = sqrt(e03x(i)*e03x(i)+e03y(i)*e03y(i)+e03z(i)*e03z(i))
        e03x(i)=e03x(i)/sum(i)
        e03y(i)=e03y(i)/sum(i)
        e03z(i)=e03z(i)/sum(i)
        area(i) = half * sum(i)
      ENDDO
C
      DO i=jft,jlt
        e02x(i)=e03y(i)*e01z(i)-e03z(i)*e01y(i)
        e02y(i)=e03z(i)*e01x(i)-e03x(i)*e01z(i)
        e02z(i)=e03x(i)*e01y(i)-e03y(i)*e01x(i)
        sum(i) = sqrt(e02x(i)*e02x(i)+e02y(i)*e02y(i)+e02z(i)*e02z(i))
        e02x(i)=e02x(i)/sum(i)
        e02y(i)=e02y(i)/sum(i)
        e02z(i)=e02z(i)/sum(i)
      ENDDO
C----------------------------
C     xl =VR1^t x0l; VR1^t=(VQ0^t*VQ)^t---extract Rzl of VR1
C----------------------------
      DO i=jft,jlt
       vr1_12=e01x(i)*e2x(i)+e01y(i)*e2y(i)+e01z(i)*e2z(i)
       vr1_21=e02x(i)*e1x(i)+e02y(i)*e1y(i)+e02z(i)*e1z(i)
       dirz(i,2) = half*(vr1_12-vr1_21)
       norm = one-dirz(i,2)*dirz(i,2)
       dirz(i,1) = sqrt(max(zero,norm))
      ENDDO 
      DO i=jft,jlt
        x0l2(i)=e01x(i)*x0g2(i)+e01y(i)*y0g2(i)+e01z(i)*z0g2(i)
        y0l2(i)=e02x(i)*x0g2(i)+e02y(i)*y0g2(i)+e02z(i)*z0g2(i)
        x0l3(i)=e01x(i)*x0g3(i)+e01y(i)*y0g3(i)+e01z(i)*z0g3(i)
        y0l3(i)=e02x(i)*x0g3(i)+e02y(i)*y0g3(i)+e02z(i)*z0g3(i)
      ENDDO
C----------------------------
C     Rotate x0l of Rz1 
C----------------------------
      DO i=jft,jlt
        xl= x0l2(i)*dirz(i,1)-y0l2(i)*dirz(i,2)
        yl= x0l2(i)*dirz(i,2)+y0l2(i)*dirz(i,1)
        x0l2(i)=xl
        y0l2(i)=yl
        xl= x0l3(i)*dirz(i,1)-y0l3(i)*dirz(i,2)
        yl= x0l3(i)*dirz(i,2)+y0l3(i)*dirz(i,1)
        x0l3(i)=xl
        y0l3(i)=yl
      ENDDO
C------U21,U31 in actual local system    
      DO i=jft,jlt
        v21x(i)=xl2(i)-x0l2(i)
        v31x(i)=xl3(i)-x0l3(i)
        v21y(i)=yl2(i)-y0l2(i)
        v31y(i)=yl3(i)-y0l3(i)
      ENDDO 
      DO i=jft,jlt
        x2_t(i) = x0l2(i)
        x3_t(i) = x0l3(i)
        y2_t(i) = y0l2(i)
        y3_t(i) = y0l3(i)
      ENDDO 
      IF (isrot>0) THEN
C------RZ13,RZ23 in actual local system    
       DO i=jft,jlt
        areai=half/max(em20,area(i))
        rlz1 =e3x(i)*axyz(i,1,1)+e3y(i)*axyz(i,2,1)+e3z(i)*axyz(i,3,1)
        rlz2 =e3x(i)*axyz(i,1,2)+e3y(i)*axyz(i,2,2)+e3z(i)*axyz(i,3,2)
        rlz3 =e3x(i)*axyz(i,1,3)+e3y(i)*axyz(i,2,3)+e3z(i)*axyz(i,3,3)
        rz13(i)=(rlz1-rlz3)*areai
        rz23(i)=(rlz2-rlz3)*areai
       ENDDO 
      END IF !(ISROT>0) THEN
C
      off_l = zero
      DO i=jft,jlt
        off_l  = min(off_l,offg(i))
      ENDDO
      IF (off_l < zero) THEN
        DO i=jft,jlt
         IF (offg(i) < zero) THEN
          v21x(i) = zero
          v31x(i) = zero
          v21y(i) = zero
          v31y(i) = zero
          rz13(i) = zero
          rz23(i) = zero
         ENDIF
        ENDDO
      ENDIF
C-----------
      RETURN
      END