dt37law.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    dt37law   ../starter/source/materials/time_step/dt37law.F
!||--- called by ------------------------------------------------------
!||    dtmain    ../starter/source/materials/time_step/dtmain.F
!||--- calls      -----------------------------------------------------
!||    dtel      ../starter/source/materials/time_step/dtel.F
!||    dtsph     ../starter/source/materials/time_step/dtsph.F
!||====================================================================
      SUBROUTINE dt37law (PM,GEO,PID,MAT, BUFMAT, IPM, DELTAX, AIRE, VOL, DTX)
C-----------------------------------------------
C   D e s c r i p t i o n
C-----------------------------------------------
C     ELEMENTARY TIME STEPS FOR ALE MULTI MATERIAL LAW 37 (/MAT/BIPHAS)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "vect01_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real, INTENT(IN) :: pm(npropm, *), geo(npropg, *), aire(*), vol(*)
      my_real, INTENT(INOUT) ::  dtx(*)
      my_real, INTENT(IN), DIMENSION(:), TARGET :: bufmat(*), deltax(*)
      INTEGER, INTENT(IN) :: PID(*),MAT(*),IPM(NPROPMI, *)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER                                :: I, MX, IADBUF,IFLG(MVSIZ)
      my_real,DIMENSION(:),POINTER           :: uparam
      
      my_real
     .   ssp(mvsiz)  , dpdm(mvsiz) , rho0(mvsiz)    , 
     .   bulk , c1   ,  p  ,        
     .   mas(mvsiz), mu1p1(mvsiz),mu1p2(mvsiz),rho1(mvsiz),rho2(mvsiz),
     .   gam,rho10,rho20,p0,vfrac1,vfrac2,uvar1,a1,r1,visa1,visb1,visa2,visb2,
     .   b1,b2,mas1,mas2,ssp1,ssp2,vis(mvsiz),a
     
      INTEGER ISOLVER
 
     
c-----------------------------------------------
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
 
      iadbuf   = ipm(7,mat(1))
      uparam   =>bufmat(iadbuf:iadbuf+17)
      isolver  = uparam(17)
      a1       = uparam(10) !mfrac_liq
      rho10    = uparam(11)
      rho20    = uparam(12)
      r1       = uparam(6)
      gam      = uparam(5)
      p0       = uparam(9)
      c1       = uparam(4)
      visa1    = uparam(1)
      visb1    = uparam(3)
      visa2    = uparam(13)
      visb2    = uparam(15)
    
       DO i=lft,llt
        rho0(i)= rho10 * a1 + (one-a1)*rho20
        mas(i)= rho0(i)*vol(i)
      ENDDO
 
      DO i=lft,llt
       IF(gam*c1>=em30)THEN !if Liquid and gas correctly defined
         rho1(i) = rho10
         rho2(i) = rho20
       ENDIF 
      ENDDO
                
      IF (isolver==2) THEN
        DO i=lft,llt
          mas1 = a1 * vol(i)
          IF (a1 < em10)THEN
            mas1=zero
            vfrac1=zero
            vfrac2=one
          ENDIF
          IF (one-a1 < em10)THEN
            mas2=zero
            rho1=mas(i)/vol(i)
            vfrac1=one
            vfrac2=zero
          ENDIF
          a = (rho0(i)-rho2(i))/(rho1(i)-rho2(i))
          vfrac1=a
          IF(vfrac1<em20)vfrac1=zero
          vfrac2 = one-vfrac1
          ssp1=c1
          ssp2=gam*p0*(rho2(i)/rho20)**gam
          uvar1=a*rho1(i)
          IF(ssp1>zero)THEN
            ssp1 = vfrac1 / ssp1
          ELSE
            ssp1=zero
          ENDIF
          IF(ssp2>zero)THEN
            ssp2 = vfrac2 / ssp2
          ELSE
            ssp2=zero
          ENDIF
          ssp(i) = ssp1 + ssp2
          ssp(i) = sqrt(one / ssp(i) / rho0(i))
          b1=uvar1
          b2=rho0(i)-b1
          vis(i)=(b1*rho1(i)*visa1 + b2*rho2(i)*visa2)/rho0(i)
        
        ENDDO
      ELSE
        DO i=lft,llt
          ssp(i)=sqrt(r1)
          vis(i)=zero
        ENDDO
      ENDIF 
 
      
      !----------------------------------------------!
      !  ELEMENTARY TIME STEP (ARTIFICIAL VISCOSITY) !
      !----------------------------------------------!
      IF(jsph==0)THEN
       CALL dtel(ssp,pm,geo,pid,mat, rho0, vis, deltax, aire, vol, dtx)
      ELSE
       CALL dtsph(ssp,pm,geo,pid,mat, rho0, vis, deltax, vol, dtx)
      ENDIF
C-----------
      RETURN
      END