gravit_imp.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    gravit_imp         ../engine/source/loads/general/grav/gravit_imp.F
!||--- called by ------------------------------------------------------
!||    dyna_ina           ../engine/source/implicit/imp_dyna.F
!||    dyna_wex           ../engine/source/implicit/imp_dyna.F
!||    imp_chkm           ../engine/source/implicit/imp_solv.F
!||    imp_solv           ../engine/source/implicit/imp_solv.F
!||--- calls      -----------------------------------------------------
!||    finter             ../engine/source/tools/curve/finter.F
!||    finter_smooth      ../engine/source/tools/curve/finter_smooth.F
!||--- uses       -----------------------------------------------------
!||    finter_mixed_mod   ../engine/source/tools/finter_mixed.F90
!||    python_funct_mod   ../common_source/modules/python_mod.F90
!||    sensor_mod         ../common_source/modules/sensor_mod.F90
!||====================================================================
      SUBROUTINE gravit_imp(IGRV  ,AGRV  ,NPC   ,TF    ,A ,
     2                  V     ,X     ,SKEW  ,MS,WFEXTT,
     3                  NSENSOR,SENSOR_TAB,WEIGHT,IB,ITASK,
     4                  NRBYAC,IRBYAC,NPBY  ,RBY   , PYTHON)
C-----------------------------------------------  
C   M o d u l e s
C-----------------------------------------------  
      USE sensor_mod
      USE python_funct_mod
      USE finter_mixed_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
#include      "comlock.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "com01_c.inc"
#include      "com04_c.inc"
#include      "com08_c.inc"
#include      "task_c.inc"
#include      "param_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER ,INTENT(IN) :: NSENSOR
      INTEGER NPC(*)
      INTEGER IGRV(NIGRV,*),IB(*)
      INTEGER WEIGHT(*),ITASK,NRBYAC,IRBYAC(*),NPBY(NNPBY,*)
C     REAL
      my_real
     .   agrv(lfacgrv,*), tf(*), a(3,*), v(3,*), ms(*),
     .   x(3,*), skew(lskew,*), wfextt, rby(nrby,*)
      TYPE (SENSOR_STR_) ,DIMENSION(NSENSOR) ,INTENT(IN) :: SENSOR_TAB
      TYPE(PYTHON_), INTENT(INOUT) :: PYTHON
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NL, N1, ISK, N2, IFUNC, K1, K2, K3, ISENS,K,NN, IAD,J, PROC, IADF, IADL, ISMOOTH
      my_real AXI, A0, AA, VV, DYDX, TS,GAMA, MA
      my_real MS0(NUMNOD)
      my_real finter,finter_smooth
      EXTERNAL finter,finter_smooth
C-----------------------------------------------
      wfextt=zero
      DO nl=1,numnod
       ms0(nl) =  ms(nl)
      ENDDO
      DO nl=1,nrbyac
       k=irbyac(nl)
       nn=npby(1,k)
       ms0(nn) =  rby(15,k)
      ENDDO
 
      DO nl=1,ngrav
        nn=igrv(1,nl)
        isk=igrv(2,nl)/10
        n2=igrv(2,nl)-10*isk
        ifunc=igrv(3,nl)
        iad=igrv(4,nl)
        ismooth = 0
        IF (ifunc > 0) ismooth = npc(2*nfunct+ifunc+1)
C-------only for Itask=0 first-----
        iadf = iad+itask*nn
        iadl = iad-1+(itask+1)*nn
        isens=0
        DO k=1,nsensor
           IF(igrv(6,nl)== sensor_tab(k)%SENS_ID) isens=k
        ENDDO
        IF(isens==0)THEN
            ts=tt
        ELSE
            ts = tt - sensor_tab(isens)%TSTART
            IF(ts<0.0)cycle
        ENDIF
 
        IF (ifunc > 0) THEN
          IF (ismooth <= 0) THEN
            a0   = agrv(1,nl)*finter_mixed(python,nfunct,ifunc,(ts-dt1)*agrv(2,nl),npc,tf)
            gama = agrv(1,nl)*finter_mixed(python,nfunct,ifunc,ts*agrv(2,nl),npc,tf)
          ELSE
            a0   = agrv(1,nl)*finter_smooth(ifunc,(ts-dt1)*agrv(2,nl),npc,tf,dydx)
            gama = agrv(1,nl)*finter_smooth(ifunc,ts*agrv(2,nl),npc,tf,dydx)
          ENDIF
        ELSE
          a0   = agrv(1,nl)
          gama = agrv(1,nl)
        ENDIF
C
        proc = ispmd + 1
        aa = gama
        IF(n2d==1.AND.isk<=1)THEN
!#include "vectorize.inc"
          DO j=iad,iad+nn-1
            n1=iabs(ib(j))
            axi=x(2,n1)
            ma=aa*ms0(n1)
            a(n2,n1)=a(n2,n1)+ma
            IF(ib(j)>0) wfextt=wfextt+half*(a0+aa)*ms(n1)*v(n2,n1)*axi*weight(n1)
          ENDDO
        ELSEIF(n2d==1.AND.isk>1)THEN
          k1=3*n2-2
          k2=3*n2-1
          k3=3*n2
!#include "vectorize.inc"
          DO j=iad,iad+nn-1
            n1=iabs(ib(j))
            axi=x(2,n1)
            vv = skew(k1,isk)*v(1,n1)+skew(k2,isk)*v(2,n1)+skew(k3,isk)*v(3,n1)
            ma=aa*ms0(n1)
            a(1,n1)=a(1,n1)+skew(k1,isk)*ma
            a(2,n1)=a(2,n1)+skew(k2,isk)*ma
            a(3,n1)=a(3,n1)+skew(k3,isk)*ma
            IF(ib(j)>0) wfextt=wfextt+half*(a0+aa)*ms(n1)*vv*axi*weight(n1)
          ENDDO
        ELSEIF(isk<=1)THEN
!#include "vectorize.inc"
          DO j=iad,iad+nn-1
            n1=iabs(ib(j))
            ma=aa*ms0(n1)
            a(n2,n1)=a(n2,n1)+ma
            IF(ib(j)>0) wfextt=wfextt+half*(a0+aa)*ms(n1)*v(n2,n1)*weight(n1)
          ENDDO
        ELSE
          k1=3*n2-2
          k2=3*n2-1
          k3=3*n2
#include "vectorize.inc"
          DO j=iad,iad+nn-1
            n1=iabs(ib(j))
            ma=aa*ms0(n1)
            vv = skew(k1,isk)*v(1,n1)+skew(k2,isk)*v(2,n1)+skew(k3,isk)*v(3,n1)
            a(1,n1)=a(1,n1)+skew(k1,isk)*ma
            a(2,n1)=a(2,n1)+skew(k2,isk)*ma
            a(3,n1)=a(3,n1)+skew(k3,isk)*ma
            IF(ib(j)>0) wfextt=wfextt+half*(a0+aa)*ms(n1)*vv*weight(n1)
          ENDDO
        ENDIF
       ENDDO !next NL
 
      RETURN
      END