fvinjnormal.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fvinjnormal_mod   ../starter/source/airbag/fvinjnormal.F
!||--- called by ------------------------------------------------------
!||    fvmesh0           ../starter/source/airbag/fvmesh0.F
!||====================================================================
      MODULE fvinjnormal_mod
      CONTAINS
!||====================================================================
!||    fvinjnormal   ../starter/source/airbag/fvinjnormal.F
!||--- called by ------------------------------------------------------
!||    fvmesh0       ../starter/source/airbag/fvmesh0.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE fvinjnormal(IBUF, ELEM, IXC, IXTG, ELTG,
     .                       NEL, ILVOUT, MINUS_SIGN_REVERSE)
      use element_mod , only : nixc,nixtg
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IXC(NIXC,*), IXTG(NIXTG,*)
      INTEGER IBUF(*), ELEM(3,*), ELTG(*)
      INTEGER NEL, ILVOUT
      INTEGER MINUS_SIGN_REVERSE(NEL)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, J, K, I1, I2, I3
      INTEGER N1, N2, N3, N4, IEL, IREVERSE
      CHARACTER*6 TITL
C-----------------------------------------------------------------------
C REDEFINE INTERNAL TRIANGLE FOR NORMAL CONSISTENCY FOR INJECTORS
C-----------------------------------------------------------------------
      IF (ilvout >= 2) WRITE(iout,1000)
      DO i=1,nel
         i1=elem(1,i)
         i2=elem(2,i)
         i3=elem(3,i)
         i1=ibuf(i1)
         i2=ibuf(i2)
         i3=ibuf(i3)
         iel=eltg(i)
         ireverse=0
         IF (iel<=numelc) THEN
            n1  =ixc(2,iel)
            n2  =ixc(3,iel)
            n3  =ixc(4,iel)
            n4  =ixc(5,iel)
            k   =ixc(nixc,iel)
            titl='SHELL:'
            IF(i1==n1) THEN
               IF(i2==n3) THEN
                   IF(i3==n2) ireverse=1
               ELSEIF(i2==n4) THEN
                   ireverse=1
               ENDIF
            ELSEIF(i1==n2) THEN
               IF(i2==n4) THEN
                   IF(i3==n3) ireverse=1
               ELSEIF(i2==n1) THEN
                   ireverse=1
               ENDIF
            ELSEIF(i1==n3) THEN
               IF(i2==n1) THEN
                   IF(i3==n4) ireverse=1
               ELSEIF(i2==n2) THEN
                   ireverse=1
               ENDIF
            ELSEIF(i1==n4) THEN
               IF(i2==n2) THEN
                   IF(i3==n1) ireverse=1
               ELSEIF(i2==n3) THEN
                   ireverse=1
               ENDIF
            ENDIF
          ELSEIF (iel>numelc) THEN
               j=iel-numelc
               n1  =ixtg(2,j)
               n2  =ixtg(3,j)
               n3  =ixtg(4,j)
               k   =ixtg(nixtg,j)
               titl='SH3N: '
               IF(i1==n1.AND.i2==n3) ireverse=1
               IF(i1==n2.AND.i2==n1) ireverse=1
               IF(i1==n3.AND.i2==n2) ireverse=1
          ENDIF
C
           IF(ireverse==1 .AND. minus_sign_reverse(i)==0) THEN
               i2=elem(2,i)
               i3=elem(3,i)
               elem(2,i)=i3
               elem(3,i)=i2
              IF(ilvout >= 2) THEN
              WRITE(iout,1100) i,titl,k
              ENDIF
           ENDIF
C
      ENDDO
C---+----1----+----2----+----3----+----4----+----5----+----6----+----7--     
 1000 FORMAT(/5x,'FVMBAG   INTERNAL SURFACE ELEMENTS RENUMBERED'
     .       /5x,'---------------------------------------------')
 1100 FORMAT( 5x,'TRIANGLE',i8,5x,a,i8)
      RETURN
      END SUBROUTINE fvinjnormal
      END MODULE fvinjnormal_mod