aniofff.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    aniofff           ../engine/source/output/anim/generate/aniofff.F
!||--- called by ------------------------------------------------------
!||    genani            ../engine/source/output/anim/generate/genani.F
!||--- calls      -----------------------------------------------------
!||    spmd_iget_partn   ../engine/source/mpi/anim/spmd_iget_partn.F
!||    write_c_c         ../common_source/tools/input_output/write_routtines.c
!||--- uses       -----------------------------------------------------
!||    elbufdef_mod      ../common_source/modules/mat_elem/elbufdef_mod.F90
!||    my_alloc_mod      ../common_source/tools/memory/my_alloc.F90
!||====================================================================
      SUBROUTINE aniofff(ELBUF_TAB,      IPARG ,IOFF ,EL2FA ,
     .                   NBF      ,IADD ,NBPART,IADG ,IOFFX1,
     .                   NANIM1D_L)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE elbufdef_mod   
      USE my_alloc_mod         
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "param_c.inc"
#include      "task_c.inc"
#include      "spmd_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IPARG(NPARG,*),EL2FA(*),NBF,IOFF(*),
     .        IADD(*),NBPART, IADG(NSPMD,*),IOFFX1(*),
     .        nanim1d_l
C
      TYPE (ELBUF_STRUCT_), TARGET, DIMENSION(NGROUP) :: ELBUF_TAB
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,NG,NEL,NFT,ITY,LFT,LLT,N,J,MLW,
     .        NN, K1, K2,MT, IMID,N1,N2,N3,N4,N_FA,
     .        nn1,nn2,nn3,nn4,nn5,nn6,nn7,nn8,nn9,nn10,nbf2,rbuf
      INTEGER,DIMENSION(:),ALLOCATABLE :: IOFFF
C
      TYPE(g_bufel_)  ,POINTER :: GBUF     
C-----------------------------------------------
      CALL my_alloc(iofff,nbf+nanim1d_l)
      nn1 = 1
      nn2 = 1
      nn3 = 1
      nn4 = nn3 
      nn5 = nn4 
      nn6 = nn5 
      nn7 = nn6 + numelt
      nn8 = nn7 + numelp
      nn9 = nn8 + numelr
      nn10= nn9 
C-----------------------------------------------
      DO ng=1,ngroup
        mlw   =iparg(1,ng)
        nel   =iparg(2,ng)
        ity   =iparg(5,ng)
        nft   =iparg(3,ng)
        lft=1
        llt=nel
C
        gbuf => elbuf_tab(ng)%GBUF
C-----------------------------------------------
C       TRUSS
C-----------------------------------------------
        IF (ity == 4) THEN
          n_fa = nn6 + nft
C-----------------------------------------------
C       POUTRES
C-----------------------------------------------
        ELSEIF (ity == 5) THEN
          n_fa = nn7 + nft
C-----------------------------------------------
C       RESSORTS
C-----------------------------------------------
        ELSEIF (ity == 6) THEN
          n_fa = nn8 + nft
        ELSE
          ity=0
        ENDIF
C-----------------------------------------------
        IF (ity /= 0) THEN
          IF (mlw == 0 .OR. mlw == 13) THEN
C-----------------------------------------------
C          DUMMY ELEMENTS
C-----------------------------------------------
            IF (ity == 4 .OR. ity == 5) THEN
              DO i=lft,llt
                ioff(el2fa(n_fa+i)) = 1
              ENDDO
            ELSE
              DO i=lft,llt
                ioff(el2fa(n_fa+i)) = 0
              ENDDO
            END IF
C-----------------------------------------------
          ELSEIF (ity == 4 .OR. ity == 5) THEN
            DO i=lft,llt
              ioff(el2fa(n_fa+i)) = nint(min(gbuf%OFF(i),one))
            ENDDO
C-----------------------------------------------
          ELSEIF (ity == 6 .AND. mlw == 3) THEN
C-----------------------------------------------
C          PULLEY SPRING 
C-----------------------------------------------
            DO i=lft,llt
              ioff(el2fa(n_fa+i)) = nint(min(gbuf%OFF(i),one))
              ioff(el2fa(n_fa+i)+1) = nint(min(gbuf%OFF(i),one))
            ENDDO
C-----------------------------------------------                        
          ELSEIF (ity == 1 .or. ity == 2 .or. ity == 51 .or.
     .            ity == 3 .or. ity == 7 .or. ity == 6) THEN
            DO i=lft,llt
              ioff(el2fa(n_fa+i)) = nint(min(gbuf%OFF(i),one))
            ENDDO
          ENDIF ! IF (MLW == 0 .OR. MLW == 13)
        ENDIF ! IF (ITY /= 0) THEN
C-----------------------------------------------
      ENDDO ! NGROUP
C-----------------------------------------------
      IF (nspmd == 1) THEN
        CALL write_c_c(ioff,nbf)
        CALL write_c_c(ioffx1,nanim1d)
      ELSE
        DO i = 1, nbf
          iofff(i) = ioff(i)
        ENDDO
        DO i=1,nanim1d_l
          iofff(i+nbf)=ioffx1(i)
        ENDDO
        nbf2 = nbf + nanim1d_l
        IF (ispmd == 0) THEN
          rbuf = nb1dg+nanim1d
        ELSE
          rbuf = 1
        ENDIF
        CALL spmd_iget_partn(1,nbf2,iofff,nbpart,iadg,rbuf,2)
      ENDIF ! IF (NSPMD == 1)
C-----------
      DEALLOCATE(iofff)
      RETURN
      END