ebcs4.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ebcs4        ../engine/source/boundary_conditions/ebcs/ebcs4.F
!||--- called by ------------------------------------------------------
!||    ebcs_main    ../engine/source/boundary_conditions/ebcs/ebcs_main.F
!||--- uses       -----------------------------------------------------
!||    ebcs_mod     ../common_source/modules/boundary_conditions/ebcs_mod.F90
!||    segvar_mod   ../engine/share/modules/segvar_mod.F
!||====================================================================
      SUBROUTINE ebcs4(NSEG,ISEG,SEGVAR,A,V,X,LISTE,NOD,IRECT,LA,FV,MS,STIFN,EBCS)
      USE ebcs_mod
      USE segvar_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com08_c.inc"
#include      "scr11_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NSEG,NOD,ISEG(NSEG),LISTE(NOD),IRECT(4,NSEG)
      my_real a(3,*),v(3,*),x(3,*),la(3,nod),ms(*),stifn(*),fv(*)
      TYPE(t_ebcs_vel), INTENT(IN) :: EBCS
      TYPE(t_segvar) :: SEGVAR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,IS,KSEG,N1,N2,N3,N4,NG1,NG2,NG3,NG4,N,
     . IVX,IVY,IVZ,IRHO,IENER
      my_real
     .       orient,rho,c,roc,fac,
     .       x13,y13,z13,x24,y24,z24,nx,ny,nz,s,
     .       roou,enou,vmx,vmy,vmz,fluxi,fluxo,p,dvx,dvy,dvz,ener,
     .       vx,vy,vz
C-----------------------------------------------
      ivx=ebcs%ivx
      ivy=ebcs%ivy
      ivz=ebcs%ivz
      irho=ebcs%irho
      iener=ebcs%iener
      IF(ivx > 0)THEN
        vx=ebcs%vx*fv(ivx)
      ELSE
        vx=ebcs%vx
      ENDIF
      IF(ivy > 0)THEN
        vy=ebcs%vy*fv(ivy)
      ELSE
        vy=ebcs%vy
      ENDIF
      IF(ivz > 0)THEN
        vz=ebcs%vz*fv(ivz)
      ELSE
        vz=ebcs%vz
      ENDIF
       IF(irho > 0)THEN
        rho=ebcs%rho*fv(irho)
      ELSE
        rho=ebcs%rho
      ENDIF
      IF(iener > 0)THEN
        ener=ebcs%ener*fv(iener)
      ELSE
        ener=ebcs%ener
      ENDIF
      c=ebcs%c
      roc=rho*c
 
!INIT. MASS DENSITY AND ENERGY
! NORMAL AT NODES
      DO i=1,nod
         la(1,i)=zero
         la(2,i)=zero
         la(3,i)=zero
      ENDDO
      DO is=1,nseg
        kseg=abs(iseg(is))
        orient=float(iseg(is)/kseg)
        n1=irect(1,is)
        n2=irect(2,is)
        n3=irect(3,is)
        n4=irect(4,is)
        IF(n4==0 .OR. n4==n3) THEN
          fac=one_over_6*orient
          n4=n3
        ELSE
          fac=one_over_8*orient
        ENDIF
        ng1=liste(n1)
        ng2=liste(n2)
        ng3=liste(n3)
        ng4=liste(n4)
        x13=x(1,ng3)-x(1,ng1)
        y13=x(2,ng3)-x(2,ng1)
        z13=x(3,ng3)-x(3,ng1)
        x24=x(1,ng4)-x(1,ng2)
        y24=x(2,ng4)-x(2,ng2)
        z24=x(3,ng4)-x(3,ng2)
        nx=(y13*z24-z13*y24)*fac
        ny=(z13*x24-x13*z24)*fac
        nz=(x13*y24-y13*x24)*fac
        la(1,n1)=la(1,n1)+nx
        la(2,n1)=la(2,n1)+ny
        la(3,n1)=la(3,n1)+nz
        la(1,n2)=la(1,n2)+nx
        la(2,n2)=la(2,n2)+ny
        la(3,n2)=la(3,n2)+nz
        la(1,n3)=la(1,n3)+nx
        la(2,n3)=la(2,n3)+ny
        la(3,n3)=la(3,n3)+nz
        vmx=v(1,ng1)+v(1,ng2)+v(1,ng3)
        vmy=v(2,ng1)+v(2,ng2)+v(2,ng3)
        vmz=v(3,ng1)+v(3,ng2)+v(3,ng3)
        IF(n4/=n3) THEN
           la(1,n4)=la(1,n4)+nx
           la(2,n4)=la(2,n4)+ny
           la(3,n4)=la(3,n4)+nz
           vmx=vmx+v(1,ng4)
           vmy=vmy+v(2,ng4)
           vmz=vmz+v(3,ng4)
        ENDIF
! mass and energy balance
        roou = segvar%RHO(kseg)
        enou = segvar%EINT(kseg)
        fluxo=(vmx*nx+vmy*ny+vmz*nz)*dt1
        fluxi=min(fluxo,zero)
        fluxo=max(fluxo,zero)
        dmf=dmf-fluxo*roou-fluxi*rho
        def=def-fluxo*enou-fluxi*ener
! masse density and incoming energy stored in face buffer
        segvar%RHO(kseg)=rho
        segvar%EINT(kseg)=ener
      ENDDO
      IF(tt == 0)THEN
        DO i=1,nod
          n=liste(i)
          v(1,n)=vx
          v(2,n)=vy
          v(3,n)=vz
        ENDDO
      ENDIF
 
      DO i=1,nod
        n=liste(i)
        s=sqrt(la(1,i)**2+la(2,i)**2+la(3,i)**2)
        dvx=v(1,n)-vx
        dvy=v(2,n)-vy
        dvz=v(3,n)-vz
        p=roc*(dvx*la(1,i)+dvy*la(2,i)+dvz*la(3,i))/s
        a(1,n)=a(1,n)-p*la(1,i)
        a(2,n)=a(2,n)-p*la(2,i)
        a(3,n)=a(3,n)-p*la(3,i)
        stifn(n)=stifn(n)+(two*(s*roc)**2)/ms(n)
      ENDDO
 
      RETURN
      END