hm_admlist.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_admlist               ../starter/source/groups/hm_admlist.F
!||--- called by ------------------------------------------------------
!||    hm_lecgre                ../starter/source/groups/hm_lecgre.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.F
!||    hm_get_int_array_index   ../starter/source/devtools/hm_reader/hm_get_int_array_index.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_admlist(NIX     ,IX      ,NUMEL   ,IPARTEL ,IPART   ,
     .                   KELTREE ,ELTREE  ,KSONTREE,NSONTREE,KLEVTREE,
     .                   NLIST   ,MESS    ,IX1     ,IX2     ,INDEX   ,
     .                   KK      ,NEL     ,NELT    ,ELKEY    ,ID      ,
     .                   TITR    ,LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE hm_option_read_mod
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   G l o b a l   P a r a m e t e r s
C-----------------------------------------------
#include      "remesh_c.inc"
#include      "scr17_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NIX, IX(NIX,*), NUMEL, IPARTEL(*), IPART(LIPART1,*),
     .        KELTREE, ELTREE(KELTREE,*), KSONTREE, NSONTREE, KLEVTREE,
     .        NLIST, IX1(*), IX2(*), INDEX(*), KK, NEL, NELT(*)
      CHARACTER MESS*40
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER ELKEY*4
      TYPE(submodel_data) LSUBMODEL(NSUBMOD)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER LIST(NLIST), IL, JJ, NENTITY, II
      INTEGER I, J, NOLD, K, IWORK(70000)
      INTEGER LELT, LELT1, LELT2, NE, KE, IP, LEVEL, NLEV,
     .        LELTMP, NELTMP(NSONTREE**(LEVELMAX+1))
      LOGICAL IS_AVAILABLE, IS_ENCRYPTED
C-----------------------------------------------
C CONSTITUTION DE LIST
C-----------------------------------------------
      il   =0
 
      CALL hm_get_intv  ('idsmax' ,nentity,is_available,lsubmodel)
 
      DO ii=1,nentity
          CALL hm_get_int_array_index ('ids'    ,jj    ,ii,is_available,lsubmodel)
          IF(jj /= 0)THEN
            il = il + 1
            list(il)=jj
          ENDIF
      enddo! NEXT II
      
C-----------------------
C TRI DE LIST EN ORDRE CROISSANT
C AVEC SUPPRESSION DES No DOUBLES
C-----------------------
      CALL my_orders(0,iwork,list,index,nlist,1)
      DO i=1,nlist
        index(nlist+i) = list(index(i))
      ENDDO
      k=1
      nold = index(nlist+1)
      DO i=1,nlist
        IF(nold/=index(nlist+i))k=k+1
        list(k) = index(nlist+i)
        nold    = index(nlist+i)
      ENDDO
      nel=k
C-----------------------
C TRI DE IX EN ORDRE CROISSANT si KK = 0
C-----------------------
      IF(kk==0)THEN
        DO i=1,numel
          ix2(i) = ix(nix,i)
        ENDDO
        CALL my_orders(0,iwork,ix2,index,numel,1)
        DO i=1,numel
          ix1(i) = ix2(index(i))
        ENDDO
        DO i=1,numel
          ix2(i) = index(i)
        ENDDO
      ENDIF
C-----------------------
C RECHERCHE DES ELEMENTS DE LIST() DANS IX()
C  ALGO < NLIST+NUMEL
C-----------------------
      i=1
      j=1
      DO i=1,nel
        DO WHILE(list(i)>ix1(j).AND.j<numel)
          j=j+1
        ENDDO
        IF(list(i)==ix1(j))THEN
          list(i)=ix2(j)
        ELSE
           CALL ancmsg(msgid=70,
     .                 msgtype=msgerror,
     .                 anmode=aninfo,
     .                 c1=elkey,
     .                 i1=id,
     .                 c2=trim(titr),
     .                 i2=list(i))
           RETURN
        ENDIF
      ENDDO
C-----------------------
C
C-----------------------
      lelt = 0
C
      DO i=1,nel
        ne=list(i)
 
        ip=ipartel(ne)
        nlev =ipart(10,ip)
 
        IF(nlev==0)THEN
          lelt=lelt+1
          nelt(lelt)=ne
        ELSE
 
          leltmp   =1
          neltmp(1)=ne
 
          level    =eltree(klevtree,ne)
          IF(level < 0) level=-(level+1)
 
          lelt1=0
          lelt2=leltmp
 
          DO WHILE(level < nlev)
            DO ke=lelt1+1,lelt2
              DO k=0,nsontree-1
                leltmp=leltmp+1
                neltmp(leltmp)=eltree(ksontree,neltmp(ke))+k
              END DO
            END DO
 
            lelt1=lelt2
            lelt2=leltmp
 
            level=level+1
          END DO
           
          DO ke=lelt1+1,lelt2
            lelt=lelt+1
            nelt(lelt)=neltmp(ke)
          END DO
 
        END IF
      END DO
C
      nel=lelt
C-----------------------
      RETURN
      END