find_closest_node.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    find_closest_node   ../starter/source/initial_conditions/inivol/find_closest_node.F
!||--- called by ------------------------------------------------------
!||    phase_detection     ../starter/source/initial_conditions/inivol/phase_detection.F
!||====================================================================
        SUBROUTINE find_closest_node(LEADING_DIRECTION,N1,N2,N3,
     .                                             X1,X2,EPS, 
     .                                             KEY1,KEY2,ID_X2,ID_LIST)
!---
C  Nearest Neighbor search
C  This routines returns ID_LIST and DIST such as
C  ID_LIST(I=1:N2) is the id of the closest node in X1(ID_X2(1:N2))
C
C This NNS algorithm is not optimal
C - worst case O(N1 x N2) 
C - best case O(N1 x LOG(N1)) + O(N1)
C - Expected in practice: O(N1 log(N1)) + O (N1 x (N2)^(1/3)) 
C      which is good enough for cases where N2 << N1
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
! com04 : numels/numelq/numeltg
#include "com04_c.inc"
       
! --------------------------------------
        INTEGER, INTENT(IN) :: LEADING_DIRECTION
        INTEGER, INTENT(IN)    ::  N1,N2,N3  ! N1: number if node
                                             ! N2: number of root nodes
                                             ! N3 : total number of node
        my_real, DIMENSION(3,N1), INTENT(IN)    ::  x1 ! Coordinates 
        my_real, DIMENSION(3,N3), INTENT(IN)    ::  x2 ! Coordinates 
        my_real, INTENT(IN)    ::  eps  ! Minimum distance between two distinct points
        INTEGER, DIMENSION(N1), INTENT(IN) :: KEY1
        INTEGER, DIMENSION(N2), INTENT(IN) ::  KEY2
        INTEGER, DIMENSION(N2), INTENT(IN) ::  ID_X2  ! Indexes of 'root' coordinates
        INTEGER, DIMENSION(N1),INTENT(INOUT) ::  ID_LIST! id of the closest root node
! --------------------------------------
C      LOCAL VARIABLES
        INTEGER :: I,J,ID,info,JMIN
        INTEGER :: LAST_POSITION
        my_real :: leading_size
        my_real :: delta,dx,dy,dz,dxl,dyl,dzl,dl
        integer :: ijk
! --------------------------------------
        last_position = 1 
        jmin = 1
        DO i = 1,n1
            dx =abs(x2(1,id_x2(key2(last_position))) - x1(1,key1(i)))   
            dy =abs(x2(2,id_x2(key2(last_position))) - x1(2,key1(i)))   
            dz =abs(x2(3,id_x2(key2(last_position))) - x1(3,key1(i)))   
            leading_size = abs(x2(leading_direction,id_x2(key2(last_position))) - x1(leading_direction,key1(i)))   
            delta = sqrt(dx*dx+dy*dy+dz*dz)
 
C        Avoid nodes closer than EPS
            IF (delta < eps) delta = huge(delta)
 
C        Upward search
            j = last_position + 1
            jmin = last_position
            id = key2(last_position)
            dxl = leading_size
            DO WHILE (j <= n2 .AND. (dxl <= delta .OR. delta < eps))
                dxl =abs(x2(1,id_x2(key2(j))) - x1(1,key1(i)))   
                dyl =abs(x2(2,id_x2(key2(j))) - x1(2,key1(i)))   
                dzl =abs(x2(3,id_x2(key2(j))) - x1(3,key1(i)))   
                dl = sqrt(dxl*dxl+dyl*dyl+dzl*dzl)
                IF (dl  < delta .AND. dl  > eps) THEN
                    delta = dl
                    id = key2(j)
                    jmin = j
                ENDIF
                j = j + 1
                IF (j <= n2) dxl =abs(x2(leading_direction,id_x2(key2(j)))-x1(leading_direction,key1(i)))  
            ENDDO
 
C        Backward search
            j = last_position
            dxl = leading_size
            DO WHILE (j > 0 .AND. (dxl <= delta .OR. delta < eps))
                dxl =abs(x2(1,id_x2(key2(j))) - x1(1,key1(i)))   
                dyl =abs(x2(2,id_x2(key2(j))) - x1(2,key1(i)))   
                dzl =abs(x2(3,id_x2(key2(j))) - x1(3,key1(i)))   
                dl = sqrt(dxl*dxl+dyl*dyl+dzl*dzl)
                IF (dl  < delta .AND. dl > eps) THEN
                    delta = dl
                    id = key2(j)
                    jmin = j
                ENDIF
                j = j - 1
                IF (j > 0)  dxl =abs(x2(leading_direction,id_x2(key2(j)))-x1(leading_direction,key1(i)))  
            ENDDO
            last_position = jmin 
            id_list(key1(i)) = id
        ENDDO
 
        DO i = 1,n1
            id_list(i) = id_x2(id_list(i))
        ENDDO
 
        RETURN
!---
        END SUBROUTINE find_closest_node