cholfact.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cholfact         ../engine/source/tools/lagmul/cholfact.F
!||--- called by ------------------------------------------------------
!||    lag_mult_sdp     ../engine/source/tools/lagmul/lag_mult_solv.F
!||    lag_mult_solv    ../engine/source/tools/lagmul/lag_mult_solv.F
!||    lag_mult_solvp   ../engine/source/tools/lagmul/lag_mult_solv.F
!||====================================================================
      INTEGER FUNCTION cholfact(N,DIAG,H,IADH,JCIH,WCOL,IROW,JCOL)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER n, iadh(*),jcih(*),irow(*),jcol(*)
      my_real diag(*),h(*),wcol(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER i, j, k, isk, iek, isj, iej, ic, iptr
      my_real lval, t
C======================================================================|
      DO j = 1, n
        irow(j) = 0
        jcol(j) = 0
      ENDDO
C---
      DO k = 1,n
        isk = iadh(k)
        iek = iadh(k+1)-1
        DO j = isk, iek
          ic = jcih(j)
          wcol(ic) = h(j)
          irow(ic) = 1
        ENDDO
C---
        IF (diag(k)<=0.) GOTO 999
        diag(k) = sqrt(diag(k))
C---
        j = jcol(k)
100     CONTINUE
        IF (j==0) GOTO 200
          isj = irow(j)
          iej = iadh(j+1)-1
          lval = h(isj)
          isj = isj + 1
          IF (isj<iej) THEN
            irow(j) = isj
            iptr = j
            j = jcol(j)
            jcol(iptr) = jcol(jcih(isj))
            jcol(jcih(isj)) = iptr
          ELSE
            j = jcol(j)
          ENDIF
          DO i = isj, iej
            ic = jcih(i)
            IF (irow(ic)/=0) THEN
              wcol(ic) = wcol(ic) - lval*h(i)
            ENDIF
          ENDDO
        GOTO 100
200     CONTINUE
C---
        IF (isk<iek) THEN
          iptr = jcih(isk)
          jcol(k) = jcol(iptr)
          jcol(iptr) = k
          irow(k) = isk
        ENDIF
C---
        DO j = isk, iek
          ic = jcih(j)
          t = wcol(ic)/diag(k)
          diag(ic) = diag(ic) - t*t
          h(j) = t
          irow(ic) = 0
        ENDDO
      ENDDO
C----
      cholfact = 0
      RETURN
999   CONTINUE
      cholfact = k
C-----------------------------------------------
      RETURN
      END
      
!||====================================================================
!||    prechol          ../engine/source/tools/lagmul/cholfact.F
!||--- called by ------------------------------------------------------
!||    lag_mult_solv    ../engine/source/tools/lagmul/lag_mult_solv.F
!||    lag_mult_solvp   ../engine/source/tools/lagmul/lag_mult_solv.F
!||====================================================================
      SUBROUTINE prechol(Z,D,L,R,NC,IADH,JCIH)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NC,IADH(*),JCIH(*)
      my_real
     .    z(*),d(*),l(*),r(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,IH
      my_real s
C======================================================================|
C--- back subst Ly = r
      DO i=1,nc
        z(i) = r(i)
      ENDDO
      DO i=1,nc
        z(i) = z(i) / d(i)
        DO ih=iadh(i),iadh(i+1)-1
          j = jcih(ih)
          z(j) = z(j) - l(ih)*z(i)
        ENDDO
      ENDDO
C--- back subst LT z = y
      DO i=nc,1,-1
        s = z(i)
        DO ih=iadh(i),iadh(i+1)-1
          j = jcih(ih)
          s = s - l(ih)*z(j)
        ENDDO
        z(i) = s / d(i)
      ENDDO
C-----------------------------------------------
      RETURN
      END