depla.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    depla   ../engine/source/assembly/depla.F
!||--- called by ------------------------------------------------------
!||    resol   ../engine/source/engine/resol.F
!||====================================================================
      SUBROUTINE depla(V, D, X, VR, DR, XDP, DDP, NUMNOD)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com08_c.inc"
#include      "scr03_c.inc"
#include      "scr05_c.inc"
#include      "scr06_c.inc"
#include      "scr16_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER, INTENT(IN) :: NUMNOD !< number of node
      my_real :: x(3,numnod) ,d(3,numnod) ,v(3,numnod) ,dr(3,numnod)  ,vr(3,numnod)
      DOUBLE PRECISION :: XDP(3,NUMNOD), DDP(3,NUMNOD)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER  I,N
      my_real vdt
      DOUBLE PRECISION VDT2
C-----------------------------------------------
C   B o d y
C-----------------------------------------------
      IF(n2d==1)THEN
!$OMP DO SCHEDULE(guided)
          DO i=1,numnod
            IF(x(2,i)+dt2*v(2,i)<zero) v(2,i)=zero
          ENDDO
!$OMP END DO
      ENDIF
C-------------------------------------------------------------
C         DISPLACEMENT (TRANSLATION & ROTATIONS)
C-------------------------------------------------------------
      IF (iresp==1) THEN
!$OMP DO SCHEDULE(guided)
        DO n=1,numnod
          vdt2 = dt2*v(1,n)
          ddp(1,n) = ddp(1,n)+vdt2
          d(1,n)=ddp(1,n)
          xdp(1,n)=xdp(1,n)+vdt2
          x(1,n)=xdp(1,n)
 
          vdt2 = dt2*v(2,n)
          ddp(2,n) = ddp(2,n)+vdt2
          d(2,n)=ddp(2,n)
          xdp(2,n)=xdp(2,n)+vdt2
          x(2,n)=xdp(2,n)
 
          vdt2 = dt2*v(3,n)
          ddp(3,n) = ddp(3,n)+vdt2
          d(3,n)=ddp(3,n)
          xdp(3,n)=xdp(3,n)+vdt2
          x(3,n)=xdp(3,n)
        ENDDO
!$OMP END DO NOWAIT
      ELSE
!$OMP DO SCHEDULE(guided)
         DO n=1,numnod
          vdt = dt2*v(1,n)
          d(1,n)=d(1,n)+vdt
          x(1,n)=x(1,n)+vdt
          vdt = dt2*v(2,n)
          d(2,n)=d(2,n)+vdt
          x(2,n)=x(2,n)+vdt
          vdt = dt2*v(3,n)
          d(3,n)=d(3,n)+vdt
          x(3,n)=x(3,n)+vdt
        ENDDO
!$OMP END DO NOWAIT
      ENDIF 
      IF((isecut>0 .OR. iisrot>0 .OR. impose_dr/=0 .OR. idrot == 1) .AND. iroddl /= 0) THEN
!$OMP DO SCHEDULE(guided)
        DO n=1,numnod
          dr(1,n)=dr(1,n)+dt2*vr(1,n)
          dr(2,n)=dr(2,n)+dt2*vr(2,n)
          dr(3,n)=dr(3,n)+dt2*vr(3,n)
        ENDDO
!$OMP END DO
      ENDIF
 
      RETURN
      END