cm1inif.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cm1inif    ../starter/source/elements/shell/coque/cm1inif.F
!||--- called by ------------------------------------------------------
!||    fsigcini   ../starter/source/constraints/fxbody/fsigcini.F
!||    fsigtini   ../starter/source/constraints/fxbody/fsigtini.F
!||====================================================================
      SUBROUTINE cm1inif(JFT  ,JLT  ,FOR  ,MOM  ,ITHK ,
     .                   THK  ,EINT ,NU   ,G    ,A1   , 
     .                   A2   ,GS   ,KXX  ,KYY  ,KXY  ,
     .                   EXX  ,EYY  ,EXY  ,EYZ  ,EXZ  ,
     .                   AREA )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JFT, JLT, ITHK
      my_real
     .    EXX(MVSIZ) , EYY(MVSIZ) , EXY(MVSIZ) , 
     .    EXZ(MVSIZ) , EYZ(MVSIZ) , KXX(MVSIZ) ,
     .    kyy(mvsiz) , kxy(mvsiz) , area(mvsiz)
      my_real
     .   for(5,*) ,mom(3,*), thk(*), eint(2,*), nu(*),
     .   g(*), a1(*), a2(*), gs(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real THK08, EZZ,
     .    DEGMB(MVSIZ), DEGFX(MVSIZ), B1(MVSIZ), B2(MVSIZ), B3(MVSIZ)
C=======================================================================
      DO i=jft,jlt
        thk08  =thk(i)*one_over_12
        b1(i)  =a1(i)*thk08
        b2(i)  =a2(i)*thk08
        b3(i)  =g(i) *thk08
      ENDDO
C
      DO i=jft,jlt
        for(1,i)=a1(i)*exx(i)+a2(i)*eyy(i)
        for(2,i)=a1(i)*eyy(i)+a2(i)*exx(i)
        for(3,i)=g(i) *exy(i)
        for(4,i)=gs(i)*eyz(i)
        for(5,i)=gs(i)*exz(i)
C
        mom(1,i)=b1(i)*kxx(i)+b2(i)*kyy(i)
        mom(2,i)=b1(i)*kyy(i)+b2(i)*kxx(i)
        mom(3,i)=b3(i)*kxy(i)
      ENDDO
C
      DO i=jft,jlt
        degmb(i) = for(1,i)*exx(i)+for(2,i)*eyy(i)+for(3,i)*exy(i)
        degfx(i) = mom(1,i)*kxx(i)+mom(2,i)*kyy(i)
     +                   +mom(3,i)*kxy(i)
        eint(1,i) = degmb(i)*half*thk(i)*area(i)
        eint(2,i) = degfx(i)*half*thk(i)*thk(i)*area(i)
      ENDDO
      IF(ithk==1) THEN
        DO i=jft,jlt
          ezz = -nu(i) * (exx(i) + eyy(i)) / (one-nu(i))
          thk(i) = thk(i) * (one + ezz)
        ENDDO
      ENDIF
C-----------
      RETURN
      END