ebcs7_iniv.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ebcs7_iniv_mod   ../engine/source/boundary_conditions/ebcs/ebcs7_iniv.F
!||--- called by ------------------------------------------------------
!||    ebcs_main        ../engine/source/boundary_conditions/ebcs/ebcs_main.F
!||====================================================================
      MODULE ebcs7_iniv_mod
      IMPLICIT NONe
      CONTAINS
!||====================================================================
!||    ebcs7_iniv   ../engine/source/boundary_conditions/ebcs/ebcs7_iniv.F
!||--- called by ------------------------------------------------------
!||    ebcs_main    ../engine/source/boundary_conditions/ebcs/ebcs_main.F
!||--- uses       -----------------------------------------------------
!||    ebcs_mod     ../common_source/modules/boundary_conditions/ebcs_mod.F90
!||    output_mod   ../common_source/modules/output/output_mod.F90
!||    segvar_mod   ../engine/share/modules/segvar_mod.F
!||====================================================================
      SUBROUTINE ebcs7_iniv(NSEG,ISEG,SEGVAR,
     .                 A,V,X,
     .                 LISTE,NOD,IRECT,
     .                 RO0,EN0,V0,
     .                 LA,MS,STIFN,EBCS,OUTPUT,DT1,TIME)
      USE ebcs_mod
      USE segvar_mod
      USE output_mod, ONLY : output_
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER :: NSEG,NOD,ISEG(NSEG),LISTE(NOD),IRECT(4,NSEG)
      my_real :: A(3,*),V(3,*),X(3,*),RO0(NSEG),EN0(NSEG),V0(3,NOD),LA(3,NOD),MS(*),STIFN(*)
      TYPE(t_ebcs_iniv), INTENT(IN) :: EBCS
      TYPE(t_segvar) :: SEGVAR
      TYPE(output_), INTENT(INOUT) :: OUTPUT !< output structure
      my_real,INTENT(IN) :: dt1 !< time step
      my_real,INTENT(IN) :: time !< current time
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,IS,KSEG,N1,N2,N3,N4,NG1,NG2,NG3,NG4,N
      my_real :: ORIENT,RHO,C,ROC,FAC,
     .           X13,Y13,Z13,X24,Y24,Z24,NX,NY,NZ,S,
     .           ROOU,ENOU,VMX,VMY,VMZ,FLUXI,FLUXO,P,DVX,DVY,DVZ
      my_real :: de_in, de_out, dm_in, dm_out
C-----------------------------------------------
      c=ebcs%c
      rho=ebcs%rho
      roc=rho*c
      de_in = zero
      de_out = zero
      dm_in = zero
      dm_out = zero
C
C     initialization of initial densities and energies
C
      IF(time == zero)THEN
        DO is=1,nseg
          kseg=abs(iseg(is))
          ro0(is) = segvar%RHO(kseg)
          en0(is) = segvar%EINT(kseg)
        ENDDO            
        DO i=1,nod
          n=liste(i)
          v0(1,i)=v(1,n)
          v0(2,i)=v(2,n)
          v0(3,i)=v(3,n)
        ENDDO
      ENDIF
C NODAL NORMAL SURFACE
      DO i=1,nod
         la(1,i)=zero
         la(2,i)=zero
         la(3,i)=zero
      ENDDO
      DO is=1,nseg
        kseg=abs(iseg(is))
        orient=float(iseg(is)/kseg)
        n1=irect(1,is)
        n2=irect(2,is)
        n3=irect(3,is)
        n4=irect(4,is)
        IF(n4==0 .OR. n4==n3) THEN
          fac=one_over_6*orient
          n4=n3
        ELSE
          fac=one_over_8*orient
        ENDIF
c
        ng1=liste(n1)
        ng2=liste(n2)
        ng3=liste(n3)
        ng4=liste(n4)
        x13=x(1,ng3)-x(1,ng1)
        y13=x(2,ng3)-x(2,ng1)
        z13=x(3,ng3)-x(3,ng1)
        x24=x(1,ng4)-x(1,ng2)
        y24=x(2,ng4)-x(2,ng2)
        z24=x(3,ng4)-x(3,ng2)
c
        nx=(y13*z24-z13*y24)*fac
        ny=(z13*x24-x13*z24)*fac
        nz=(x13*y24-y13*x24)*fac
c
        la(1,n1)=la(1,n1)+nx
        la(2,n1)=la(2,n1)+ny
        la(3,n1)=la(3,n1)+nz
        la(1,n2)=la(1,n2)+nx
        la(2,n2)=la(2,n2)+ny
        la(3,n2)=la(3,n2)+nz
        la(1,n3)=la(1,n3)+nx
        la(2,n3)=la(2,n3)+ny
        la(3,n3)=la(3,n3)+nz 
C
        vmx=v(1,ng1)+v(1,ng2)+v(1,ng3)
        vmy=v(2,ng1)+v(2,ng2)+v(2,ng3)
        vmz=v(3,ng1)+v(3,ng2)+v(3,ng3)
 
        IF(n4/=n3) THEN
           la(1,n4)=la(1,n4)+nx
           la(2,n4)=la(2,n4)+ny
           la(3,n4)=la(3,n4)+nz
           vmx=vmx+v(1,ng4)
           vmy=vmy+v(2,ng4)
           vmz=vmz+v(3,ng4)
        ENDIF
C
c mass and total energy balance
c
        roou = segvar%RHO(kseg)
        enou = segvar%EINT(kseg)
c
        fluxo=(vmx*nx+vmy*ny+vmz*nz)*dt1
        fluxi=min(fluxo,zero)
        fluxo=max(fluxo,zero)
        dm_out=dm_out-fluxo*roou
        dm_in=dm_in-fluxi*ro0(is)
        de_out=de_out-fluxo*enou
        de_in=de_in-fluxi*en0(is)
C
C storage of density and incoming energy in facet buffer
C
        segvar%RHO(kseg)=ro0(is)
        segvar%EINT(kseg)=en0(is)
      ENDDO
 
!$OMP CRITICAL
      output%DATA%INOUT%DM_IN  = output%DATA%INOUT%DM_IN + dm_in
      output%DATA%INOUT%DM_OUT = output%DATA%INOUT%DM_OUT + dm_out
      output%DATA%INOUT%DE_IN = output%DATA%INOUT%DE_IN + de_in
      output%DATA%INOUT%DE_OUT = output%DATA%INOUT%DE_OUT + de_out
!$OMP END CRITICAL
 
 
      DO i=1,nod
        n=liste(i)
        s=sqrt(la(1,i)**2+la(2,i)**2+la(3,i)**2)
        dvx=v(1,n)-v0(1,i)
        dvy=v(2,n)-v0(2,i)
        dvz=v(3,n)-v0(3,i)
c        write(6,*)I,N,v(3,N),v0(3,I),roc
        p=roc*(dvx*la(1,i)+dvy*la(2,i)+dvz*la(3,i))/s
c
        a(1,n)=a(1,n)-p*la(1,i)
        a(2,n)=a(2,n)-p*la(2,i)
        a(3,n)=a(3,n)-p*la(3,i)
        stifn(n)=stifn(n)+(two*(s*roc)**2)/ms(n)
      ENDDO
c
      RETURN
      END SUBROUTINE ebcs7_iniv
      END MODULE ebcs7_iniv_mod