czstrah3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    czstrah3   ../engine/source/elements/shell/coquez/czstrah3.F
!||--- called by ------------------------------------------------------
!||    czforc3    ../engine/source/elements/shell/coquez/czforc3.F
!||====================================================================
      SUBROUTINE czstrah3(JFT    ,JLT    ,STRA_H,VHG    ,A_I   ,
     3                    MX23   ,MX34   ,MY23  ,MY34   ,DT1C  ,
     4                    EXX    ,EYY    ,EXY   ,EXZ    ,EYZ   ,  
     3                    KXX    ,KYY    ,KXY   ,NEL    )
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: JFT, JLT,NEL
      my_real, DIMENSION(MVSIZ),INTENT(IN) :: A_I,
     .                    DT1C,MX23,MX34,MY23,MY34,
     .                    exx,eyy,exy,exz,eyz,  
     .                    kxx ,kyy ,kxy 
      my_real, DIMENSION(MVSIZ,6),INTENT(IN) :: vhg
      my_real, DIMENSION(NEL,8,4),INTENT(INOUT) :: stra_h
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER PT,PT00,PT0,I,J,EP,IUN,NG,K,NPG
      MY_REAL 
     .   HX(MVSIZ),HY(MVSIZ),DHG(MVSIZ,6),PG1,PG,VPG(2,4)
      my_real 
     .   a4_1(mvsiz),a_4(mvsiz),strain(8),hxz(mvsiz),hyz(mvsiz)
       PARAMETER (pg=.577350269189626)
       parameter(pg1=-.577350269189626)
      DATA vpg/pg1,pg1,pg,pg1,pg,pg,pg1,pg/  ! VPG(1:2,4):ksi,eta
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--
      npg =4
      a4_1(jft:jlt) = four*a_i(jft:jlt)
      a_4(jft:jlt) = fourth*a_i(jft:jlt)
      DO j=1,6
        dhg(jft:jlt,j) = vhg(jft:jlt,j) * dt1c(jft:jlt)
      ENDDO
      DO ng = 1,npg
        DO i=jft,jlt          
          hx(i) = a4_1(i)*(my34(i)*vpg(2,ng)- my23(i)*vpg(1,ng))
          hy(i) = a4_1(i)*(-mx34(i)*vpg(2,ng)+mx23(i)*vpg(1,ng))
          hxz(i)= a_4(i)*(my34(i)*vpg(2,ng)*dhg(i,5)- my23(i)*vpg(1,ng)*dhg(i,6))
          hyz(i)= a_4(i)*(mx23(i)*vpg(1,ng)*dhg(i,5)- mx34(i)*vpg(2,ng)*dhg(i,6))
          strain(1) = exx(i) + hx(i)*dhg(i,1)
          strain(2) = eyy(i) + hy(i)*dhg(i,2)
          strain(3) = exy(i)  
          strain(6) = kxx(i) + hx(i)*dhg(i,3)
          strain(7) = kyy(i) + hy(i)*dhg(i,4)
          strain(8) = kxy(i)  
          strain(5) = exz(i) + hxz(i)
          strain(4) = eyz(i) + hyz(i)
          stra_h(i,1,ng) = stra_h(i,1,ng) + strain(1) 
          stra_h(i,2,ng) = stra_h(i,2,ng) + strain(2) 
          stra_h(i,3,ng) = stra_h(i,3,ng) + strain(3) 
          stra_h(i,4,ng) = stra_h(i,4,ng) + strain(4) 
          stra_h(i,5,ng) = stra_h(i,5,ng) + strain(5) 
          stra_h(i,6,ng) = stra_h(i,6,ng) + strain(6) 
          stra_h(i,7,ng) = stra_h(i,7,ng) + strain(7) 
          stra_h(i,8,ng) = stra_h(i,8,ng) + strain(8) 
        ENDDO
      ENDDO
C
      RETURN
      END