estim_flops.F

Go to the documentation of this file.

C
C  This file is part of MUMPS 5.5.1, released
C  on Tue Jul 12 13:17:24 UTC 2022
C
C
C  Copyright 1991-2022 CERFACS, CNRS, ENS Lyon, INP Toulouse, Inria,
C  Mumps Technologies, University of Bordeaux.
C
C  This version of MUMPS is provided to you free of charge. It is
C  released under the CeCILL-C license 
C  (see doc/CeCILL-C_V1-en.txt, doc/CeCILL-C_V1-fr.txt, and
C  https://cecill.info/licences/Licence_CeCILL-C_V1-en.html)
C
      SUBROUTINE mumps_estim_flops( INODE, N, PROCNODE_STEPS,
     &           KEEP199,
     &           ND, FILS, FRERE_STEPS, STEP, PIMASTER,
     &           KEEP28, KEEP50, KEEP253,
     &           FLOP1,
     &           IW, LIW, XSIZE )
      IMPLICIT NONE
      INTEGER INODE, N, KEEP50, LIW, KEEP199, KEEP28, KEEP253
      INTEGER PROCNODE_STEPS(KEEP28), ND(KEEP28),
     &        FILS(N), FRERE_STEPS(KEEP28),
     &        STEP(N), 
     & pimaster(keep28),
     &  iw( liw )
      INTEGER XSIZE
      DOUBLE PRECISION FLOP1
      INTEGER NUMORG, IN, NASS, IFSON, NUMSTK, NFRONT, NPIV, NCB, 
     &        LEVEL, ISON
      LOGICAL MUMPS_IN_OR_ROOT_SSARBR
      INTEGER MUMPS_TYPENODE
      EXTERNAL mumps_in_or_root_ssarbr, mumps_typenode
      include 'mumps_headers.h'
      flop1 = 0.0d0
      IF (mumps_in_or_root_ssarbr(procnode_steps(step(inode)),
     &                keep199) ) RETURN
      in     = inode
      numorg = 0
   10 numorg = numorg + 1
      in = fils(in)
      IF (in .GT. 0) GOTO 10
      numstk = 0
      nass = 0
      ifson = -in
      ison = ifson
      IF (ison .EQ. 0) GOTO 30
   20 numstk = numstk + 1
      nass = nass + iw(pimaster(step(ison)) + 1 +xsize)
      ison = frere_steps(step(ison))
      IF (ison .GT. 0) GOTO 20
   30 nfront = nd(step(inode)) + nass + keep253
      npiv  = nass + numorg
      ncb   = nfront - npiv
      level = mumps_typenode(procnode_steps(step(inode)),keep199)
      CALL mumps_get_flops_cost(nfront,npiv,npiv,keep50,level,flop1)
      RETURN
      END SUBROUTINE mumps_estim_flops
      SUBROUTINE mumps_update_flops_root(OPELIW, KEEP50, NFRONT, NPIV,
     &           NPROW, NPCOL, MYID)
      DOUBLE PRECISION, intent(inout) :: OPELIW
      INTEGER, intent(in) :: KEEP50, NFRONT, NPIV,
     &           nprow, npcol, myid
      DOUBLE PRECISION :: COST, COST_PER_PROC
      INTEGER, PARAMETER :: LEVEL3 = 3
      call mumps_get_flops_cost(nfront, npiv, nfront, keep50, level3, 
     &                          cost)
      cost_per_proc = dble(int( cost,8) / int(nprow * npcol,8))
      opeliw = opeliw + cost_per_proc
      RETURN
      END SUBROUTINE mumps_update_flops_root
      SUBROUTINE mumps_get_flops_cost(NFRONT,NPIV,NASS,
     &                                 KEEP50,LEVEL,COST)
      IMPLICIT NONE
      INTEGER, intent(in) :: NFRONT,NPIV,KEEP50,LEVEL, NASS
      DOUBLE PRECISION, intent(out) :: COST
      IF (keep50.EQ.0) THEN
        IF (level.EQ.1 .OR. level.EQ.3) THEN
          cost = dble(2) * dble(nfront) * dble(npiv) *
     &      dble(nfront - npiv - 1) +
     &      dble(npiv) * dble(npiv + 1) * dble(2 * npiv + 1)
     &          / dble(3)
          cost = cost + dble(2 * nfront - npiv - 1)
     &      * dble(npiv) /dble(2)
        ELSEIF (level.EQ.2) THEN
          cost = dble(2*nass)*dble(nfront) -
     &          dble(nass+nfront)*dble(npiv+1)
          cost = dble(npiv)*cost +
     &     dble(2 * nass - npiv - 1) * dble(npiv) / dble(2) +
     &     dble(npiv) * dble(npiv + 1) *
     &     dble(2 * npiv + 1) /dble(3)
        ENDIF
      ELSE
        IF (level.EQ.1 .OR. (level.EQ.3 .AND. keep50.EQ.1)) THEN
          cost = dble(npiv) * (
     &          dble( nfront ) * dble( nfront ) +
     &          dble( nfront ) - (
     &          dble( nfront)*dble(npiv) + dble(npiv+1)
     &          )) +( dble(npiv)*dble(npiv+1)
     &          *dble(2*npiv+1))/ dble(6)
        ELSE IF (level.EQ.3.AND.keep50.EQ.2) THEN
          cost = dble(2) * dble(nfront) * dble(npiv) *
     &      dble(nfront - npiv - 1) +
     &      dble(npiv) * dble(npiv + 1) *
     &      dble(2 * npiv + 1) / dble(3)
          cost = cost + dble(2 * nfront - npiv - 1)
     &         * dble(npiv) / dble(2)
        ELSE
          cost = dble(npiv) * (
     &          dble( nass ) * dble( nass ) + dble( nass )
     &        - ( dble( nass) * dble(npiv) + dble( npiv + 1 ) ) )
     &        + ( dble(npiv)*dble(npiv+1)*dble(2*npiv+1) )
     &        / dble( 6 )
        ENDIF
      ENDIF
      RETURN
      END SUBROUTINE mumps_get_flops_cost
      SUBROUTINE mumps_print_still_active(MYID, KEEP, DKEEP17, OPELIW, 
     &                        OPLAST_PRINTED, MPA)
      IMPLICIT NONE
      INTEGER, intent(in)             :: KEEP (500), MYID, MPA
      DOUBLE PRECISION                :: DKEEP17
      DOUBLE PRECISION, intent(in)    :: OPELIW
      DOUBLE PRECISION, intent(inout) :: OPLAST_PRINTED
      IF (mpa.GT.0) THEN
        IF ( (opeliw-oplast_printed).GT. dkeep17) THEN
         WRITE(mpa,'(A,I6,A,A,1PD10.3)')
     &   ' ... MPI process', myid, 
     &   ': theoretical number of flops locally performed',
     &   ' so far        = ',
     &    opeliw
         oplast_printed = opeliw
        ENDIF
      ENDIF
      RETURN
      END SUBROUTINE mumps_print_still_active