cevec3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cevec3         ../engine/source/elements/shell/coque/cevec3.F
!||--- called by ------------------------------------------------------
!||    cforc3         ../engine/source/elements/shell/coque/cforc3.F
!||--- calls      -----------------------------------------------------
!||    cortdir3       ../engine/source/elements/shell/coque/cortdir3.F
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod   ../common_source/modules/mat_elem/elbufdef_mod.F90
!||====================================================================
      SUBROUTINE cevec3(ELBUF_STR,DIR_A  ,DIR_B  ,
     1    JFT,JLT,X1 ,X2 ,X3 ,X4 ,Y1 ,Y2 ,Y3 ,Y4  ,
     2    Z1 ,Z2 ,Z3 ,Z4 ,E1X,E1Y,E1Z,E2X,E2Y, E2Z, 
     3    E3X,E3Y,E3Z,IREP,NLAY,NEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT,J,IREP,NLAY,NEL
      my_real
     .   X1(*), X2(*), X3(*), X4(*), Y1(*), Y2(*), Y3(*), Y4(*),
     .   z1(*), z2(*), z3(*), z4(*), e1x(*), e1y(*), e1z(*), e2x(*),
     .   e2y(*), e2z(*), e3x(*), e3y(*), e3z(*), dir_a(*),dir_b(*)
      TYPE (ELBUF_STRUCT_) :: ELBUF_STR
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
C     REAL
      my_real
     .   x31(mvsiz), y31(mvsiz), z31(mvsiz), x42(mvsiz), y42(mvsiz),
     .   z42(mvsiz), x21(mvsiz), y21(mvsiz), z21(mvsiz),
     .   sum(mvsiz), suma
C=======================================================================
      DO i=jft,jlt                                      
        x21(i)=x2(i)-x1(i)                              
        y21(i)=y2(i)-y1(i)                              
        z21(i)=z2(i)-z1(i)                              
        x31(i)=x3(i)-x1(i)                              
        y31(i)=y3(i)-y1(i)                              
        z31(i)=z3(i)-z1(i)                              
        x42(i)=x4(i)-x2(i)                              
        y42(i)=y4(i)-y2(i)                              
        z42(i)=z4(i)-z2(i)                              
C
        e3x(i)=y31(i)*z42(i)-z31(i)*y42(i)              
        e3y(i)=z31(i)*x42(i)-x31(i)*z42(i)              
        e3z(i)=x31(i)*y42(i)-y31(i)*x42(i)              
        suma=e3x(i)*e3x(i)+e3y(i)*e3y(i)+e3z(i)*e3z(i)  
        suma=max(sqrt(suma),em20)                       
        e3x(i)=e3x(i)/suma                              
        e3y(i)=e3y(i)/suma                              
        e3z(i)=e3z(i)/suma                              
      ENDDO                                             
C
      DO i=jft,jlt                                       
        suma= x21(i)*e3x(i)+y21(i)*e3y(i)+z21(i)*e3z(i)  
        e1x(i)= x21(i)-e3x(i)*suma                       
        e1y(i)= y21(i)-e3y(i)*suma                       
        e1z(i)= z21(i)-e3z(i)*suma                       
      ENDDO                                              
C
      DO i=jft,jlt                                      
        suma=e1x(i)*e1x(i)+e1y(i)*e1y(i)+e1z(i)*e1z(i)  
        suma=max(sqrt(suma),em20)                       
        e1x(i)=e1x(i)/suma                              
        e1y(i)=e1y(i)/suma                              
        e1z(i)=e1z(i)/suma                              
      ENDDO                                             
C
      DO i=jft,jlt                                        
        e2x(i)=e3y(i)*e1z(i)-e3z(i)*e1y(i)                
        e2y(i)=e3z(i)*e1x(i)-e3x(i)*e1z(i)                
        e2z(i)=e3x(i)*e1y(i)-e3y(i)*e1x(i)                
        suma  =e2x(i)*e2x(i)+e2y(i)*e2y(i)+e2z(i)*e2z(i)  
        suma  =max(sqrt(suma),em20)                       
        e2x(i)=e2x(i)/suma                                
        e2y(i)=e2y(i)/suma                                
        e2z(i)=e2z(i)/suma                                
      ENDDO                                               
C
C---  directions orthotropie / anisotropie convectes
C
      CALL cortdir3(elbuf_str,dir_a,dir_b  ,jft    ,jlt    ,
     .              nlay   ,irep   ,x21    ,y21    ,z21    ,
     .              x31    ,y31    ,z31    ,e1x    ,e1y    ,   
     .              e1z    ,e2x    ,e2y    ,e2z    ,nel    )
C-----------
      RETURN
      END