fail_energy_c.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fail_energy_c   ../engine/source/materials/fail/energy/fail_energy_c.F
!||--- called by ------------------------------------------------------
!||    mulawc          ../engine/source/materials/mat_share/mulawc.F90
!||    usermat_shell   ../engine/source/materials/mat_share/usermat_shell.F
!||--- calls      -----------------------------------------------------
!||    finter          ../engine/source/tools/curve/finter.F
!||====================================================================
      SUBROUTINE fail_energy_c(
     1     NEL      ,NUPARAM  ,NUVAR    ,NFUNC    ,IFUNC    ,
     2     UPARAM   ,UVAR     ,NPF      ,TF       ,TIME     , 
     3     NGL      ,IPG      ,ILAY     ,IPT      ,EPSP     ,
     4     AREA     ,THK      ,DMG_FLAG ,
     5     DMG_SCALE,OFF      ,FOFF     ,DFMAX    ,TDEL     ,
     6     SIGNXX   ,SIGNYY   ,SIGNXY   ,SIGNYZ   ,SIGNZX   ,
     7     DEPSXX   ,DEPSYY   ,DEPSXY   ,DEPSYZ   ,DEPSZX   )
C-----------------------------------------------
C    energy failure model
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include "units_c.inc"
#include "comlock.inc"
C---------+---------+---+---+--------------------------------------------
C VAR     | SIZE    |TYP| RW| DEFINITION
C---------+---------+---+---+--------------------------------------------
C NEL     |  1      | I | R | SIZE OF THE ELEMENT GROUP NEL 
C NUPARAM |  1      | I | R | SIZE OF THE USER PARAMETER ARRAY
C UPARAM  | NUPARAM | F | R | USER MATERIAL PARAMETER ARRAY
C NUVAR   |  1      | I | R | NUMBER OF USER ELEMENT VARIABLES
C UVAR    |NEL*NUVAR| F |R/W| USER ELEMENT VARIABLE ARRAY
C---------+---------+---+---+--------------------------------------------
C TIME    |  1      | F | R | CURRENT TIME
C---------+---------+---+---+--------------------------------------------
C EINT    | NEL     | F | R | INTERNAL ENERGY
C---------+---------+---+---+--------------------------------------------
C OFF     | NEL     | F | R | DELETED ELEMENT FLAG (=1. ON, =0. OFF)
C FOFF    | NEL     | I |R/W| DELETED INTEGRATION POINT FLAG (=1 ON, =0 OFF)
C DFMAX   | NEL     | F |R/W| MAX DAMAGE FACTOR 
C TDEL    | NEL     | F | W | FAILURE TIME
C DMG_FLAG|  1      | I | W | STRESS REDUCTION FLAG DUE TO DAMAGE
C DMG_SCALE| NEL    | F | W | STRESS REDUCTION FACTOR
C---------+---------+---+---+--------------------------------------------
C NGL                         ELEMENT ID
C IPG                         CURRENT GAUSS POINT (in plane)
C ILAY                        CURRENT LAYER
C IPT                         CURRENT INTEGRATION POINT IN THE LAYER
C---------+---------+---+---+--------------------------------------------
C   I N P U T   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NEL,NUPARAM,NUVAR,IPG,ILAY,IPT
      INTEGER ,DIMENSION(NEL) ,INTENT(IN) :: NGL
      my_real ,INTENT(IN) :: TIME
      my_real ,DIMENSION(NEL) ,INTENT(IN)    :: AREA,THK,EPSP,OFF,
     .  SIGNXX,SIGNYY,SIGNXY,SIGNYZ,SIGNZX,DEPSXX,DEPSYY,DEPSXY,
     .  DEPSYZ,DEPSZX
      my_real,DIMENSION(NUPARAM) ,INTENT(IN) :: UPARAM
C-----------------------------------------------
C   I N P U T   O U T P U T   A r g u m e n t s 
C-----------------------------------------------
      INTEGER ,INTENT(OUT) ::DMG_FLAG
      INTEGER ,DIMENSION(NEL) ,INTENT(INOUT) :: FOFF
      my_real ,DIMENSION(NEL) ,INTENT(INOUT) :: DFMAX
      my_real ,DIMENSION(NEL) ,INTENT(OUT)   :: tdel,dmg_scale
      my_real ,DIMENSION(NEL,NUVAR) ,INTENT(INOUT) :: uvar
C-----------------------------------------------
C   VARIABLES FOR FUNCTION INTERPOLATION 
C-----------------------------------------------
      INTEGER NPF(*), NFUNC, IFUNC(NFUNC)
      my_real finter ,tf(*)
      EXTERNAL finter
C        Y = FINTER(IFUNC(J),X,NPF,TF,DYDX)
C        Y       : y = f(x)
C        X       : x
C        DYDX    : f'(x) = dy/dx
C        IFUNC(J): FUNCTION INDEX
C              J : FIRST(J=1), SECOND(J=2) .. FUNCTION USED FOR THIS LAW
C        NPF,TF  : FUNCTION PARAMETER
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,NINDX
      INTEGER ,DIMENSION(NEL) :: INDX
      my_real RFAC,R1,R2,IE_SP,DYDX,RIEF1,RIEF2,XFAC
      my_real DAMAGE(NEL)
C=======================================================================
      RIEF1    = uparam(1)             
      rief2    = uparam(2)           
      xfac     = uparam(4)           
      dmg_flag = int(uparam(5))
      nindx    = 0  
C-----------------------------------------------
      DO i = 1,nel
        IF (off(i) == one .and. foff(i) == 1) THEN
          IF (ifunc(1) /= 0) THEN
            rfac = finter(ifunc(1),epsp(i)*xfac,npf,tf,dydx)
            rfac = max(rfac,em20)
          ELSE
            rfac = one
          ENDIF  
          r1 = rief1*rfac
          r2 = rief2*rfac
 
          uvar(i,1) = uvar(i,1) + signxx(i)*depsxx(i) + 
     .                            signyy(i)*depsyy(i) +
     .                            signxy(i)*depsxy(i) + 
     .                            signyz(i)*depsyz(i) + 
     .                            signzx(i)*depszx(i)
          ie_sp = uvar(i,1)
          IF (ie_sp > r1) THEN
            damage(i) = (ie_sp-r1)/(r2-r1)
            damage(i) = min(one,damage(i))
            dfmax(i)  = max(dfmax(i) ,damage(i))
          ENDIF
          IF (ie_sp > r2) THEN
            nindx = nindx + 1
            indx(nindx) = i
            foff(i) = 0
            tdel(i) = time
          ENDIF                    
        ENDIF                    
      ENDDO
c
      IF (dmg_flag == 1) THEN
        DO i = 1,nel
          dmg_scale(i) = one - dfmax(i)
        ENDDO          
      ENDIF
c------------------------
      IF (nindx > 0) THEN  
        DO j=1,nindx       
          i = indx(j)      
#include  "lockon.inc"
          WRITE(iout, 2000) ngl(i),ipg,ilay,ipt
          WRITE(istdo,2100) ngl(i),ipg,ilay,ipt,time
#include  "lockoff.inc"
        END DO
      END IF              
c------------------------
 2000 FORMAT(1x,'FAILURE (ENERGY) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',
     .       i2,1x,',LAYER',i3,1x,',INTEGRATION PT',i3)
 2100 FORMAT(1x,'FAILURE (ENERGY) OF SHELL ELEMENT ',i10,1x,',GAUSS PT',
     .       i2,1x,',LAYER',i3,1x,',INTEGRATION PT',i3,1x,'AT TIME :',1pe12.4)
c------------------------
      RETURN
      END