hm_read_fail_user.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_fail_user      ../starter/source/materials/fail/failuser/hm_read_fail_user.f
!||--- called by ------------------------------------------------------
!||    hm_read_fail           ../starter/source/materials/fail/hm_read_fail.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    arret                  ../starter/source/system/arret.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_get_string_index    ../starter/source/devtools/hm_reader/hm_get_string_index.F
!||    user_output            ../starter/source/user_interface/user_output.f
!||--- uses       -----------------------------------------------------
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_fail_user(FAIL   ,IRUPT,IUSER_KEY,USERL_AVAIL,
     .                             LSUBMODEL,UNITAB_SUB,MAT_ID)
C-----------------------------------------------
C   ROUTINE DESCRIPTION :
C   ===================
C   Read user material failure - generic routine
C------------------------------------------------------------------
C   DUMMY ARGUMENTS DESCRIPTION:
C   ===================
C
C     NAME          DESCRIPTION                         
C
C     USERL_AVAIL   Flag if userlibrary was load
C     IS_AVAILABLE  Bool / Result of HM_interface
C     LSUBMODEL     SUBMODEL Structure.
C------------------------------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE fail_param_mod
      USE message_mod
      USE submodel_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharline
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "scr15_c.inc"
#include      "units_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER IRUPT,MAT_ID
      INTEGER USERL_AVAIL
      TYPE(submodel_data),INTENT(IN)  :: LSUBMODEL(*)
      my_real, DIMENSION(4)           :: unitab_sub
      CHARACTER(LEN=NCHARLINE) :: IUSER_KEY
      TYPE (FAIL_PARAM_)  ,INTENT(INOUT) :: FAIL
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER NUPARAM,NUVAR,NFUNC
      INTEGER, PARAMETER :: MAXFUNC  = 100
      INTEGER, PARAMETER :: MAXPARAM = 1000
      INTEGER, DIMENSION(MAXFUNC)  :: IFUNC
      my_real, DIMENSION(MAXPARAM) :: uparam
      CHARACTER(LEN=4096) :: SCR_FILE_NAME
      CHARACTER(LEN=ncharline) :: RLINE
      CHARACTER (LEN=4) :: CRUP
      CHARACTER(LEN=nchartitle) :: TITLE
      LOGICAL :: IS_AVAILABLE
      INTEGER NLINES,J
      INTEGER SCR_FILE_NAME_LEN
!
      CHARACTER OPTION*256
      INTEGER SIZE
C-----------------------------------------------
      IF (userl_avail == 0)THEN
      ! ERROR to be printed & exit
        option='/FAIL/'//iuser_key
        size=len_trim(option)
        CALL ancmsg(msgid=1130,
     .              msgtype=msgerror,c1=option(1:size),anmode=aninfo)
        CALL arret(2)
      ENDIF
 
      CALL hm_get_intv ('Number_of_datalines' ,nlines ,is_available, lsubmodel)
 
      IF(nlines > 0)THEN 
 
        ! Create tempo file  
        WRITE(crup,'(I4.4)')irupt
        scr_file_name='SI'//rootnam(1:rootlen)//'_'//crup//'.scr'
        scr_file_name_len=len_trim(scr_file_name)
        OPEN(unit=30,file=trim(scr_file_name),form='FORMATTED',recl=ncharline)
 
        ! Read & Dump in scratch file
        DO j=1,nlines   
         CALL hm_get_string_index('arraydatalines', rline, j, ncharline, is_available)
         WRITE(30,fmt='(A)')trim(rline)
        ENDDO
        CLOSE(unit=30)
!
        CALL st_userlib_lecr(irupt,rootnam,rootlen,uparam,maxparam,nuparam,
     .                       nuvar ,ifunc,maxfunc,nfunc,unitab_sub,
     .                       mat_id)
c
        fail%KEYWORD = 'USER FAILURE MODEL' 
        fail%IRUPT   = irupt 
        fail%FAIL_ID = 0 
        fail%NUPARAM = nuparam
        fail%NIPARAM = 0
        fail%NUVAR   = nuvar
        fail%NFUNC   = nfunc
        fail%NTABLE  = 0
        fail%NMOD    = 0
c            
        ALLOCATE (fail%UPARAM(fail%NUPARAM))
        ALLOCATE (fail%IPARAM(fail%NIPARAM))
        ALLOCATE (fail%IFUNC (fail%NFUNC))
        ALLOCATE (fail%TABLE (fail%NTABLE))
c
        fail%UPARAM(1:nuparam) = uparam(1:nuparam)
        fail%IFUNC (1:nfunc)   = ifunc(1:nfunc)
c
        CALL user_output(iout,irupt,rootnam,rootlen,1)
      ELSE
         ! Error MESSAGE_Mess
      ENDIF
!---------
      RETURN
      END