Functions
integer function	icamax (n, cx, incx)
	ICAMAX
integer function	idamax (n, dx, incx)
	IDAMAX
integer function	isamax (n, sx, incx)
	ISAMAX
integer function	izamax (n, zx, incx)
	IZAMAX
logical function	lsame (ca, cb)
	LSAME
subroutine	xerbla (srname, info)
	XERBLA
subroutine	xerbla_array (srname_array, srname_len, info)
	XERBLA_ARRAY

Detailed Description

This is the group of Auxiliary 3 BLAS routines.

Function Documentation

◆ icamax()

integer function icamax	(	integer	n,
		complex, dimension(*)	cx,
		integer	incx )

ICAMAX

Purpose:

!>
!>    ICAMAX finds the index of the first element having maximum |Re(.)| + |Im(.)|
!>

Parameters

[in]	N	!> N is INTEGER !> number of elements in input vector(s) !>
[in]	CX	!> CX is COMPLEX array, dimension ( 1 + ( N - 1 )*abs( INCX ) ) !>
[in]	INCX	!> INCX is INTEGER !> storage spacing between elements of CX !>

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Further Details:

!>
!>     jack dongarra, linpack, 3/11/78.
!>     modified 3/93 to return if incx .le. 0.
!>     modified 12/3/93, array(1) declarations changed to array(*)
!>

Definition at line 70 of file icamax.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      COMPLEX CX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      REAL SMAX
      INTEGER I,IX
*     ..
*     .. External Functions ..
      REAL SCABS1
      EXTERNAL scabs1
*     ..
      icamax = 0
      IF (n.LT.1 .OR. incx.LE.0) RETURN
      icamax = 1
      IF (n.EQ.1) RETURN
      IF (incx.EQ.1) THEN
*
*        code for increment equal to 1
*
         smax = scabs1(cx(1))
         DO i = 2,n
            IF (scabs1(cx(i)).GT.smax) THEN
               icamax = i
               smax = scabs1(cx(i))
            END IF
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         ix = 1
         smax = scabs1(cx(1))
         ix = ix + incx
         DO i = 2,n
            IF (scabs1(cx(ix)).GT.smax) THEN
               icamax = i
               smax = scabs1(cx(ix))
            END IF
            ix = ix + incx
         END DO
      END IF
      RETURN
*
*     End of ICAMAX
*

◆ idamax()

integer function idamax	(	integer	n,
		double precision, dimension(*)	dx,
		integer	incx )

IDAMAX

Purpose:

!>
!>    IDAMAX finds the index of the first element having maximum absolute value.
!>

Parameters

[in]	N	!> N is INTEGER !> number of elements in input vector(s) !>
[in]	DX	!> DX is DOUBLE PRECISION array, dimension ( 1 + ( N - 1 )*abs( INCX ) ) !>
[in]	INCX	!> INCX is INTEGER !> storage spacing between elements of DX !>

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Further Details:

!>
!>     jack dongarra, linpack, 3/11/78.
!>     modified 3/93 to return if incx .le. 0.
!>     modified 12/3/93, array(1) declarations changed to array(*)
!>

Definition at line 70 of file idamax.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION DX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      DOUBLE PRECISION DMAX
      INTEGER I,IX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC dabs
*     ..
      idamax = 0
      IF (n.LT.1 .OR. incx.LE.0) RETURN
      idamax = 1
      IF (n.EQ.1) RETURN
      IF (incx.EQ.1) THEN
*
*        code for increment equal to 1
*
         dmax = dabs(dx(1))
         DO i = 2,n
            IF (dabs(dx(i)).GT.dmax) THEN
               idamax = i
               dmax = dabs(dx(i))
            END IF
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         ix = 1
         dmax = dabs(dx(1))
         ix = ix + incx
         DO i = 2,n
            IF (dabs(dx(ix)).GT.dmax) THEN
               idamax = i
               dmax = dabs(dx(ix))
            END IF
            ix = ix + incx
         END DO
      END IF
      RETURN
*
*     End of IDAMAX
*

◆ isamax()

integer function isamax	(	integer	n,
		real, dimension(*)	sx,
		integer	incx )

ISAMAX

Purpose:

!>
!>    ISAMAX finds the index of the first element having maximum absolute value.
!>

Parameters

[in]	N	!> N is INTEGER !> number of elements in input vector(s) !>
[in]	SX	!> SX is REAL array, dimension ( 1 + ( N - 1 )*abs( INCX ) ) !>
[in]	INCX	!> INCX is INTEGER !> storage spacing between elements of SX !>

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Further Details:

!>
!>     jack dongarra, linpack, 3/11/78.
!>     modified 3/93 to return if incx .le. 0.
!>     modified 12/3/93, array(1) declarations changed to array(*)
!>

Definition at line 70 of file isamax.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      REAL SX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      REAL SMAX
      INTEGER I,IX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC abs
*     ..
      isamax = 0
      IF (n.LT.1 .OR. incx.LE.0) RETURN
      isamax = 1
      IF (n.EQ.1) RETURN
      IF (incx.EQ.1) THEN
*
*        code for increment equal to 1
*
         smax = abs(sx(1))
         DO i = 2,n
            IF (abs(sx(i)).GT.smax) THEN
               isamax = i
               smax = abs(sx(i))
            END IF
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         ix = 1
         smax = abs(sx(1))
         ix = ix + incx
         DO i = 2,n
            IF (abs(sx(ix)).GT.smax) THEN
               isamax = i
               smax = abs(sx(ix))
            END IF
            ix = ix + incx
         END DO
      END IF
      RETURN
*
*     End of ISAMAX
*

◆ izamax()

integer function izamax	(	integer	n,
		complex16, dimension()	zx,
		integer	incx )

IZAMAX

Purpose:

!>
!>    IZAMAX finds the index of the first element having maximum |Re(.)| + |Im(.)|
!>

Parameters

[in]	N	!> N is INTEGER !> number of elements in input vector(s) !>
[in]	ZX	!> ZX is COMPLEX16 array, dimension ( 1 + ( N - 1 )abs( INCX ) ) !>
[in]	INCX	!> INCX is INTEGER !> storage spacing between elements of ZX !>

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Further Details:

!>
!>     jack dongarra, 1/15/85.
!>     modified 3/93 to return if incx .le. 0.
!>     modified 12/3/93, array(1) declarations changed to array(*)
!>

Definition at line 70 of file izamax.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      COMPLEX*16 ZX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      DOUBLE PRECISION DMAX
      INTEGER I,IX
*     ..
*     .. External Functions ..
      DOUBLE PRECISION DCABS1
      EXTERNAL dcabs1
*     ..
      izamax = 0
      IF (n.LT.1 .OR. incx.LE.0) RETURN
      izamax = 1
      IF (n.EQ.1) RETURN
      IF (incx.EQ.1) THEN
*
*        code for increment equal to 1
*
         dmax = dcabs1(zx(1))
         DO i = 2,n
            IF (dcabs1(zx(i)).GT.dmax) THEN
               izamax = i
               dmax = dcabs1(zx(i))
            END IF
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         ix = 1
         dmax = dcabs1(zx(1))
         ix = ix + incx
         DO i = 2,n
            IF (dcabs1(zx(ix)).GT.dmax) THEN
               izamax = i
               dmax = dcabs1(zx(ix))
            END IF
            ix = ix + incx
         END DO
      END IF
      RETURN
*
*     End of IZAMAX
*

◆ lsame()

logical function lsame	(	character	ca,
		character	cb )

LSAME

Purpose:

!>
!> LSAME returns .TRUE. if CA is the same letter as CB regardless of
!> case.
!>

Parameters

[in]	CA	!> CA is CHARACTER*1 !>
[in]	CB	!> CB is CHARACTER*1 !> CA and CB specify the single characters to be compared. !>

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Definition at line 52 of file lsame.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER CA,CB
*     ..
*
* =====================================================================
*
*     .. Intrinsic Functions ..
      INTRINSIC ichar
*     ..
*     .. Local Scalars ..
      INTEGER INTA,INTB,ZCODE
*     ..
*
*     Test if the characters are equal
*
      lsame = ca .EQ. cb
      IF (lsame) RETURN
*
*     Now test for equivalence if both characters are alphabetic.
*
      zcode = ichar('Z')
*
*     Use 'Z' rather than 'A' so that ASCII can be detected on Prime
*     machines, on which ICHAR returns a value with bit 8 set.
*     ICHAR('A') on Prime machines returns 193 which is the same as
*     ICHAR('A') on an EBCDIC machine.
*
      inta = ichar(ca)
      intb = ichar(cb)
*
      IF (zcode.EQ.90 .OR. zcode.EQ.122) THEN
*
*        ASCII is assumed - ZCODE is the ASCII code of either lower or
*        upper case 'Z'.
*
          IF (inta.GE.97 .AND. inta.LE.122) inta = inta - 32
          IF (intb.GE.97 .AND. intb.LE.122) intb = intb - 32
*
      ELSE IF (zcode.EQ.233 .OR. zcode.EQ.169) THEN
*
*        EBCDIC is assumed - ZCODE is the EBCDIC code of either lower or
*        upper case 'Z'.
*
          IF (inta.GE.129 .AND. inta.LE.137 .OR.
     +        inta.GE.145 .AND. inta.LE.153 .OR.
     +        inta.GE.162 .AND. inta.LE.169) inta = inta + 64
          IF (intb.GE.129 .AND. intb.LE.137 .OR.
     +        intb.GE.145 .AND. intb.LE.153 .OR.
     +        intb.GE.162 .AND. intb.LE.169) intb = intb + 64
*
      ELSE IF (zcode.EQ.218 .OR. zcode.EQ.250) THEN
*
*        ASCII is assumed, on Prime machines - ZCODE is the ASCII code
*        plus 128 of either lower or upper case 'Z'.
*
          IF (inta.GE.225 .AND. inta.LE.250) inta = inta - 32
          IF (intb.GE.225 .AND. intb.LE.250) intb = intb - 32
      END IF
      lsame = inta .EQ. intb
*
*     RETURN
*
*     End of LSAME
*

◆ xerbla()

subroutine xerbla	(	character()	srname,
		integer	info )

XERBLA

Purpose:

!>
!> XERBLA  is an error handler for the LAPACK routines.
!> It is called by an LAPACK routine if an input parameter has an
!> invalid value.  A message is printed and execution stops.
!>
!> Installers may consider modifying the STOP statement in order to
!> call system-specific exception-handling facilities.
!>

Parameters

[in]	SRNAME	!> SRNAME is CHARACTER() !> The name of the routine which called XERBLA. !>
[in]	INFO	!> INFO is INTEGER !> The position of the invalid parameter in the parameter list !> of the calling routine. !>

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Definition at line 59 of file xerbla.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER*(*)      SRNAME
      INTEGER            INFO
*     ..
*
* =====================================================================
*
*     .. Intrinsic Functions ..
      INTRINSIC          len_trim
*     ..
*     .. Executable Statements ..
*
      WRITE( *, fmt = 9999 )srname( 1:len_trim( srname ) ), info
*
      stop
*
 9999 FORMAT( ' ** On entry to ', a, ' parameter number ', i2, ' had ',
     $      'an illegal value' )
*
*     End of XERBLA
*

◆ xerbla_array()

subroutine xerbla_array	(	character(1), dimension(srname_len)	srname_array,
		integer	srname_len,
		integer	info )

XERBLA_ARRAY

Purpose:

!>
!> XERBLA_ARRAY assists other languages in calling XERBLA, the LAPACK
!> and BLAS error handler.  Rather than taking a Fortran string argument
!> as the function's name, XERBLA_ARRAY takes an array of single
!> characters along with the array's length.  XERBLA_ARRAY then copies
!> up to 32 characters of that array into a Fortran string and passes
!> that to XERBLA.  If called with a non-positive SRNAME_LEN,
!> XERBLA_ARRAY will call XERBLA with a string of all blank characters.
!>
!> Say some macro or other device makes XERBLA_ARRAY available to C99
!> by a name lapack_xerbla and with a common Fortran calling convention.
!> Then a C99 program could invoke XERBLA via:
!>    {
!>      int flen = strlen(__func__);
!>      lapack_xerbla(__func__, &flen, &info);
!>    }
!>
!> Providing XERBLA_ARRAY is not necessary for intercepting LAPACK
!> errors.  XERBLA_ARRAY calls XERBLA.
!>

Parameters

[in]

SRNAME_ARRAY

!>          SRNAME_ARRAY is CHARACTER(1) array, dimension (SRNAME_LEN)
!>          The name of the routine which called XERBLA_ARRAY.
!>

[in]

SRNAME_LEN

!>          SRNAME_LEN is INTEGER
!>          The length of the name in SRNAME_ARRAY.
!>

[in]

INFO

!>          INFO is INTEGER
!>          The position of the invalid parameter in the parameter list
!>          of the calling routine.
!>

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Definition at line 79 of file xerbla_array.f.

*
*  -- Reference BLAS level1 routine --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER SRNAME_LEN, INFO
*     ..
*     .. Array Arguments ..
      CHARACTER(1) SRNAME_ARRAY(SRNAME_LEN)
*     ..
*
* =====================================================================
*
*     ..
*     .. Local Scalars ..
      INTEGER I
*     ..
*     .. Local Arrays ..
      CHARACTER*32 SRNAME
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC min, len
*     ..
*     .. External Functions ..
      EXTERNAL xerbla
*     ..
*     .. Executable Statements ..
      srname = ''
      DO i = 1, min( srname_len, len( srname ) )
         srname( i:i ) = srname_array( i )
      END DO
 
      CALL xerbla( srname, info )
 
      RETURN
*
*     End of XERBLA_ARRAY
*

OpenRadioss 2025.1.11 OpenRadioss project