func_slope.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    func_slope    ../starter/source/tools/curve/func_slope.F
!||--- called by ------------------------------------------------------
!||    law111_upd    ../starter/source/materials/mat/mat111/law111_upd.F
!||    law158_upd    ../starter/source/materials/mat/mat158/law158_upd.F
!||    law58_upd     ../starter/source/materials/mat/mat058/law58_upd.F
!||    law77_upd     ../starter/source/materials/mat/mat077/law77_upd.F
!||    law90_upd     ../starter/source/materials/mat/mat090/law90_upd.F
!||--- uses       -----------------------------------------------------
!||    message_mod   ../starter/share/message_module/message_mod.F
!||    table_mod     ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE func_slope(IDN,FAC,NPC,PLD,STIFFMIN,STIFFMAX,STIFFINI,STIFFAVG)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE table_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IDN,NPC(*) 
      my_real pld(*),fac,stiffmin,stiffmax,stiffini,stiffavg
C-----------------------------------------------
      INTENT(IN)    :: npc,pld,idn
      INTENT(OUT)   :: stiffmax,stiffini,stiffavg
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER J,PN1,PN2,COUNT
      my_real dydx,dx,dy
C=======================================================================
          ! COMPUTE MAXIMUM SLOPE AND INITIAL SLOPE OF FUNCTION
C=======================================================================
      pn1 = npc(idn)
      pn2 = npc(idn+1)
      stiffini = zero
      stiffavg = zero
      stiffmax = zero
      stiffmin = ep20
      count = 0
      DO j = pn1,pn2-4,2
        count = count + 1
        dx = pld(j+2) - pld(j)
        dy = pld(j+3) - pld(j+1)               
        dydx = fac*dy/dx
        stiffmax = max(stiffmax,dydx)
        stiffmin = min(stiffmin,dydx)
        stiffavg = stiffavg + dydx
        IF(pld(j+2)== zero )THEN
           dx = pld(j+2) - pld(j)
           dy = pld(j+3) - pld(j+1)            
           stiffini = max(stiffini, fac*dy/dx)
        ELSEIF(pld(j) == zero) THEN
           dx = pld(j+2) - pld(j)
           dy = pld(j+3) - pld(j+1)             
           stiffini = max(stiffini, fac*dy/dx)
        ELSEIF(pld(pn1) >= zero) THEN
           dx = pld(pn1+2) - pld(pn1 )
           dy = pld(pn1+3) - pld(pn1 + 1)             
           stiffini = max(stiffini, fac*dy/dx)
        ENDIF
      ENDDO
      stiffavg = stiffavg / count
c-----------
      RETURN
      END
C=======================================================================
!||====================================================================
!||    unify_x       ../starter/source/tools/curve/func_slope.F
!||--- uses       -----------------------------------------------------
!||    message_mod   ../starter/share/message_module/message_mod.F
!||    table_mod     ../starter/share/modules1/table_mod.F
!||====================================================================
      SUBROUTINE unify_x(IDN1,IDN2,NPC,PLD,NPOINT,LEN1,LEN2,XUNI,NPTNEW)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE table_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER     IDN1,IDN2,NPOINT,LEN1,LEN2,
     .        NPTNEW,NPC(*) 
      my_real 
     .        pld(*),xuni(npoint) 
C-----------------------------------------------
      INTENT(IN)    :: npc,pld
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I,J,K
      my_real 
     .      ec , et  
c=======================================================================
       !IDN1 = IFUNC(1) ! uni C
       !IDN2 = IFUNC(2) ! uni T
       i = 0
       j = 0
       ec = pld(npc(idn1) )
       et = pld(npc(idn2) )
       DO k = 1,npoint
        IF(i == 2*len1 .AND. j == 2*len2 )THEN 
         EXIT
        ELSE
         IF     ((ec < et.AND.i<2*len1) .OR. j >= 2*len2)THEN
           xuni(k) = ec 
           i = i + 2 
           ec = pld(npc(idn1)+ i )
         ELSEIF ((ec > et.AND.j<2*len2)   .OR. i >= 2*len1)THEN  
           xuni(k) = et 
           j = j + 2
           et = pld(npc(idn2)+ j )
         ELSEIF (ec == et)THEN 
           xuni(k) = et 
           i = i + 2
           j = j + 2
           ec = pld(npc(idn1)+ i )
           et = pld(npc(idn2)+ j )
         ENDIF
        ENDIF
       ENDDO
       nptnew = k
c-----------
      RETURN
      END