c3curv3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    c3curv3       ../engine/source/elements/sh3n/coque3n/c3curv3.F
!||--- called by ------------------------------------------------------
!||    c3forc3       ../engine/source/elements/sh3n/coque3n/c3forc3.F
!||    c3forc3_crk   ../engine/source/elements/xfem/c3forc3_crk.F
!||====================================================================
      SUBROUTINE c3curv3(JFT,JLT,VRL1,VRL2,VRL3,
     .                   IXTG,WXY,ISMSTR,KXX,KYY,KXY,
     .                   PX1 ,PY1 ,PY2  ,EYZ   ,EZX  ,
     .                   E1X      ,E1Y      ,E1Z     ,E2X      ,                 
     .                   E2Y      ,E2Z      ,E3X     ,E3Y      ,E3Z      )       
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT,IXTG(NIXTG,*),ISMSTR
      my_real VRL1(MVSIZ,3), VRL2(MVSIZ,3), VRL3(MVSIZ,3),WXY(*),
     .  E1X(MVSIZ),  E1Y(MVSIZ),  E1Z(MVSIZ),  E2X(MVSIZ), 
     .  E2Y(MVSIZ),  E2Z(MVSIZ),  E3X(MVSIZ),  E3Y(MVSIZ), 
     .  e3z(mvsiz),  ezx(mvsiz),  eyz(mvsiz),               
     .  px1(mvsiz),  py1(mvsiz),  py2(mvsiz),
     .  kxx(mvsiz),  kyy(mvsiz),  kxy(mvsiz)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real RX1(MVSIZ),  RX2(MVSIZ),  RX3(MVSIZ),
     .        RY1(MVSIZ),  RY2(MVSIZ),  RY3(MVSIZ)
      my_real RX12T,RX13T,RX23T,RY12T,RY13T,RY23T,RXAVT,RYAVT
C=======================================================================
      DO i=jft,jlt
        rx1(i)=e1x(i)*vrl1(i,1)+e1y(i)*vrl1(i,2)+e1z(i)*vrl1(i,3)
        ry1(i)=e2x(i)*vrl1(i,1)+e2y(i)*vrl1(i,2)+e2z(i)*vrl1(i,3)
        ry2(i)=e2x(i)*vrl2(i,1)+e2y(i)*vrl2(i,2)+e2z(i)*vrl2(i,3)
        rx2(i)=e1x(i)*vrl2(i,1)+e1y(i)*vrl2(i,2)+e1z(i)*vrl2(i,3)
        rx3(i)=e1x(i)*vrl3(i,1)+e1y(i)*vrl3(i,2)+e1z(i)*vrl3(i,3)
        ry3(i)=e2x(i)*vrl3(i,1)+e2y(i)*vrl3(i,2)+e2z(i)*vrl3(i,3)
      ENDDO
C
      DO i=jft,jlt
        rx12t  = rx1(i) - rx2(i)
        rx13t  = rx1(i) - rx3(i)
        rx23t  = rx2(i) - rx3(i)
C
        kyy(i)=-py1(i) * rx13t - py2(i) * rx23t
        kxy(i)= px1(i) * rx12t
C
        ry12t = ry1(i) - ry2(i)
        ry13t = ry1(i) - ry3(i)
        ry23t = ry2(i) - ry3(i)
C
        kxx(i) = px1(i) * ry12t
        kxy(i) = py1(i) * ry13t + py2(i) * ry23t - kxy(i)
C
        ryavt  = px1(i) * (
     .              px1(i) * (-rx1(i)+rx2(i)) 
     .            + (two*py1(i)+three*py2(i)) * ry1(i)
     .            + (three*py1(i)+two*py2(i)) * ry2(i)
 
     .            + ( py1(i) + py2(i) )   * ry3(i) )
        rxavt  = -px1(i) * (   
     .           + (two*py1(i)+py2(i)) * rx1(i)
     .           + (py1(i)+two*py2(i)) * rx2(i)
     .           + three*(py1(i)+py2(i)) * rx3(i) )
     .           + py1(i) * (py1(i)+two*py2(i)) * ry1(i)
     .           - py2(i) * (two*py1(i)+py2(i)) * ry2(i)
     .           + ( py2(i)**2 - py1(i)**2 )   * ry3(i)
C
        ezx(i) = ezx(i) + ryavt * third
        eyz(i) = eyz(i) + rxavt * third   
      ENDDO
c
      IF (ismstr==10) THEN
        DO i=jft,jlt
         rx12t = rx1(i) - rx2(i)
         ry13t = ry1(i) - ry3(i)
         ry23t = ry2(i) - ry3(i)
C
         wxy(i) = py1(i) * ry13t + py2(i) * ry23t + px1(i) * rx12t
        ENDDO 
      ENDIF
c-----------
      RETURN
      END