cdrvrf3.f

Go to the documentation of this file.

*> \brief \b CDRVRF3
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CDRVRF3( NOUT, NN, NVAL, THRESH, A, LDA, ARF, B1, B2,
*      +                    S_WORK_CLANGE, C_WORK_CGEQRF, TAU )
*
*       .. Scalar Arguments ..
*       INTEGER            LDA, NN, NOUT
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       INTEGER            NVAL( NN )
*       REAL               S_WORK_CLANGE( * )
*       COMPLEX            A( LDA, * ), ARF( * ), B1( LDA, * ),
*      +                   B2( LDA, * )
*       COMPLEX            C_WORK_CGEQRF( * ), TAU( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CDRVRF3 tests the LAPACK RFP routines:
*>     CTFSM
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>                The unit number for output.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>                The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>                The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>                The threshold value for the test ratios.  A result is
*>                included in the output file if RESULT >= THRESH.  To have
*>                every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension (LDA,NMAX)
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>                The leading dimension of the array A.  LDA >= max(1,NMAX).
*> \endverbatim
*>
*> \param[out] ARF
*> \verbatim
*>          ARF is COMPLEX array, dimension ((NMAX*(NMAX+1))/2).
*> \endverbatim
*>
*> \param[out] B1
*> \verbatim
*>          B1 is COMPLEX array, dimension (LDA,NMAX)
*> \endverbatim
*>
*> \param[out] B2
*> \verbatim
*>          B2 is COMPLEX array, dimension (LDA,NMAX)
*> \endverbatim
*>
*> \param[out] S_WORK_CLANGE
*> \verbatim
*>          S_WORK_CLANGE is REAL array, dimension (NMAX)
*> \endverbatim
*>
*> \param[out] C_WORK_CGEQRF
*> \verbatim
*>          C_WORK_CGEQRF is COMPLEX array, dimension (NMAX)
*> \endverbatim
*>
*> \param[out] TAU
*> \verbatim
*>          TAU is COMPLEX array, dimension (NMAX)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cdrvrf3( NOUT, NN, NVAL, THRESH, A, LDA, ARF, B1, B2,
     +                    S_WORK_CLANGE, C_WORK_CGEQRF, TAU )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDA, NN, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      INTEGER            NVAL( NN )
      REAL               S_WORK_CLANGE( * )
      COMPLEX            A( LDA, * ), ARF( * ), B1( LDA, * ),
     +                   b2( lda, * )
      COMPLEX            C_WORK_CGEQRF( * ), TAU( * )
*     ..
*
*  =====================================================================
*     ..
*     .. Parameters ..
      COMPLEX            ZERO, ONE
      parameter( zero = ( 0.0e+0, 0.0e+0 ) ,
     +                     one  = ( 1.0e+0, 0.0e+0 ) )
      INTEGER            NTESTS
      parameter( ntests = 1 )
*     ..
*     .. Local Scalars ..
      CHARACTER          UPLO, CFORM, DIAG, TRANS, SIDE
      INTEGER            I, IFORM, IIM, IIN, INFO, IUPLO, J, M, N, NA,
     +                   nfail, nrun, iside, idiag, ialpha, itrans
      COMPLEX            ALPHA
      REAL               EPS
*     ..
*     .. Local Arrays ..
      CHARACTER          UPLOS( 2 ), FORMS( 2 ), TRANSS( 2 ),
     +                   diags( 2 ), sides( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( NTESTS )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, CLANGE
      COMPLEX            CLARND
      EXTERNAL           slamch, clarnd, clange
*     ..
*     .. External Subroutines ..
      EXTERNAL           ctrttf, cgeqrf, cgeqlf, ctfsm, ctrsm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, sqrt
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos  / 'U', 'L' /
      DATA               forms  / 'N', 'C' /
      DATA               sides  / 'L', 'R' /
      DATA               transs / 'N', 'C' /
      DATA               diags  / 'N', 'U' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      nrun = 0
      nfail = 0
      info = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
      eps = slamch( 'Precision' )
*
      DO 170 iim = 1, nn
*
         m = nval( iim )
*
         DO 160 iin = 1, nn
*
            n = nval( iin )
*
            DO 150 iform = 1, 2
*
               cform = forms( iform )
*
               DO 140 iuplo = 1, 2
*
                  uplo = uplos( iuplo )
*
                  DO 130 iside = 1, 2
*
                     side = sides( iside )
*
                     DO 120 itrans = 1, 2
*
                        trans = transs( itrans )
*
                        DO 110 idiag = 1, 2
*
                           diag = diags( idiag )
*
                           DO 100 ialpha = 1, 3
*
                              IF ( ialpha.EQ. 1) THEN
                                 alpha = zero
                              ELSE IF ( ialpha.EQ. 2) THEN
                                 alpha = one
                              ELSE
                                 alpha = clarnd( 4, iseed )
                              END IF
*
*                             All the parameters are set:
*                                CFORM, SIDE, UPLO, TRANS, DIAG, M, N,
*                                and ALPHA
*                             READY TO TEST!
*
                              nrun = nrun + 1
*
                              IF ( iside.EQ.1 ) THEN
*
*                                The case ISIDE.EQ.1 is when SIDE.EQ.'L'
*                                -> A is M-by-M ( B is M-by-N )
*
                                 na = m
*
                              ELSE
*
*                                The case ISIDE.EQ.2 is when SIDE.EQ.'R'
*                                -> A is N-by-N ( B is M-by-N )
*
                                 na = n
*
                              END IF
*
*                             Generate A our NA--by--NA triangular
*                             matrix.
*                             Our test is based on forward error so we
*                             do want A to be well conditioned! To get
*                             a well-conditioned triangular matrix, we
*                             take the R factor of the QR/LQ factorization
*                             of a random matrix.
*
                              DO j = 1, na
                                 DO i = 1, na
                                    a( i, j) = clarnd( 4, iseed )
                                 END DO
                              END DO
*
                              IF ( iuplo.EQ.1 ) THEN
*
*                                The case IUPLO.EQ.1 is when SIDE.EQ.'U'
*                                -> QR factorization.
*
                                 srnamt = 'CGEQRF'
                                 CALL cgeqrf( na, na, a, lda, tau,
     +                                        c_work_cgeqrf, lda,
     +                                        info )
                              ELSE
*
*                                The case IUPLO.EQ.2 is when SIDE.EQ.'L'
*                                -> QL factorization.
*
                                 srnamt = 'CGELQF'
                                 CALL cgelqf( na, na, a, lda, tau,
     +                                        c_work_cgeqrf, lda,
     +                                        info )
                              END IF
*
*                             After the QR factorization, the diagonal
*                             of A is made of real numbers, we multiply
*                             by a random complex number of absolute
*                             value 1.0E+00.
*
                              DO j = 1, na
                                 a( j, j) = a(j,j) * clarnd( 5, iseed )
                              END DO
*
*                             Store a copy of A in RFP format (in ARF).
*
                              srnamt = 'CTRTTF'
                              CALL ctrttf( cform, uplo, na, a, lda, arf,
     +                                     info )
*
*                             Generate B1 our M--by--N right-hand side
*                             and store a copy in B2.
*
                              DO j = 1, n
                                 DO i = 1, m
                                    b1( i, j) = clarnd( 4, iseed )
                                    b2( i, j) = b1( i, j)
                                 END DO
                              END DO
*
*                             Solve op( A ) X = B or X op( A ) = B
*                             with CTRSM
*
                              srnamt = 'CTRSM'
                              CALL ctrsm( side, uplo, trans, diag, m, n,
     +                               alpha, a, lda, b1, lda )
*
*                             Solve op( A ) X = B or X op( A ) = B
*                             with CTFSM
*
                              srnamt = 'CTFSM'
                              CALL ctfsm( cform, side, uplo, trans,
     +                                    diag, m, n, alpha, arf, b2,
     +                                    lda )
*
*                             Check that the result agrees.
*
                              DO j = 1, n
                                 DO i = 1, m
                                    b1( i, j) = b2( i, j ) - b1( i, j )
                                 END DO
                              END DO
*
                              result(1) = clange( 'I', m, n, b1, lda,
     +                                            s_work_clange )
*
                              result(1) = result(1) / sqrt( eps )
     +                                    / max( max( m, n), 1 )
*
                              IF( result(1).GE.thresh ) THEN
                                 IF( nfail.EQ.0 ) THEN
                                    WRITE( nout, * )
                                    WRITE( nout, fmt = 9999 )
                                 END IF
                                 WRITE( nout, fmt = 9997 ) 'CTFSM',
     +                              cform, side, uplo, trans, diag, m,
     +                              n, result(1)
                                 nfail = nfail + 1
                              END IF
*
  100                      CONTINUE
  110                   CONTINUE
  120                CONTINUE
  130             CONTINUE
  140          CONTINUE
  150       CONTINUE
  160    CONTINUE
  170 CONTINUE
*
*     Print a summary of the results.
*
      IF ( nfail.EQ.0 ) THEN
         WRITE( nout, fmt = 9996 ) 'CTFSM', nrun
      ELSE
         WRITE( nout, fmt = 9995 ) 'CTFSM', nfail, nrun
      END IF
*
 9999 FORMAT( 1x, ' *** Error(s) or Failure(s) while testing CTFSM
     +         ***')
 9997 FORMAT( 1x, '     Failure in ',a5,', CFORM=''',a1,''',',
     + ' SIDE=''',a1,''',',' UPLO=''',a1,''',',' TRANS=''',a1,''',',
     + ' DIAG=''',a1,''',',' M=',i3,', N =', i3,', test=',g12.5)
 9996 FORMAT( 1x, 'All tests for ',a5,' auxiliary routine passed the ',
     +        'threshold ( ',i5,' tests run)')
 9995 FORMAT( 1x, a6, ' auxiliary routine: ',i5,' out of ',i5,
     +        ' tests failed to pass the threshold')
*
      RETURN
*
*     End of CDRVRF3
*
      END