ecran1.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    ecran1           ../starter/source/initial_conditions/detonation/ecran1.f
!||--- called by ------------------------------------------------------
!||    m5in2            ../starter/source/initial_conditions/detonation/m5in2.F
!||    m5in2t           ../starter/source/initial_conditions/detonation/m5in2t.F
!||--- calls      -----------------------------------------------------
!||    ancmsg           ../starter/source/output/message/message.F
!||    iombr            ../starter/source/initial_conditions/detonation/iombr.F
!||--- uses       -----------------------------------------------------
!||    detonators_mod   ../starter/share/modules1/detonators_mod.F
!||    message_mod      ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE ecran1(DETONATOR,X,VDET)
C-----------------------------------------------
      USE message_mod
      USE detonators_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real x(3,numnod)
      my_real,INTENT(IN)::vdet
      TYPE(detonator_wave_shaper_struct_),TARGET :: DETONATOR
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr11_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, J, JJ, JJJ,NPE
      my_real dtomin, ddmx, d2
      INTEGER,POINTER,DIMENSION(:) :: IECR, IORDR, IFLG
      my_real,POINTER,DIMENSION(:) :: dtime
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER,EXTERNAL :: IOMBR
C-----------------------------------------------
 
      npe=detonator%NUMNOD
      iecr => detonator%NODES(1:)
      iordr => detonator%IORDR(1:)
      iflg => detonator%FLAG(1:)
      dtime => detonator%TIME(1:)
C---------------------------------------
C     COMPUTING DETONATION TIMES OF THE SCREEN POINTS
C---------------------------------------
C     1) LIGHTENING FROM DETONATION ORIGIN
C         check if the target can be directly lightened from detonation origin.
C            yes if no crossing with the screen (IOMBR returns 0)
C             no otherwise (IOMBR return 1)
C---------------------------------------
      dtomin=ep20
      iordr(1)=0
 
      DO i=1,npe
        ddmx  =ep20
        iflg(i)=0
        ii=iecr(i)
        yl=x(2,ii)
        zl=x(3,ii)
        IF(iombr(detonator,x,iecr,ddmx,vdet) == 0)THEN   !Vdet is optional velocity from origin (default is material velocity VDTO)
          dtime(i)=dto !DT0 is lightening time from function IOMBR
          IF(dtime(i) <= dtomin)THEN
            iordr(1)=i
            dtomin=dtime(i)
          ENDIF
        ELSE
          dtime(i)=ep20
        ENDIF
      END DO !I=1,NPE
 
      IF(iordr(1) == 0)THEN
        CALL ancmsg(msgid=422,
     .              msgtype=msgerror,
     .              anmode=aninfo)
      ENDIF
 
C-----------------------------------------
C     2) LIGHTENING SCREEN POINTS FROM SCREEN POINTS THEMSELVES
C-----------------------------------------
      DO j=1,npe-1
        jj=iordr(j)
        jjj=iecr(jj)
        !define J as a new source. (J from N-1, N-2, ..., 1 ; first point is the nearest one from detonation origin)
        yd=x(2,jjj)
        zd=x(3,jjj)
        dto0=dtime(jj)
        iflg(jj)=1
        dtomin=ep20
        DO i=1,npe
          ! check if I can be lightened from J (I from 1,2,...,N ; first node is the farthest one from detonation origin)
          IF(iflg(i) == 1)cycle !I
          ddmx  =ep20
          ii=iecr(i)
          yl=x(2,ii)
          zl=x(3,ii)
          IF(iabs(i-jj) == 1)THEN
            d2 =(yd-yl)**2+(zd-zl)**2
            dto=dto0+sqrt(d2)/vdto
            dtime(i)= min(dtime(i),dto)
          ELSEIF(iombr(detonator,x,iecr,ddmx,vdto) == 0)THEN
            dtime(i)= min(dtime(i),dto)
          ENDIF
          IF(dtime(i) <= dtomin)THEN
            iordr(j+1)=i
            dtomin=dtime(i)
          ENDIF
        END DO !I=1,NPE
      END DO !J=1,NPE-1
 
      RETURN
      END