i21gap3.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    i21gap3       ../engine/source/interfaces/int21/i21gap3.F
!||--- called by ------------------------------------------------------
!||    i21main_gap   ../engine/source/interfaces/int21/i21main_gap.F
!||====================================================================
      SUBROUTINE i21gap3(
     1 ITASK ,IRECTS ,NRTS ,NSN   ,NSV   ,
     2 GAP   ,IGAP  ,GAP_S ,GAPMIN,CRITER,
     3 GAPMAX,TZINF ,DIST  ,THKNOD,GAPSCALE,
     4 DEPTH ,MARGE ,DRAD  ,IDEL  ,THKNOD0,
     5 GAP_S0,DGAPLOAD)
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "task_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ITASK, NRTS, NSN, IGAP, IDEL
      INTEGER IRECTS(4,*), NSV(*)
C     REAL
      my_real
     .   GAP, GAPMIN, CRITER, GAPMAX, TZINF, DIST, GAPSCALE,
     .   depth, marge
      my_real , INTENT(IN) :: dgapload ,drad
      my_real
     .   gap_s(*), thknod(*), gap_s0(*), thknod0(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NSNF, NSNL, I, J, NELS, NELC, NELTG, NEL
C     REAL
      my_real
     .   GAPM, CRITERL, GAPSUPL
C------------------------------------
C     GAP VARIABLE NOEUDS SECONDS
C------------------------------------
      nsnf = 1 + itask*nsn / nthread
      nsnl = (itask+1)*nsn / nthread
      
      IF(igap>=2)THEN
       DO i=nsnf,nsnl
        gap_s(i) = max(half*gapscale*(thknod(nsv(i))-thknod0(i))
     .                                            +gap_s0(i),zero)
       ENDDO
      ENDIF
C---------------------------------------------
C
C Calcul du gap reel a utiliser lors du critere de retri
C
      IF (igap==0) THEN
        criter =max(gap,em01*max(depth,drad,gap+dgapload))
        dist   =tzinf-max(gap+dgapload,depth,drad)
      ELSE
        criterl=ep30
        gapsupl=zero
        DO i = nsnf,nsnl
          IF(idel==0.OR.gap_s(i)/=zero)THEN
C gap_s/=0 <=> node is still connected through non deleted shells
            criterl = min(criterl,gap_s(i))
            gapsupl = max(gapsupl,gap_s(i))
          END IF
        ENDDO
        criterl=max(max(gapmin,criterl),em01*max(depth,drad,gapsupl+dgapload))
        gapsupl=min(gapmax,gapsupl)
#include "lockon.inc"
        criter=min(criter,criterl)
        dist  =min(dist,tzinf-max(gapsupl+dgapload,depth,drad))
        IF( tzinf-gapsupl <= zero)THEN
C assure le retri et remet la marge initiale (on a forcement depth  <= gapsupl)
          tzinf= gapsupl+marge
          dist =-one
        END IF
#include "lockoff.inc"
      ENDIF      
C------------------------------------
      RETURN
      END