diffusion__mod_8F_source.html

Copyright>        OpenRadioss

Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.

Copyright>

Copyright>        This program is free software: you can redistribute it and/or modify

Copyright>        it under the terms of the GNU Affero General Public License as published by

Copyright>        the Free Software Foundation, either version 3 of the License, or

Copyright>        (at your option) any later version.

Copyright>

Copyright>        This program is distributed in the hope that it will be useful,

Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of

Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

Copyright>        GNU Affero General Public License for more details.

Copyright>

Copyright>        You should have received a copy of the GNU Affero General Public License

Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.

Copyright>

Copyright>

Copyright>        Commercial Alternative: Altair Radioss Software

Copyright>

Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss

Copyright>        software under a commercial license.  Contact Altair to discuss further if the

Copyright>        commercial version may interest you: https://www.altair.com/radioss/.

!||====================================================================

!||    diffusion_mod       ../engine/share/modules/diffusion_mod.F

!||--- called by ------------------------------------------------------

!||    alemain             ../engine/source/ale/alemain.F

!||    ns_fvm_diffusion    ../engine/source/multifluid/ns_fvm_diffusion.F

!||    radioss2            ../engine/source/engine/radioss2.F

!||    resol               ../engine/source/engine/resol.F

!||    resol_head          ../engine/source/engine/resol_head.F

!||--- uses       -----------------------------------------------------

!||    linear_solver_mod   ../engine/share/modules/linear_solver_mod.F

!||    matrix_mod          ../common_source/linearalgebra/matrix_mod.F

!||    vector_mod          ../common_source/linearalgebra/vector_mod.F

!||====================================================================

      MODULE diffusion_mod

      USE linear_solver_mod

      USE matrix_mod

      USE vector_mod

      IMPLICIT NONE

#include "my_real.inc"

!     .___________________________.   !

!     |                           |   !

!     |   **********************  |   !

!     |   ** Type definitions **  |   !

!     |   **********************  |   !

!     |___________________________|   !


      TYPE :: t_diffusion

      CLASS(t_linear_solver), PRIVATE, POINTER :: linear_solver

      TYPE(t_cfs_matrix) :: mat

      TYPE(t_vector) :: rhs

      DOUBLE PRECISION, DIMENSION(:), ALLOCATABLE :: sol

      INTEGER, DIMENSION(:), ALLOCATABLE :: flag_outlet

      my_real, DIMENSION(:), ALLOCATABLE :: nu

      INTEGER :: nrhs

      LOGICAL :: outlet_flagged = .false.

      CONTAINS

      PROCEDURE, pass :: init_diffusion

      PROCEDURE, pass :: solve_diffusion

      PROCEDURE, pass :: terminate_diffusion

      PROCEDURE, pass :: get_solution

      END TYPE t_diffusion


!     ._____________________________.   !

!     |                             |   !

!     |   ************************  |   !

!     |   ** Interface routines **  |   !

!     |   ************************  |   !

!     |_____________________________|   !


      CONTAINS

!||====================================================================

!||    init_diffusion         ../engine/share/modules/diffusion_mod.F

!||--- calls      -----------------------------------------------------

!||--- uses       -----------------------------------------------------

!||    ale_connectivity_mod   ../common_source/modules/ale/ale_connectivity_mod.F

!||    linear_solver_mod      ../engine/share/modules/linear_solver_mod.F

!||    spmd_comm_world_mod    ../engine/source/mpi/spmd_comm_world.F90

!||====================================================================


      SUBROUTINE init_diffusion(this, LINSOL, NRHS, IPARG, ALE_CONNECT)

      USE linear_solver_mod

      USE ale_connectivity_mod

C-----------------------------------------------

C   I m p l i c i t   T y p e s

C-----------------------------------------------

        USE spmd_comm_world_mod, ONLY : spmd_comm_world

#include      "implicit_f.inc"

C-----------------------------------------------

C     C o m m o n   B l o c k s

C-----------------------------------------------

!     NSPMD

#include      "com01_c.inc"

!     NPARG

#include      "param_c.inc"

!     NUMELS

#include      "com04_c.inc"

!     NSVOIS

#include      "spmd_c.inc"

C-----------------------------------------------

C   M e s s a g e   P a s s i n g

C-----------------------------------------------

#include "spmd.inc"

C-----------------------------------------------

C     D u m m y   A r g u m e n t s

C-----------------------------------------------

      CLASS(t_diffusion) :: this

      CLASS(t_linear_solver), INTENT(IN), TARGET :: LINSOL

      INTEGER, DIMENSION(NPARG, NGROUP), INTENT(IN) :: IPARG

      INTEGER, INTENT(IN) :: NRHS

      TYPE(t_ale_connectivity), INTENT(IN) :: ALE_CONNECT

C-----------------------------------------------

C     L o c a l   V a r i a b l e s

C-----------------------------------------------

      INTEGER :: MAT_NZ, NG, II, NEL, ITY, MATLAW, NFT, I, JJ, KK

      INTEGER :: GLOB_DIM, MAX_ID, IAD, LGTH

#ifdef MPI

      INTEGER IERR

#endif


      this%NRHS = nrhs

!     number of non zero values for the diffusion matrix elem <-> elem matrix

      mat_nz = 0

      DO ng = 1, ngroup

         matlaw = iparg(1, ng)

         IF (matlaw == 151) THEN

            nel = iparg(2, ng)

            nft = iparg(3, ng)

            ity = iparg(5, ng)

            DO ii = 1, nel

               i = ii + nft

               mat_nz = mat_nz + 1

               iad = ale_connect%EE_CONNECT%IAD_CONNECT(i)

               lgth = ale_connect%EE_CONNECT%IAD_CONNECT(i+1)-ale_connect%EE_CONNECT%IAD_CONNECT(i)

               DO jj = 1, lgth

                  kk = ale_connect%EE_CONNECT%CONNECTED(iad + jj - 1)

                  IF (kk > 0) THEN

                     mat_nz = mat_nz + 1

                  ENDIF

               ENDDO

            ENDDO

         ENDIF

      ENDDO

!     create matrix

      CALL this%MAT%MATRIX_CREATE(mat_nz)

!     create rhs

      CALL this%RHS%CREATE(nrhs * numels)

!     global system size

      glob_dim = numels

      max_id = maxval(ale_connect%IDGLOB%ID(1:numels + nsvois))

#ifdef MPI

      IF (nspmd > 1) THEN

         CALL mpi_allreduce(max_id, glob_dim, 1, mpi_int, mpi_max, spmd_comm_world, ierr)

      ENDIF

#endif

!     solution

      ALLOCATE(this%SOL(3 * glob_dim))

!     init solver

      this%LINEAR_SOLVER => linsol

      CALL this%LINEAR_SOLVER%INIT_SOLVER(glob_dim)

!     set rhs and matrix

      CALL this%LINEAR_SOLVER%SET_RHS(3, this%RHS)

      CALL this%LINEAR_SOLVER%SET_MATRIX(this%MAT)

!     diffusion coefficient, outlet flag

      this%OUTLET_FLAGGED = .false.

      IF (n2d == 0) THEN

         ALLOCATE(this%NU(numels + nsvois))

         this%NU(1:numels + nsvois) = zero

         ALLOCATE(this%FLAG_OUTLET(6 * numels))

         this%FLAG_OUTLET(1:6 * numels) = 0

      ELSE

         ALLOCATE(this%NU(numelq + numeltg + nqvois + ntgvois))

         this%NU(1:numelq + numeltg + nqvois + ntgvois) = zero

         ALLOCATE(this%FLAG_OUTLET(4 * numelq + 3 * numeltg))

         this%FLAG_OUTLET(1:4 * numelq + 3 * numeltg) = 0

      ENDIF


      END SUBROUTINE init_diffusion


!||====================================================================

!||    solve_diffusion       ../engine/share/modules/diffusion_mod.F

!||--- calls      -----------------------------------------------------

!||    get_global_dim        ../engine/share/modules/linear_solver_mod.F

!||--- uses       -----------------------------------------------------

!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90

!||====================================================================


      SUBROUTINE solve_diffusion(this)

C-----------------------------------------------

C   I m p l i c i t   T y p e s

C-----------------------------------------------

        USE spmd_comm_world_mod, ONLY : spmd_comm_world

#include      "implicit_f.inc"

      CLASS(t_diffusion) :: this

      INTEGER :: GLOB_DIM


      glob_dim = this%LINEAR_SOLVER%GET_GLOBAL_DIM()

      CALL this%LINEAR_SOLVER%SOLVE(this%SOL, this%NRHS * glob_dim)


      END SUBROUTINE solve_diffusion


!||====================================================================

!||    get_solution          ../engine/share/modules/diffusion_mod.F

!||--- calls      -----------------------------------------------------

!||    get_global_dim        ../engine/share/modules/linear_solver_mod.F

!||--- uses       -----------------------------------------------------

!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90

!||====================================================================


      SUBROUTINE get_solution(this, SOL, GLOB_DIM)

C-----------------------------------------------

C   I m p l i c i t   T y p e s

C-----------------------------------------------

        USE spmd_comm_world_mod, ONLY : spmd_comm_world

#include      "implicit_f.inc"

      CLASS(t_diffusion), INTENT(INOUT), TARGET :: this

      INTEGER, INTENT(OUT) :: GLOB_DIM


      DOUBLE PRECISION, DIMENSION(:), INTENT(INOUT), POINTER :: SOL

      sol => this%SOL

      glob_dim = this%LINEAR_SOLVER%GET_GLOBAL_DIM()


      END SUBROUTINE get_solution


!||====================================================================

!||    terminate_diffusion   ../engine/share/modules/diffusion_mod.F

!||--- uses       -----------------------------------------------------

!||    spmd_comm_world_mod   ../engine/source/mpi/spmd_comm_world.F90

!||====================================================================


      SUBROUTINE terminate_diffusion(this)

C-----------------------------------------------

C   I m p l i c i t   T y p e s

C-----------------------------------------------

        USE spmd_comm_world_mod, ONLY : spmd_comm_world

#include      "implicit_f.inc"

      CLASS(t_diffusion), INTENT(INOUT) :: this


      CALL this%LINEAR_SOLVER%TERMINATE()

      CALL this%MAT%MATRIX_DESTROY()

      CALL this%RHS%DESTROY()

      IF (ALLOCATED(this%SOL)) DEALLOCATE(this%SOL)

      IF (ALLOCATED(this%NU)) DEALLOCATE(this%NU)

      IF (ALLOCATED(this%FLAG_OUTLET)) DEALLOCATE(this%FLAG_OUTLET)


      END SUBROUTINE terminate_diffusion

      END MODULE diffusion_mod

my_real
#define my_real
Definition cppsort.cpp:32

mpi_allreduce
subroutine mpi_allreduce(sendbuf, recvbuf, cnt, datatype, operation, comm, ierr)
Definition mpi.f:103

ale_connectivity_mod
Definition ale_connectivity_mod.F:223

diffusion_mod
Definition diffusion_mod.F:36

diffusion_mod::init_diffusion
subroutine init_diffusion(this, linsol, nrhs, iparg, ale_connect)
Definition diffusion_mod.F:82

diffusion_mod::get_solution
subroutine get_solution(this, sol, glob_dim)
Definition diffusion_mod.F:209

diffusion_mod::solve_diffusion
subroutine solve_diffusion(this)
Definition diffusion_mod.F:188

diffusion_mod::terminate_diffusion
subroutine terminate_diffusion(this)
Definition diffusion_mod.F:228

linear_solver_mod
Definition linear_solver_mod.F:35

matrix_mod
Definition matrix_mod.F:34

vector_mod
Definition vector_mod.F:37

ale_connectivity_mod::t_ale_connectivity
Definition ale_connectivity_mod.F:254

diffusion_mod::t_diffusion
Definition diffusion_mod.F:49

linear_solver_mod::t_linear_solver
Definition linear_solver_mod.F:55

matrix_mod::t_cfs_matrix
Definition matrix_mod.F:42

vector_mod::t_vector
Definition vector_mod.F:45