create_line_from_element.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    create_line_from_element   ../starter/source/model/sets/create_line_from_element.F
!||--- called by ------------------------------------------------------
!||    create_box_clause          ../starter/source/model/sets/create_box_clause.F
!||    hm_set                     ../starter/source/model/sets/hm_set.F
!||    insert_clause_in_set       ../starter/source/model/sets/insert_clause_in_set.F
!||--- calls      -----------------------------------------------------
!||    line_buffer                ../starter/source/model/sets/line_buffer.F
!||--- uses       -----------------------------------------------------
!||    message_mod                ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE create_line_from_element(IXT     ,IXP  ,IXR  ,CLAUSE ,DELBUF,
     .                                    GO_IN_ARRAY)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE my_alloc_mod
      USE setdef_mod
      USE message_mod
      USE set_scratch_mod
      use element_mod , only : nixt,nixp,nixr
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: IXT(NIXT,*),IXP(NIXP,*),IXR(NIXR,*)
!
      TYPE (SET_) :: CLAUSE
      TYPE (SET_SCRATCH) ::  DELBUF
      LOGICAL GO_IN_ARRAY
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, NIX, SZELMAX, IAD_LINE, NSEG, LINE_NENTITY
      INTEGER IWORK(70000)
!
      INTEGER, ALLOCATABLE, DIMENSION(:,:) :: ITRI
      INTEGER, ALLOCATABLE, DIMENSION(:) :: INDEX, BUFTMPLINE
C=======================================================================
      delbuf%SZ_LINE = 0
!
!!      SZELMAX = MAX(CLAUSE%NB_TRUSS,CLAUSE%NB_BEAM,CLAUSE%NB_SPRING)
      szelmax = clause%NB_TRUSS + clause%NB_BEAM + clause%NB_SPRING
      IF (szelmax == 0) RETURN
!
      line_nentity = 4 ! NOD1, NOD2, ELTYP, ELEM
      ALLOCATE(buftmpline(szelmax*line_nentity))
      ALLOCATE(itri(3,szelmax))
      ALLOCATE(index(2*szelmax))
!
      iad_line = 1
!------------------
!----
!     ! temporary line segments got from elements
      nseg = 0
      CALL line_buffer(
     .             ixt      ,ixp    ,ixr  ,buftmpline ,  nseg,
     .             iad_line ,clause )
!----
!
      nix = line_nentity
!
      DO  i=1,nseg
        index(i)=i
        itri(1,i) = buftmpline((i-1)*nix+1)
        itri(2,i) = buftmpline((i-1)*nix+2)
        itri(3,i) = buftmpline((i-1)*nix+4)
      ENDDO
      iwork(1:70000) = 0
      CALL my_orders(0,iwork,itri,index,nseg,3)
!---
!     clause surf allocation
!---
!------------------
!
! Decide whether the result is stored in an array or in the clause.
! In certain cases it is useful to store in ARRAY.
! Example : Clause with delete clause. Lines must be recreated & merged...
! ----------------------------------------------------------------------------
      IF (go_in_array .EQV. .true.) THEN
        delbuf%SZ_LINE = nseg
        ALLOCATE(delbuf%LINE(nseg,4))
        DO i=1,nseg
          delbuf%LINE(i,1) = buftmpline((index(i)-1)*nix+1)
          delbuf%LINE(i,2) = buftmpline((index(i)-1)*nix+2)
          delbuf%LINE(i,3) = buftmpline((index(i)-1)*nix+3)
          delbuf%LINE(i,4) = buftmpline((index(i)-1)*nix+4)
        ENDDO
      ELSE
        IF(ALLOCATED( clause%LINE_NODES )) DEALLOCATE( clause%LINE_NODES )
        IF(ALLOCATED( clause%LINE_ELTYP )) DEALLOCATE( clause%LINE_ELTYP )
        IF(ALLOCATED( clause%LINE_ELEM ))  DEALLOCATE( clause%LINE_ELEM )
!
        clause%NB_LINE_SEG = nseg
        CALL my_alloc(clause%LINE_NODES,nseg,2)
        CALL my_alloc(clause%LINE_ELTYP,nseg)
        CALL my_alloc(clause%LINE_ELEM,nseg)
!
        DO i=1,nseg
          clause%LINE_NODES(i,1) = buftmpline((index(i)-1)*nix+1)
          clause%LINE_NODES(i,2) = buftmpline((index(i)-1)*nix+2)
          clause%LINE_ELTYP(i)   = buftmpline((index(i)-1)*nix+3)
          clause%LINE_ELEM(i)    = buftmpline((index(i)-1)*nix+4)
        ENDDO
      ENDIF ! IF (GO_IN_ARRAY .EQV. .TRUE.)
!------------------
      IF(ALLOCATED(itri))       DEALLOCATE(itri)
      IF(ALLOCATED(index))      DEALLOCATE(index)
      IF(ALLOCATED(buftmpline)) DEALLOCATE(buftmpline)
!------------------
!-----------
      RETURN
      END