dtcdk_reg.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    dtcdk_reg        ../engine/source/elements/sh3n/coquedk/dtcdk_reg.F
!||--- called by ------------------------------------------------------
!||    cdkforc3         ../engine/source/elements/sh3n/coquedk/cdkforc3.F
!||--- uses       -----------------------------------------------------
!||    nlocal_reg_mod   ../common_source/modules/nlocal_reg_mod.F
!||====================================================================
      SUBROUTINE dtcdk_reg(NLOC_DMG,THK     ,NEL     ,OFF     ,
     .                     LE      ,IMAT    ,NDDL    ,DT2T    )
C-----------------------------------------------
C   M o d u l e s
C----------------------------------------------- 
      USE nlocal_reg_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "scr02_c.inc"
#include      "scr18_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER                                    :: NEL,IMAT,NDDL
      my_real, INTENT(INOUT)                     ::
     .  dt2t
      my_real, DIMENSION(NEL), INTENT(IN)        :: 
     .  le,off,thk
      TYPE(nlocal_str_), TARGET                  :: NLOC_DMG 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I
      my_real 
     .  l2,zeta,dtnl_th,dtnl,le_max
C=======================================================================
      ! Recovering non-local parameters
      l2     = nloc_dmg%LEN(imat)**2 ! Non-local internal length ** 2
      zeta   = nloc_dmg%DENS(imat)   ! Non-local density
      le_max = nloc_dmg%LE_MAX(imat) ! Maximal length of convergence
c      
      !-----------------------------------------------------------------------
      ! Computing non-local timestep
      !-----------------------------------------------------------------------
      IF (nodadt == 0) THEN
        DO i = 1,nel
          ! If the element is not broken, normal computation
          IF (off(i)/=zero) THEN
            ! Non-local critical time-step in the plane
            dtnl = (two*(min(le(i),le_max))*sqrt(three*zeta))/
     .                  sqrt(twelve*l2 + (min(le(i),le_max))**2)
            ! Non-local critical time-step in the thickness
            IF (nddl>1) THEN
              IF (nddl > 2) THEN
                dtnl_th = (two*(min(thk(i)/nddl,le_max))*sqrt(three*zeta))/
     .                       sqrt(twelve*l2 + (min(thk(i)/nddl,le_max))**2)
              ELSE
                dtnl_th = (two*(min(thk(i),le_max))*sqrt(three*zeta))/
     .                       sqrt(twelve*l2 + (min(thk(i),le_max))**2)
              ENDIF
            ELSE
              dtnl_th = ep20
            ENDIF
            ! Retaining the minimal value
            dt2t = min(dt2t,dtfac1(1)*cdamp*dtnl_th,dtfac1(1)*cdamp*dtnl)
          ENDIF
        ENDDO
      ENDIF
c
      END