fvventholeint.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fvventholeint   ../starter/source/airbag/fvventholeint.F
!||--- called by ------------------------------------------------------
!||    fvmesh0         ../starter/source/airbag/fvmesh0.F
!||--- uses       -----------------------------------------------------
!||====================================================================
      SUBROUTINE fvventholeint(IBUF  , ELEM   , IBAGHOL,
     .                         NVENT , IGRSURF,
     .                         ITAGEL, NN     , NEL, NB_NODE) 
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "param_c.inc"
#include      "com04_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IBUF(*), ELEM(3,*), IBAGHOL(NIBHOL,*), 
     .        NVENT,
     .        itagel(*), nn, nel, nb_node
      TYPE (SURF_)   , DIMENSION(NSURF)   :: IGRSURF
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER I, II, ITABINV(NB_NODE), ITAGVENT(NN),
     .        ISU, NELSU, IEL, NG1, NG2, NG3, NG4, N1, N2, N3, N4,
     .        ivent, nall, nn1, nn2, iventyp
C----------------------------------------------------
      DO i=1,nb_node
         itabinv(i)=0
      ENDDO
C
      DO i=1,nn
         ii=ibuf(i)
         itabinv(ii)=i
         itagvent(i)=0
      ENDDO
C     
      DO ivent=1,nvent
         isu=ibaghol(2,ivent)
         IF(isu == 0) cycle
         iventyp=ibaghol(13,ivent)
         IF(iventyp == 0) cycle
         nelsu=igrsurf(isu)%NSEG
         DO i=1,nelsu
            ng1 = igrsurf(isu)%NODES(i,1)
            ng2 = igrsurf(isu)%NODES(i,2)
            ng3 = igrsurf(isu)%NODES(i,3)
            ng4 = igrsurf(isu)%NODES(i,4)
            n1=itabinv(ng1)
            n2=itabinv(ng2)
            n3=itabinv(ng3)
            n4=itabinv(ng4)
            itagvent(n1)=ivent
            itagvent(n2)=ivent
            itagvent(n3)=ivent
            itagvent(n4)=ivent
         ENDDO
      ENDDO
C
      DO iel=1,nel
         IF(itagel(iel) > 0) cycle   ! injecteur
         n1=elem(1,iel)
         n2=elem(2,iel)
         n3=elem(3,iel)
         nall=itagvent(n1)*itagvent(n2)*itagvent(n3)
         IF(nall/=0) THEN
            nn1=itagvent(n2)-itagvent(n1)
            nn2=itagvent(n3)-itagvent(n1)
            IF (nn1 == 0 .AND. nn2 == 0) itagel(iel)=-itagvent(n1)
         ENDIF 
      ENDDO
C
      RETURN
      END