fxgrvcor.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    fxgrvcor           ../engine/source/constraints/fxbody/fxgrvcor.F
!||--- called by ------------------------------------------------------
!||    resol              ../engine/source/engine/resol.F
!||--- calls      -----------------------------------------------------
!||    finter             ../engine/source/tools/curve/finter.F
!||--- uses       -----------------------------------------------------
!||    finter_mixed_mod   ../engine/source/tools/finter_mixed.F90
!||    python_funct_mod   ../common_source/modules/python_mod.F90
!||====================================================================
      SUBROUTINE fxgrvcor(FXBIPM, FXBGRVI , A      , IGRV, AGRV,
     .                    NPC   , TF      , MS     , V   , SKEW,
     .                    FXBGRW, IAD_ELEM, FR_ELEM, WFEXT,python)
        use python_funct_mod, only : python_
        use finter_mixed_mod, only : finter_mixed
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com04_c.inc"
#include      "com06_c.inc"
#include      "com08_c.inc"
#include      "param_c.inc"
#include      "fxbcom.inc"
#include      "com01_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER FXBIPM(NBIPM,*), FXBGRVI(*), IGRV(NIGRV,*), NPC(*), IAD_ELEM(2,*), FR_ELEM(*)
      my_real  A(3,*), AGRV(LFACGRV,*), TF(*), MS(*), V(3,*), SKEW(LSKEW,*), FXBGRW(*)
      DOUBLE PRECISION, INTENT(INOUT) :: WFEXT
      TYPE(python_), intent(inout) :: python
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NFX, NLG, AGRVI, IADG, IG, NL, NNO, ISK, N2, N1, IFUNC,
     .        I, K1, K2, K3, IAGRV(NUMNOD), J, JJ
      my_real
     .        fi0, fi, dydx, wfextt, vv
      my_real finter
      EXTERNAL finter
C
      DO i=1,numnod
         iagrv(i)=1
      ENDDO
      IF (nspmd>1) THEN
         DO i=1,nspmd
            DO j=iad_elem(1,i),iad_elem(1,i+1)-1
               jj=fr_elem(j)
               iagrv(jj)=iagrv(jj)+1
            ENDDO
         ENDDO
      ENDIF
C
      wfextt=zero
      DO nfx=1,nfxbody
         nlg=fxbipm(25,nfx)
         agrvi=fxbipm(26,nfx)
         iadg=0
         DO ig=1,nlg
            nl=fxbgrvi(agrvi+iadg)
            nno=fxbgrvi(agrvi+iadg+1)
            isk=igrv(2,nl)/10
            n2=igrv(2,nl)-10*isk
            ifunc=igrv(3,nl)
            IF (ifunc > 0) THEN
              fi0=agrv(1,nl)*finter_mixed(python,nfunct,ifunc,(tt-dt1)*agrv(2,nl),npc,tf)
              fi =agrv(1,nl)*finter_mixed(python,nfunct,ifunc,tt*agrv(2,nl),npc,tf)
            ELSE
              fi0= agrv(1,nl)
              fi = agrv(1,nl)
            ENDIF
            IF (isk<=1) THEN
               DO i=1,nno
                  n1=fxbgrvi(agrvi+iadg+i+1)
                  a(n2,n1)=a(n2,n1)-fi
                  wfextt=wfextt+half*(fi0+fi)*ms(n1)*v(n2,n1)*dt1
     .                                /iagrv(n1)
               ENDDO
            ELSE
               k1=3*n2-2
               k2=3*n2-1
               k3=3*n2
               DO i=1,nno
                  n1=fxbgrvi(agrvi+iadg+i+1)
                  vv = skew(k1,isk)*v(1,n1)+skew(k2,isk)*v(2,n1)+
     .                 skew(k3,isk)*v(3,n1)
                  a(1,n1)=a(1,n1)-skew(k1,isk)*fi
                  a(2,n1)=a(2,n1)-skew(k2,isk)*fi
                  a(3,n1)=a(3,n1)-skew(k3,isk)*fi
                  wfextt=wfextt+half*(fi0+fi)*ms(n1)*vv*dt1/iagrv(n1)
               ENDDO
            ENDIF
            iadg=iadg+2+nno
         ENDDO
         wfext=wfext-wfextt+fxbgrw(nfx)
      ENDDO
C
      RETURN
      END