cderii.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cderii       ../starter/source/elements/shell/coque/cderii.F
!||--- called by ------------------------------------------------------
!||    cbainit3     ../starter/source/elements/shell/coqueba/cbainit3.F
!||    cinit3       ../starter/source/elements/shell/coque/cinit3.F
!||    inirig_mat   ../starter/source/elements/initia/inirig_mat.F
!||====================================================================
      SUBROUTINE cderii(PX1 ,PX2 ,PY1 ,PY2 ,
     .                  X1G ,X2G ,X3G ,X4G ,Y1G ,Y2G  , 
     .                  Y3G ,Y4G ,Z1G ,Z2G ,Z3G ,Z4G  ,
     .                  E1X ,E2X ,E3X ,E1Y ,E2Y ,E3Y ,E1Z ,E2Z ,E3Z ,
     .                  X2L ,X3L ,X4L ,Y2L ,Y3L ,Y4L)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, DIMENSION(MVSIZ), INTENT(IN)  :: 
     .         e1x ,e2x ,e3x ,e1y ,e2y ,e3y ,e1z ,e2z ,e3z ,
     .         x1g,x2g,x3g,x4g,y1g,y2g,y3g,y4g,z1g,z2g,z3g,z4g
c
      my_real, DIMENSION(MVSIZ), INTENT(OUT) :: px1,px2,py1,py2,
     .         x2l,x3l,x4l,y2l,y3l,y4l
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real, DIMENSION(MVSIZ) :: X21G,Y21G,Z21G,X31G,Y31G,Z31G,X41G,
     .                             Y41G,Z41G,Z2L,Z3L,Z4L
C=======================================================================
      DO i=lft,llt
        x21g(i) = x2g(i)-x1g(i)
        y21g(i) = y2g(i)-y1g(i)
        z21g(i) = z2g(i)-z1g(i)
        x31g(i) = x3g(i)-x1g(i)
        y31g(i) = y3g(i)-y1g(i)
        z31g(i) = z3g(i)-z1g(i)
        x41g(i) = x4g(i)-x1g(i)
        y41g(i) = y4g(i)-y1g(i)
        z41g(i) = z4g(i)-z1g(i)
      ENDDO
C
      DO i=lft,llt
        x2l(i)=e1x(i)*x21g(i)+e1y(i)*y21g(i)+e1z(i)*z21g(i)
        y2l(i)=e2x(i)*x21g(i)+e2y(i)*y21g(i)+e2z(i)*z21g(i)
c        Z2L(I)=E3X(I)*X21G(I)+E3Y(I)*Y21G(I)+E3Z(I)*Z21G(I)
        x3l(i)=e1x(i)*x31g(i)+e1y(i)*y31g(i)+e1z(i)*z31g(i)
        y3l(i)=e2x(i)*x31g(i)+e2y(i)*y31g(i)+e2z(i)*z31g(i)
c        Z3L(I)=E3X(I)*X31G(I)+E3Y(I)*Y31G(I)+E3Z(I)*Z31G(I)
        x4l(i)=e1x(i)*x41g(i)+e1y(i)*y41g(i)+e1z(i)*z41g(i)
        y4l(i)=e2x(i)*x41g(i)+e2y(i)*y41g(i)+e2z(i)*z41g(i)
c        Z4L(I)=E3X(I)*X41G(I)+E3Y(I)*Y41G(I)+E3Z(I)*Z41G(I)
      ENDDO
c
      DO i=lft,llt
        px1(i)= half *(y2l(i)-y4l(i))
        px2(i)= half * y3l(i)
        py1(i)=-half *(x2l(i)-x4l(i))
        py2(i)=-half * x3l(i)
      ENDDO
c-----------
      RETURN
      END