fail_cockroft_ib.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fail_cockroft_ib   ../engine/source/materials/fail/cockroft_latham/fail_cockroft_ib.F
!||--- called by ------------------------------------------------------
!||    fail_beam18        ../engine/source/elements/beam/fail_beam18.F
!||====================================================================
      SUBROUTINE fail_cockroft_ib(                                         
     .          NEL      ,NGL      ,NUPARAM  ,UPARAM  ,
     .          TIME     ,DPLA     ,OFF      ,DFMAX,  
     .          TDEL     ,IOUT     ,ISTDO    ,EPSXX    ,
     .          IPT      ,SIGNXX   ,SIGNXY   ,SIGNXZ   ,
     .          NVARF    , UVAR    ,FOFF     ,UELR,NPG)
!====================================================================
! cockroft  failure model for integrated beams
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include  "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include  "comlock.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER                     ,INTENT(IN)    :: NEL     ! size of element group
      INTEGER                     ,INTENT(IN)    :: NUPARAM ! size of parameter array
      INTEGER                     ,INTENT(IN)    :: IPT     ! current integration point
      INTEGER                     ,INTENT(IN)    :: IOUT    ! output file unit
      INTEGER                     ,INTENT(IN)    :: ISTDO   ! output file unit
      INTEGER                     ,INTENT(IN)    :: NVARF
      INTEGER ,DIMENSION(NEL)     ,INTENT(IN)    :: NGL     ! table of element identifiers
      my_real                     ,INTENT(IN)    :: time    ! current time
      my_real ,DIMENSION(NUPARAM) ,INTENT(IN)    :: uparam  ! failure model parameter array
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: dpla    ! plastic strain increment
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: off     ! element deactivation flag
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: signxx  ! stress component
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: signxy  ! stress component
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: signxz  ! stress component
 
 
      my_real ,DIMENSION(NEL)     ,INTENT(IN)    :: epsxx 
      INTEGER ,DIMENSION(NEL)     ,INTENT(INOUT) :: FOFF    ! integration point deactivation flag
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: dfmax   ! maximum damage
      my_real ,DIMENSION(NEL)     ,INTENT(INOUT) :: tdel    ! deactivation time
      my_real ,DIMENSION(NEL,NVARF),INTENT(INOUT) :: uvar  
      my_real, DIMENSION(NEL)     ,INTENT(INOUT)  :: uelr 
      INTEGER                      ,INTENT(IN)    :: NPG    
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,NINDXF,failip
      INTEGER ,DIMENSION(NEL) :: INDXF
      my_real
     .                            C0,EMA,EEQ,SIG_A,SIG_FILTRE,R,Q,I1,S11,
     .                            S22 , S33,R_INTER,PHI,I2 
      my_real ,DIMENSION(NEL) ::  eps_eq,damage,epsrate,eps11,epsi,d_eeq
C=======================================================================
C     UVAR(I,1) contains previous equivalent strain value increment
C     UVAR(I,2) contains the Cockroft-Latham accumulated value
c     UVAR(I,3) contains the previous first principal stress
c     UVAR(I,4) contains total strain
      c0                  = uparam(1)
      ema                 = uparam(2)
      failip  = min(nint(uparam(3)),npg) !   Number of failed integration point prior to solid element deletion. default = 1 (integer)
 
      nindxf              = 0                                   
c-----------------------------   
      IF(c0 < zero)THEN   ! equivalent strain 
        DO i =1,nel
          IF(off(i) == one .AND. foff(i) == 1  ) THEN 
            eeq   = abs(epsxx(i))         
            d_eeq(i) = eeq - uvar(i,1)
            IF (d_eeq(i) <= zero) d_eeq(i) = zero
            uvar(i,1) = eeq             
          ENDIF
        ENDDO
      ELSE  ! positive = plastic strain increment
        DO i =1,nel
          IF(off(i) == one .AND. foff(i) == 1  ) THEN 
            d_eeq(i) = dpla(i)
            uvar(i,1) = uvar(i,1) + dpla(i)
          ENDIF
        ENDDO
      ENDIF
 
 
      DO i =1,nel
        IF(off(i) == one .AND. foff(i) == 1  ) THEN
          !   principal stress calculation
          i1 = signxx(i) 
          i2 = -signxy(i)*signxy(i)-signxz(i)*signxz(i)
          
          q  = (three*i2 - i1*i1)/nine
          r  = (two*i1*i1*i1 - nine*i1*i2 )/cinquante4     
           
          r_inter = min(r/sqrt(max(em20,(-q**3))),one)
          phi = acos(max(r_inter,-one))
           
          s11 = two*sqrt(-q)*cos(phi/three)+third*i1
          s22 = two*sqrt(-q)*cos((phi+two*pi)/three)+third*i1
          s33 = two*sqrt(-q)*cos((phi+four*pi)/three)+third*i1
 
          sig_a = max(s11  ,s22 )
          sig_a = max(sig_a,s33 )
 
 
          IF (sig_a>zero)THEN
            sig_filtre   = sig_a * ema + (one-ema)* uvar(i,3)
            uvar(i,3)= sig_filtre
            !integral
            uvar(i,2) = uvar(i,2) + max(sig_filtre,zero) * d_eeq(i)
          ENDIF
 
          !damage
          dfmax(i) =  min(uvar(i,2) / max(em20,abs(c0))  ,one)
          
          IF (dfmax(i) >= one) THEN
            foff(i) = 0
            tdel(i) = time 
            nindxf  = nindxf + 1  
            indxf(nindxf) = i
            dfmax(i)      = one
            uelr(i)     = uelr(i) + one
            IF (nint(uelr(i)) >= failip) THEN 
              off(i)    = four_over_5
            ENDIF
          ENDIF 
        ENDIF
      ENDDO
C!
      DO  j = 1,nindxf
         i = indxf(j)
#include "lockon.inc"
          WRITE(iout, 1000) ngl(i),ipt,time
          WRITE(istdo,1000) ngl(i),ipt,time
          IF (off(i) == four_over_5) THEN 
            WRITE(iout, 1111) ngl(i),time
            WRITE(istdo,1111) ngl(i),time
          ENDIF  
#include "lockoff.inc" 
 
       ENDDO
c------------------
 1000 FORMAT(5x,'FAILURE (COCKROFT-LATHAM) OF BEAM ELEMENT ',i10,1x,',INTEGRATION PT',i5
     .      ,2x,'AT TIME :',1pe12.4)
 1111 FORMAT(1x,'DELETED BEAM ELEMENT ',i10,1x,'AT TIME :',1pe12.4)
c------------------
 
       RETURN
       END