hm_read_cyljoint.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_cyljoint       ../starter/source/constraints/general/cyl_joint/hm_read_cyljoint.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    anodset                ../starter/source/output/analyse/analyse_node.c
!||    fretitl                ../starter/source/starter/freform.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    hm_sz_r2r              ../starter/source/coupling/rad2rad/routines_r2r.F
!||    ifrontplus             ../starter/source/spmd/node/frontplus.F
!||    kinset                 ../starter/source/constraints/general/kinset.F
!||    nodgrnr5               ../starter/source/starter/freform.F
!||    udouble                ../starter/source/system/sysfus.F
!||    usr2sys                ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    joint_mod              ../starter/share/modules1/joint_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    r2r_mod                ../starter/share/modules1/r2r_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_cyljoint(LJOINT ,ITABM1,IKINE  ,ITAB   ,IGRNOD,
     .                            NOM_OPT,LSUBMODEL)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE r2r_mod     
      USE message_mod
      USE groupdef_mod
      USE submodel_mod
      USE hm_option_read_mod 
      USE joint_mod
      USE names_and_titles_mod , ONLY : nchartitle
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   A n a l y s e   M o d u l e
C-----------------------------------------------
#include      "analyse_name.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr17_c.inc"
#include      "units_c.inc"
#include      "com04_c.inc"
#include      "r2r_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER LJOINT(*), ITABM1(*), IKINE(*), ITAB(*)
      INTEGER NOM_OPT(LNOPT1,*)
C-----------------------------------------------
      TYPE (GROUP_)  ,DIMENSION(NGRNOD)   :: IGRNOD
      TYPE(submodel_data) LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER :: K, I, NS, J, LJ, NU, IDIR,ID,N1,N2,IGU,IKINE1(3*NUMNOD),UID,NY,SUB_ID,IGS
      my_real :: bid
      CHARACTER MESS*40
      CHARACTER(LEN=NCHARTITLE) :: TITR
      LOGICAL :: IS_AVAILABLE
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER USR2SYS,NODGRNR5
      EXTERNAL usr2sys,nodgrnr5
C
      DATA mess/'CYLINDRICAL JOINTS DEFINITION           '/
C=======================================================================
C
      is_available = .false.
C
      k=1
      ny = 0
C
      DO i=1,3*numnod
        ikine1(i) = 0
      ENDDO
C      
      CALL hm_option_start('/CYL_JOINT')
C
      DO i=1,njoint
        ny=ny+1
C----------Multidomaines --> on ignore les cyljoint non tags----------
        IF(nsubdom>0)THEN
                  IF(tagcyl(ny)==0)CALL hm_sz_r2r(tagcyl,ny,lsubmodel)
        END IF
C----------------------------------------------------------------------
        CALL hm_option_read_key(lsubmodel,
     .                       option_id = id,
     .                       unit_id = uid,
     .                       submodel_id = sub_id,
     .                       option_titr = titr)
C
        nom_opt(1,i)=id 
        CALL fretitl(titr,nom_opt(lnopt1-ltitr+1,i),ltitr)       
C
        CALL hm_get_intv('independentnode',n1,is_available,lsubmodel)
        CALL hm_get_intv('dependentnodes',n2,is_available,lsubmodel)
        CALL hm_get_intv('dependentnodeset',igu,is_available,lsubmodel)
C                                           
        ns=2+nodgrnr5(igu,igs,ljoint(k+3),igrnod,itabm1,mess)  
C
        ljoint(k+1)=usr2sys(n1,itabm1,mess,id)                            
        ljoint(k+2)=usr2sys(n2,itabm1,mess,id)                  
        CALL anodset(ljoint(k+1), check_used)                          
        CALL anodset(ljoint(k+2), check_used)                         
        ljoint(k)=ns                                                   
        WRITE (iout,1000) id,ns                                        
        WRITE (iout,1100) (itab(ljoint(k+j)),j=1,ns)                   
 
        !   allocation of cyl_joint%secondary_node : ns = secondary node + main node
        ALLOCATE( cyl_join(i)%SECONDARY_NODE(ns) )
        DO lj=1,ns
            nu = itab(ljoint(k+lj))
            cyl_join(i)%SECONDARY_NODE(lj) = ljoint(k+lj)
                  IF(joint_sms) CALL ifrontplus(ljoint(k+lj),1)
            !   ----------------------
            DO idir=1,6
                CALL kinset(64,nu,ikine(ljoint(k+lj)),idir,0
     .                        ,ikine1(ljoint(k+lj)))
            ENDDO
            !   ----------------------
        ENDDO
        ! save the number of secondary nodes 
        cyl_join(i)%NB_SECONDARY_NODE = ns
        ! save the main nodes 
        ALLOCATE( cyl_join(i)%MAIN_NODE(2) )
        cyl_join(i)%MAIN_NODE(1:2) = ljoint(k+1:k+2)
        k=k+ns+1
 
      ENDDO
C-------------------------------------
C Recherche des ID doubles
C-------------------------------------
      CALL udouble(nom_opt,lnopt1,njoint,mess,0,bid)
C
 
 1000 FORMAT(/' CYLINDRICAL JOINT ',i10,       /
     +          ,' -------------------'/
     + '        ',i8,' NODES:')
 
 1100 FORMAT(7x,10i10)
      RETURN
      END