hm_get_float_array_2indexes.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_get_float_array_2indexes   ../starter/source/devtools/hm_reader/hm_get_float_array_2indexes.F
!||--- called by ------------------------------------------------------
!||    hm_read_drape                 ../starter/source/properties/composite_options/drape/hm_read_drape.F
!||    hm_read_prop17                ../starter/source/properties/shell/hm_read_prop17.F
!||    hm_read_prop51                ../starter/source/properties/shell/hm_read_prop51.F
!||    hm_read_stack                 ../starter/source/stack/hm_read_stack.F
!||--- calls      -----------------------------------------------------
!||--- uses       -----------------------------------------------------
!||    message_mod                   ../starter/share/message_module/message_mod.F
!||    submodel_mod                  ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_get_float_array_2indexes(NAME,RVAL,INDEX1,INDEX2,IS_AVAILABLE,LSUBMODEL,UNITAB)
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   REQUEST DATA INTO MODEL NEUTRAL OBJECT DATABASE USING HM_READER
C   PICK VALUE IN A LIST OF VALUES
C   ASK (INDEX1_TH,INDEX2)_TH (REAL) VALUE OF 'NAME' FIELD DEFINED IN .cfg FILE 
C   APPLY AUTOMATICALLY UNIT SYSTEM USING DIMENSION DEFINED IN .cfg FILE
C-----------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME         DESCRIPTION              
C
C     NAME         FIELD NAME         
C     RVAL         REAL VALUE OF THE FIELD 
C     INDEX1       INDEX NUMBER OF THE VALUE (ROW)
C     INDEX2       INDEX NUMBER OF THE VALUE (COLUMN)
C     IS_AVAILABLE VALUE AVAILABLE IN MODEL OR NOT
C     LSUBMODEL    SUBMODEL STRUCTURE       
C     UNITAB       UNIT ARRAY       
C============================================================================
C   M o d u l e s
C-----------------------------------------------
      use, INTRINSIC :: iso_c_binding, only: c_bool 
      USE message_mod       
      USE submodel_mod
      USE unitab_mod
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C----------------------------------------------- 
C INPUT ARGUMENTS
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER,INTENT(IN)::INDEX1,INDEX2
      CHARACTER*(*),INTENT(IN)::NAME
      TYPE(submodel_data),INTENT(IN)::LSUBMODEL(*)
C OUTPUT ARGUMENTS
      my_real,
     .  INTENT(OUT)::rval
      LOGICAL,INTENT(OUT)::IS_AVAILABLE
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: I,J,VALUE_TYPE,SUB_ID,IFLAGUNIT,UID
      my_real :: fac_l,fac_m,fac_t,fac
      real*8 dval,length_dim,mass_dim,time_dim
      LOGICAL(KIND=C_BOOL) C_IS_AVAILABLE
C-----------------------------------------------
        c_is_available = .false.
        length_dim = zero
        mass_dim = zero
        time_dim = zero
        fac = one
C--------------------------------------------------
        CALL cpp_get_floatv_2index(name(1:len_trim(name)),len_trim(name),dval,index1,c_is_available,
     .                    length_dim,mass_dim,time_dim,uid,sub_id,index2)
        is_available = c_is_available
C--------------------------------------------------
C      ID OFFSETS FOR //SUBMODEL 
C--------------------------------------------------
        IF(sub_id /= 0 .AND. uid == 0)THEN
          IF(lsubmodel(sub_id)%UID /= 0)THEN
            uid = lsubmodel(sub_id)%UID
          ENDIF
        ENDIF
C--------------------------------------------------
c      APPLY UNIT SYSTEM
C--------------------------------------------------
        iflagunit = 0 
        fac_m = zero
        fac_l = zero
        fac_t = zero  
        DO j=1,unitab%NUNITS                         
          IF (unitab%UNIT_ID(j) == uid) THEN    
            fac_m = unitab%FAC_M(j)
            fac_l = unitab%FAC_L(j)
            fac_t = unitab%FAC_T(j)
            iflagunit = 1                      
            EXIT                              
          ENDIF        
        ENDDO
        IF (fac_m  /= zero) fac = fac * (fac_m ** mass_dim  )
        IF (fac_l  /= zero) fac = fac * (fac_l ** length_dim)
        IF (fac_t  /= zero) fac = fac * (fac_t ** time_dim  )     
C-------------------------------------------------- 
        rval  = dval *  fac
C--------------------------------------------------                             
      RETURN
C
      END