create_node_from_element.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    create_node_from_element        ../starter/source/model/sets/create_node_from_element.F
!||--- called by ------------------------------------------------------
!||    hm_set                          ../starter/source/model/sets/hm_set.F
!||--- calls      -----------------------------------------------------
!||    tag_node_from_1d_2d_elem        ../starter/source/model/sets/tag_node_from_1D_2D_elem.F
!||    tag_node_from_part_sphcel       ../starter/source/model/sets/tag_node_from_part_sphcel.F90
!||    tag_node_from_solid             ../starter/source/model/sets/tag_node_from_solid.f
!||    tag_node_from_spring            ../starter/source/model/sets/tag_node_from_spring.F
!||--- uses       -----------------------------------------------------
!||    message_mod                     ../starter/share/message_module/message_mod.F
!||    tag_node_from_part_sphcel_mod   ../starter/source/model/sets/tag_node_from_part_sphcel.F90
!||====================================================================
      SUBROUTINE create_node_from_element(
     .                            IXS   ,IXS10  ,IXS20  ,IXS16  ,IXQ    ,
     .                            IXC   ,IXTG   ,IXT    ,IXP    ,IXR    ,
     .                            IXX   ,KXX    ,KXSP   ,CLAUSE ,GEO,
     .                            ARRAY ,SZ     ,GO_IN_ARRAY    )
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE setdef_mod
      USE tag_node_from_part_sphcel_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "sphcom.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXS(NIXS,*),IXS10(6,*),IXS16(8,*),IXS20(12,*),
     .        IXQ(NIXQ,*),IXC(NIXC,*),IXTG(NIXTG,*),IXT(NIXT,*),
     .        IXP(NIXP,*),IXR(NIXR,*),IXX(*),KXX(*),KXSP(NISP,*)
      my_real
     .        geo(npropg,*)
!
      TYPE (SET_) ::  CLAUSE
      INTEGER ARRAY(*),SZ
      LOGICAL GO_IN_ARRAY
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IND,LIMIT
      INTEGER, ALLOCATABLE, DIMENSION(:) :: TAGNOD,CLAUSE_NODE
      INTEGER IWORK(70000)
      INTEGER, DIMENSION(:),ALLOCATABLE:: IDX,SORT
C=======================================================================
!
      ALLOCATE(tagnod(numnod))
      tagnod(:) = 0
      ALLOCATE(clause_node(numnod))
 
      ind=0
!
      ! SOLID
      IF ( clause%NB_SOLID > 0 )
     . CALL tag_node_from_solid(
     .                         ixs   ,ixs10  ,ixs20  ,ixs16   ,clause%NB_SOLID ,
     .                         clause%SOLID  ,tagnod ,clause_node,ind )
      ! QUAD
      IF ( clause%NB_QUAD > 0 )
     . CALL tag_node_from_1d_2d_elem(
     .                         ixq         ,nixq   ,2     ,5    ,clause%NB_QUAD,
     .                         clause%QUAD ,tagnod,clause_node,ind )
      ! SH4N
      IF ( clause%NB_SH4N > 0 )
     . CALL tag_node_from_1d_2d_elem(
     .                         ixc         ,nixc   ,2     ,5    ,clause%NB_SH4N,
     .                         clause%SH4N ,tagnod,clause_node,ind  )
      ! SH3N
      IF ( clause%NB_SH3N > 0 .AND. clause%NB_TRIA == 0 )
     . CALL tag_node_from_1d_2d_elem(
     .                         ixtg        ,nixtg  ,2     ,4    ,clause%NB_SH3N,
     .                         clause%SH3N ,tagnod,clause_node,ind  )
      ! TRIA
      IF ( clause%NB_TRIA > 0 )
     . CALL tag_node_from_1d_2d_elem(
     .                         ixtg        ,nixtg  ,2     ,4    ,clause%NB_TRIA,
     .                         clause%TRIA ,tagnod,clause_node,ind  )
      ! TRUSS
      IF ( clause%NB_TRUSS > 0 )
     . CALL tag_node_from_1d_2d_elem(
     .                         ixt         ,nixt   ,2     ,3   ,clause%NB_TRUSS,
     .                         clause%TRUSS,tagnod,clause_node,ind  )
      ! BEAM
      IF ( clause%NB_BEAM > 0 )
     . CALL tag_node_from_1d_2d_elem(
     .                         ixp         ,nixp   ,2     ,3   ,clause%NB_BEAM,
     .                         clause%BEAM ,tagnod,clause_node,ind  )
      ! SPRING
      IF ( clause%NB_SPRING > 0 )
     . CALL tag_node_from_spring(
     .                   ixr   ,geo  ,clause%NB_SPRING  ,clause%SPRING  ,tagnod,clause_node,ind)
!
!
!   ATTENTION --- PARTS SPH are not inverted
!
!
      ! SPH
      IF ( clause%NB_SPHCEL > 0 )
     . CALL tag_node_from_part_sphcel(
     .                   clause%NB_SPHCEL  ,clause%SPHCEL  ,tagnod,clause_node,ind,numnod)
!      IF (NUMSPH > 0) 
!     .    CALL TAGNOD_PART(KXSP,NISP,3,3,NUMSPH,IPARTSP,TAGPART,TAGNOD)
C-----------
      limit = numnod/2
      IF (ind < limit)THEN                                  ! cheaper to use Order on small node groups
        ALLOCATE(idx(2*ind))
        ALLOCATE(sort(ind))
        sort(1:ind) = clause_node(1:ind)
        CALL my_orders(0,iwork,sort,idx,ind,1)
 
        DO i=1,ind
          clause_node(i) = sort(idx(i))
        ENDDO
        DEALLOCATE(idx)
        DEALLOCATE(sort)
      ELSE
       ind = 0
       DO i=1,numnod
         IF (tagnod(i) == 1) THEN
           ind = ind + 1
           clause_node(ind) = i
         ENDIF
       ENDDO
      ENDIF
!
! Decide whether the result is stored in an array or in the clause.
! In certain cases it is useful to store in ARRAY.
! example : clause with delete clause. nodes must be recreated & merged...
! ----------------------------------------------------------------------------
       IF (go_in_array .EQV. .true.) THEN
        sz = ind
        array(1:ind) = clause_node(1:ind)
       ELSE
        ! clause node allocation
        sz=0
        clause%NB_NODE = ind
        IF(ALLOCATED( clause%NODE )) DEALLOCATE( clause%NODE )
        ALLOCATE( clause%NODE(ind) )
        clause%NODE(1:ind) = clause_node(1:ind)
      ENDIF
C-----------
      DEALLOCATE(tagnod)
      DEALLOCATE(clause_node)
C-----------
      RETURN
      END