edefo2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    edefo2   ../engine/source/ale/euler2d/edefo2.F
!||--- called by ------------------------------------------------------
!||    bforc2   ../engine/source/ale/bimat/bforc2.F
!||    qforc2   ../engine/source/elements/solid_2d/quad/qforc2.f
!||====================================================================
      SUBROUTINE edefo2(VOL,V,VEUL,
     .                  Y1,Y2,Y3,Y4,Z1,Z2,Z3,Z4,
     .                  VY1,VY2,VY3,VY4,VZ1,VZ2,VZ3,VZ4,
     .                  PY1,PY2,PZ1,PZ2,
     .                  WYZ,DYZ,DZY,EYY,EZZ,ETT,EYZ,EYT,EZT,
     .                  VOLN,AIRE,DELTAX,VDY,VDZ,VD2,
     .                  NC1,NC2,NC3,NC4)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "mvsiz_p.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      my_real
     .   vol(*), v(3,numnod), veul(10,*),
     .   y1(*),y2(*),y3(*),y4(*),z1(*),z2(*),z3(*),z4(*),
     .   vy1(*),vy2(*),vy3(*),vy4(*),vz1(*),vz2(*),vz3(*),vz4(*),
     .   py1(*), py2(*), pz1(*), pz2(*),
     .   wyz(*), dyz(*), dzy(*),
     .   eyy(*),ezz(*), ett(*), eyz(*), eyt(*), ezt(*),
     .   voln(*),aire(*),deltax(*),vdy(*),vdz(*),vd2(*)
      INTEGER NC1(*), NC2(*), NC3(*), NC4(*)
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com08_c.inc"
#include      "vect01_c.inc"
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II
      my_real VY13(MVSIZ), VY24(MVSIZ), VZ13(MVSIZ),VZ24(MVSIZ),YAVG(MVSIZ)
C-----------------------------------------------
      DO I=lft,llt
        ii=i+nft
        py1(i)=half*(z2(i)-z4(i))
        py2(i)=half*(z3(i)-z1(i))
        pz1(i)=half*(y4(i)-y2(i))
        pz2(i)=half*(y1(i)-y3(i))      
        aire(i)=veul(1,ii)
        deltax(i)=veul(2,ii)
      ENDDO !next I
 
      IF(n2d == 1) THEN
       DO i=lft,llt
         voln(i)=vol(i)
       ENDDO
      ELSE
       DO i=lft,llt
         voln(i)=aire(i)
       ENDDO
      ENDIF
 
      DO i=lft,llt
        vy1(i)=v(2,nc1(i))
        vz1(i)=v(3,nc1(i))
        vy2(i)=v(2,nc2(i))
        vz2(i)=v(3,nc2(i))
        vy3(i)=v(2,nc3(i))
        vz3(i)=v(3,nc3(i))
        vy4(i)=v(2,nc4(i))
        vz4(i)=v(3,nc4(i))
      ENDDO  
 
      IF(mtn /= 11)THEN
       DO i=lft,llt
         yavg(i) =y1(i)+y2(i)+y3(i)+y4(i)
         vy13(i)=vy1(i)-vy3(i)
         vy24(i)=vy2(i)-vy4(i)
         vz13(i)=vz1(i)-vz3(i)
         vz24(i)=vz2(i)-vz4(i)
         vdy(i)=fourth*(vy1(i)+vy2(i)+vy3(i)+vy4(i))
         vdz(i)=fourth*(vz1(i)+vz2(i)+vz3(i)+vz4(i))
         vd2(i)=vdy(i)**2+vdz(i)**2
       ENDDO 
 
       DO i=lft,llt
         eyy(i)=(py1(i)*vy13(i)+py2(i)*vy24(i))/aire(i)
         ezz(i)=(pz1(i)*vz13(i)+pz2(i)*vz24(i))/aire(i)
         ett(i)=zero
         dzy(i)=(py1(i)*vz13(i)+py2(i)*vz24(i))/aire(i)
         dyz(i)=(pz1(i)*vy13(i)+pz2(i)*vy24(i))/aire(i)
         eyt(i)=zero
         ezt(i)=zero
       ENDDO 
 
       IF(n2d == 1) THEN
        DO i=lft,llt
         ett(i)=(vy1(i)+vy2(i)+vy3(i)+vy4(i))/yavg(i)
        ENDDO
       ENDIF
 
       DO i=lft,llt
         eyz(i)= dzy(i)+dyz(i)
         wyz(i)=half*dt1*(dzy(i)-dyz(i))
       ENDDO
      ENDIF
C-----------------------------------------------
      RETURN
      END