create_seg_clause.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    create_seg_clause           ../starter/source/model/sets/create_seg_clause.F
!||--- called by ------------------------------------------------------
!||    hm_set                      ../starter/source/model/sets/hm_set.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                      ../starter/source/output/message/message.F
!||    hm_get_int_array_2indexes   ../starter/source/devtools/hm_reader/hm_get_int_array_2indexes.F
!||    hm_get_int_array_index      ../starter/source/devtools/hm_reader/hm_get_int_array_index.F
!||    set_usrtos                  ../starter/source/model/sets/ipartm1.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod          ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod                 ../starter/share/message_module/message_mod.F
!||    submodel_mod                ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE create_seg_clause(CLAUSE,  ITABM1  ,JCLAUSE ,IS_AVAILABLE ,LSUBMODEL)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C   ===================
C   Create PART Clause from LIST
C-----------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C     CLAUSE        (SET structure) Clause to be treated
C     IPARTM1       MAP Table UID -> LocalID
C     JCLAUSE       parameter with HM_READER (current clause read)
C     IS_AVAILABLE  Bool / Result of HM_interface
C     LSUBMODEL     SUBMODEL Structure.
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE setdef_mod
      USE submodel_mod
      USE message_mod
      USE hm_option_read_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER JCLAUSE
      LOGICAL :: IS_AVAILABLE
      INTEGER, INTENT(IN), DIMENSION(NUMNOD,2) :: ITABM1
      TYPE (SET_) ::  CLAUSE
      TYPE(submodel_data),INTENT(IN):: LSUBMODEL(NSUBMOD)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, NINDX, SEG_MAX, NOD_1, NOD_2, NOD_3, NOD_4, NODSYS_1, NODSYS_2, NODSYS_3, NODSYS_4, SEG_ID, LINE_SEG
      INTEGER, ALLOCATABLE, DIMENSION(:,:) :: BUFSURF
      INTEGER,EXTERNAL :: SET_USRTOS
C-----------------------------------------------
C   S o u r c e  L i n e s
C-----------------------------------------------
      line_seg = 0
      CALL hm_get_int_array_index('segmax' ,seg_max ,jclause,is_available,lsubmodel)
      ALLOCATE(bufsurf(4,seg_max))
      nindx = 0
!
      ! Read & convert Segs
      ! ---------------------
      DO i=1,seg_max  ! always = 1 for clause 'SEG'
        CALL hm_get_int_array_2indexes('segid',seg_id,jclause ,i,is_available,lsubmodel)
        CALL hm_get_int_array_2indexes('ids1' ,nod_1 ,jclause ,i,is_available,lsubmodel)
        CALL hm_get_int_array_2indexes('ids2' ,nod_2 ,jclause ,i,is_available,lsubmodel)
        CALL hm_get_int_array_2indexes('ids3' ,nod_3 ,jclause ,i,is_available,lsubmodel)
        CALL hm_get_int_array_2indexes('ids4' ,nod_4 ,jclause ,i,is_available,lsubmodel)
        nodsys_1 = set_usrtos(nod_1,itabm1,numnod)
        IF (nodsys_1 == 0) THEN
           ! Node was not found. Issue an error.
           CALL ancmsg(msgid=1903,anmode=aninfo,msgtype=msgerror,
     .                             i1 = clause%SET_ID,
     .                             i2=seg_id,
     .                             i3=nod_1,
     .                             c1=trim(clause%TITLE),
     .                             c2='NODE')
        ELSE
          nodsys_1 = itabm1(nodsys_1,2)
        ENDIF
 
        nodsys_2 = set_usrtos(nod_2,itabm1,numnod)
        IF (nodsys_2 == 0) THEN
          ! Node was not found. Issue an error.
           CALL ancmsg(msgid=1903,anmode=aninfo,msgtype=msgerror,
     .                             i1 = clause%SET_ID,
     .                             i2=seg_id,
     .                             i3=nod_2,
     .                             c1=trim(clause%TITLE),
     .                             c2='NODE')
        ELSE
          nodsys_2 = itabm1(nodsys_2,2)
        ENDIF
        
        line_seg = 0
        IF (nod_3 == 0 .AND. nod_4 == 0) THEN
          line_seg = 1 ! Line SEG
          nodsys_3 = 0
          nodsys_4 = 0
        ELSE
          nodsys_3 = set_usrtos(nod_3,itabm1,numnod)
          nodsys_4 = set_usrtos(nod_4,itabm1,numnod)
        ENDIF
 
        IF (line_seg == 0) then! Surf seg -> continues node check existence
          IF (nodsys_3 == 0) THEN
            ! Node was not found. Issue an error.
            CALL ancmsg(msgid=1903,anmode=aninfo,msgtype=msgerror,
     .                             i1 = clause%SET_ID,
     .                             i2=seg_id,
     .                             i3=nod_3,
     .                             c1=trim(clause%TITLE),
     .                             c2='NODE')
          ELSE
            ! Node found
            nodsys_3 = itabm1(nodsys_3,2)
          ENDIF
 
          IF (nod_4 == 0) THEN 
            ! correction to allow for 3 noded surface (triangle)
              nodsys_4 = nodsys_3
          ELSE IF (nodsys_4 == 0) THEN
            ! Node was not found. Issue an error.
            CALL ancmsg(msgid=1903,anmode=aninfo,msgtype=msgerror,
     .                             i1 = clause%SET_ID,
     .                             i2=seg_id,
     .                             i3=nod_4,
     .                             c1=trim(clause%TITLE),
     .                             c2='NODE')
          ELSE IF (nodsys_4 /= 0) THEN
            ! Node found
              nodsys_4 =  itabm1(nodsys_4,2)
          ENDIF
 
        ENDIF ! IF (LINE_SEG == 0)
 
        nindx = nindx+1    !   nb of CLAUSE SEGs
        bufsurf(1,nindx) = nodsys_1
        bufsurf(2,nindx) = nodsys_2
        bufsurf(3,nindx) = nodsys_3
        bufsurf(4,nindx) = nodsys_4
 
      ENDDO ! DO I=1,SEG_MAX
 
      ! Copy in final SET
      ! ------------------
 
      !------------------------------------!
      !  create SURF clause or LINE clause !
      !------------------------------------!
 
      IF (line_seg == 0) THEN
 
        ! SURF seg (4-node SEG)
        clause%NB_SURF_SEG = nindx
        ALLOCATE(clause%SURF_NODES(nindx,4))
        ALLOCATE(clause%SURF_ELTYP(nindx))
        ALLOCATE(clause%SURF_ELEM(nindx))
 
        DO i=1,nindx
          clause%SURF_NODES(i,1) = bufsurf(1,i) ! N1
          clause%SURF_NODES(i,2) = bufsurf(2,i) ! N2
          clause%SURF_NODES(i,3) = bufsurf(3,i) ! N3
          clause%SURF_NODES(i,4) = bufsurf(4,i) ! N4
          clause%SURF_ELTYP(i)   = 0  ! ELTYP
          clause%SURF_ELEM(i)    = 0  ! ELEM
        ENDDO
 
      ELSE
 
        ! LINE seg (2-node SEG)
        clause%NB_LINE_SEG = nindx
        ALLOCATE(clause%LINE_NODES(nindx,2))
        ALLOCATE(clause%LINE_ELTYP(nindx))
        ALLOCATE(clause%LINE_ELEM(nindx))
 
        DO i=1,nindx
          clause%LINE_NODES(i,1) = bufsurf(1,i) ! N1
          clause%LINE_NODES(i,2) = bufsurf(2,i) ! N2
          clause%LINE_ELTYP(i)   = 0  ! ELTYP
          clause%LINE_ELEM(i)    = 0  ! ELEM
        ENDDO
 
      ENDIF ! IF (LINE_SEG == 0)
 
C-------------------------
      DEALLOCATE(bufsurf)
C-------------------------
      RETURN
      END