failwave_init.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    failwave_init   ../starter/source/materials/fail/failwave_init.F
!||--- called by ------------------------------------------------------
!||    lectur          ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    message_mod     ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE failwave_init(FAILWAVE,IPARG,IXC,IXTG,NUMNOD)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE my_alloc_mod
      USE message_mod
      USE failwave_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NUMNOD
      INTEGER ,DIMENSION(NPARG,NGROUP), INTENT(IN) :: IPARG
      INTEGER ,DIMENSION(NIXC,*)  ,INTENT(IN) :: IXC
      INTEGER ,DIMENSION(NIXTG,*) ,INTENT(IN) :: IXTG
      TYPE (FAILWAVE_STR_) :: FAILWAVE 
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,IFAILWAVE,NG,NEL,NFT,ITY,IGTYP,IFRW,INOD,NNOD,NDDL,SIZE,MAXLEV
      INTEGER ,DIMENSION(:), ALLOCATABLE :: TAGNOD,INDX,IDXI
C=======================================================================
 
      ALLOCATE( tagnod(numnod),indx(numnod),idxi(numnod) )
c
      ifailwave = failwave%WAVE_MOD
      IF (ifailwave == 0) THEN
        failwave%NNOD   = 0
        failwave%NDDL   = 0
        failwave%SIZE   = 0
        ALLOCATE (failwave%FWAVE_NOD(0,0,0))
        ALLOCATE (failwave%FWAVE_NOD_STACK(0,0,0))
        ALLOCATE (failwave%MAXLEV(0))
        ALLOCATE (failwave%INDX(0))
        ALLOCATE (failwave%IDXI(0))
c
      ELSE
c
        tagnod(:) = 0
        indx(:)   = 0
        idxi(:)   = 0
c
        DO ng=1,ngroup
          ifrw = iparg(79,ng)
          IF (ifrw > 0) THEN
            nel   = iparg(2,ng)
            nft   = iparg(3,ng)
            ity   = iparg(5,ng)
            igtyp = iparg(38,ng)
            IF (ity == 3) THEN
              DO i=1,nel
                DO j=2,5
                  inod = ixc(j,i+nft)
                  tagnod(inod) = 1
                ENDDO      
              ENDDO      
            ELSE IF (ity == 7) THEN
              DO i=1,nel
                DO j=2,4
                  inod = ixtg(j,i+nft)
                  tagnod(inod) = 1
                ENDDO      
              ENDDO      
            ENDIF
          ENDIF
        ENDDO      
c
        nnod = 0
        DO i=1,numnod
          IF (tagnod(i) == 1) THEN
            nnod = nnod + 1
            indx(nnod) = i                ! INDX(nnod)   -> NUMNOD
            idxi(i)    = nnod             ! IDXI(numnod) -> NNOD
          ENDIF
        ENDDO
c
        IF (ifailwave == 1) THEN   ! isotropic propagation
          nddl   = 1
          SIZE   = 1
        ELSE                       ! directional propagation
          nddl   = 2
          SIZE   = 10
        ENDIF
        failwave%NNOD = nnod
        failwave%SIZE = SIZE
        failwave%NDDL = nddl
        CALL my_alloc (failwave%INDX,nnod)
        CALL my_alloc (failwave%IDXI,numnod)
        CALL my_alloc (failwave%MAXLEV,0)
        CALL my_alloc (failwave%MAXLEV_STACK,0)
        ALLOCATE (failwave%FWAVE_NOD(nddl,numnod,size))
        ALLOCATE (failwave%FWAVE_NOD_STACK(nddl,numnod,size))
c
        failwave%INDX(1:nnod)  = indx(1:nnod)
        failwave%IDXI(1:numnod)= idxi(1:numnod)
        failwave%FWAVE_NOD = 0
        failwave%FWAVE_NOD_STACK = 0
      ENDIF
 
      DEALLOCATE( tagnod,indx,idxi )    
c
c--------------------------------
      RETURN
      END