cr_spline_point_proj.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    cr_spline_point_proj   ../common_source/tools/interpolation/cr_spline_point_proj.F
!||--- called by ------------------------------------------------------
!||    detcord                ../starter/source/initial_conditions/detonation/detcord.F
!||--- calls      -----------------------------------------------------
!||    cr_spline_interpol     ../common_source/tools/interpolation/cr_spline_interpol.F
!||    cr_spline_knots        ../common_source/tools/interpolation/cr_spline_knots.F
!||====================================================================
      SUBROUTINE cr_spline_point_proj(LOCAL_PT,Z,ALPHA,Zh,h,T)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
        !COMPUTE PROJECTION ZH ON A GIVEN POINT Z ALONG THE SPLINE INTERPOLATION
        !  INPUT  - LOCAL_PT : 4 control points P0,P1,P2,P3
        !  INPUT  - Z : TEST POINt to project
        !  INPUT  - ALPHA : CCR SPLINE PARAMETER
        !  OUTPUT - Zh : projected point
        !  OUTPUT - H : distance from spline
        !  OUTPUT - T : position [0,1] on SPLINE [T1,T2]
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
        my_real,INTENT(IN)    :: local_pt(4,3),z(3),alpha
        my_real,INTENT(INOUT) :: zh(3),h
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
        my_real               :: knots(4),c(3),c_d(3),c_dd(3),t
        my_real               :: f,f_d
        INTEGER            :: ITER
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
        t = 0.5
        CALL cr_spline_knots(local_pt, knots, alpha)
        DO iter=1,20
          CALL cr_spline_interpol(local_pt,knots,t,c,c_d,c_dd)
          f   = dot_product(c(1:3)-z(1:3), c_d(1:3))
          f_d = dot_product(c_d(1:3), c_d(1:3)) + dot_product(c(1:3)-z(1:3), c_dd(1:3))
          IF(f_d /= 0.)THEN
            t=t-f/f_d
          ELSE
            IF(f == 0.)EXIT
            print *, "/DFS/DETCORD : error, convergence issue"
            stop 220022
          ENDIF
          IF(t<0.)t=1e-10
          IF(t>1.)t=1.-1e-10
        ENDDO
        CALL cr_spline_interpol(local_pt,knots,t,c,c_d,c_dd)
        zh(1:3) = c(1:3)
        h=sqrt(dot_product(c(1:3)-z(1:3),c(1:3)-z(1:3)))
      END SUBROUTINE cr_spline_point_proj