hm_read_prop03.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_prop03           ../starter/source/properties/beam/hm_read_prop03.F
!||--- called by ------------------------------------------------------
!||    hm_read_properties       ../starter/source/properties/hm_read_properties.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                   ../starter/source/output/message/message.f
!||    hm_get_floatv            ../starter/source/devtools/hm_reader/hm_get_floatv.F
!||    hm_get_intv              ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_is_encrypted   ../starter/source/devtools/hm_reader/hm_option_is_encrypted.F
!||--- uses       -----------------------------------------------------
!||    elbuftag_mod             ../starter/share/modules1/elbuftag_mod.F
!||    hm_option_read_mod       ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod              ../starter/share/message_module/message_mod.F
!||    submodel_mod             ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_prop03(GEO       ,IGEO     ,PROP_TAG ,IGTYP    ,IG        ,
     .                          IDTITL    ,UNITAB   ,LSUBMODEL)
C============================================================================
C   M o d u l e s
C-----------------------------------------------
      USE unitab_mod
      USE elbuftag_mod  
      USE message_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharfield
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "com01_c.inc"
#include      "tablen_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      TYPE (UNIT_TYPE_),INTENT(IN) ::UNITAB 
      INTEGER IGEO(*)
      INTEGER IGTYP,IG
      my_real
     .   geo(*)
      CHARACTER(LEN=NCHARTITLE)::IDTITL
      TYPE(prop_tag_) , DIMENSION(0:MAXPROP) :: PROP_TAG
      TYPE(submodel_data),INTENT(IN)::LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER ISMSTR,ISHEAR,IHBE,
     .   ihbe_old, 
     .   ir1x, ir1y, ir1z, ir2x, ir2y, ir2z,irx 
      my_real
     .    pun,cvis
      CHARACTER(LEN=NCHARFIELD) :: STRING
      CHARACTER CHROT*7
      LOGICAL IS_AVAILABLE, IS_ENCRYPTED
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      DATA pun/0.1/
C=======================================================================
C
        is_encrypted = .false.
        is_available = .false.
C--------------------------------------------------
C OLD HIDDEN FLAGS - SET TO ZERO
C--------------------------------------------------
        ihbe=0
        ismstr=0
        cvis=0
C--------------------------------------------------
C EXTRACT DATA (IS OPTION CRYPTED)
C--------------------------------------------------
        CALL hm_option_is_encrypted(is_encrypted)
C--------------------------------------------------
C EXTRACT DATAS (INTEGER VALUES)
C--------------------------------------------------
        CALL hm_get_intv('Ismstr',ismstr,is_available,lsubmodel)
        CALL hm_get_intv('Translation_Wx1',ir1x,is_available,lsubmodel)
        CALL hm_get_intv('Translation_Wy1',ir1y,is_available,lsubmodel)
        CALL hm_get_intv('Translation_Wz1',ir1z,is_available,lsubmodel)
        CALL hm_get_intv('Translation_Wx2',ir2x,is_available,lsubmodel)
        CALL hm_get_intv('Translation_Wy2',ir2y,is_available,lsubmodel)
        CALL hm_get_intv('Translation_Wz2',ir2z,is_available,lsubmodel)
        CALL hm_get_intv('ISHEAR',ishear,is_available,lsubmodel)
C--------------------------------------------------
C EXTRACT DATAS (REAL VALUES)
C--------------------------------------------------
        CALL hm_get_floatv('MAT_Dm',geo(16),is_available,lsubmodel,unitab)
        CALL hm_get_floatv('MAT_Df',geo(17),is_available,lsubmodel,unitab)
        CALL hm_get_floatv('AREA',geo(1),is_available,lsubmodel,unitab)
        CALL hm_get_floatv('IYY',geo(2),is_available,lsubmodel,unitab)
        CALL hm_get_floatv('IZZ',geo(18),is_available,lsubmodel,unitab)
        CALL hm_get_floatv('IXX',geo(4),is_available,lsubmodel,unitab)
C----------------------
C
C----------------------
        IF(n2d>0.AND.ihbe/=0.AND.ihbe/=2)THEN
          ihbe_old=ihbe
          ihbe=0
          CALL ancmsg(msgid=321,
     .                msgtype=msgwarning,
     .                anmode=aninfo_blind_2,
     .                i1=ig,
     .                c1=idtitl,
     .                i2=ihbe_old,
     .                i3=ihbe)
        ENDIF
C
        geo(3)=ismstr
        IF ((ismstr==3).OR.(ismstr==1)) geo(5)=ep06
C  double stockage temporaire - supprimer GEO(12)=IGTYP apres tests
        igeo( 1)=ig
        igeo(10)=ihbe
        igeo(11)=igtyp
        geo(12) =igtyp+pun
        geo(171)=ihbe
C
C----------------------
C
        IF(ismstr==2.OR.ismstr==4)THEN
          ismstr=0
        ELSEIF(ismstr==1.OR.ismstr==3)THEN
          ismstr=1
        ENDIF
        IF(geo(17)==zero) geo(17)=em02
C
        irx=min(1,ir1x+ir2x)
        geo(7)= 1.1-irx
        geo(8)= 1.1-ir1y
        geo(9)= 1.1-ir1z
        geo(10)=1.1-ir2y
        geo(11)=1.1-ir2z
        IF(ishear/=0) THEN
          geo(37)=one
        ELSE
          geo(37)=zero
        ENDIF
C
        IF (geo(1)<=zero) THEN
          CALL ancmsg(msgid=314,
     .                   msgtype=msgerror,
     .                   anmode=aninfo_blind_1,
     .                   i1=ig,
     .                   c1=idtitl,
     .                   r1=geo(1))
        ENDIF
        IF (geo(2)<=zero) THEN
          CALL ancmsg(msgid=315,
     .                   msgtype=msgerror,
     .                   anmode=aninfo_blind_1,
     .                   i1=ig,
     .                   c1=idtitl,
     .                   r1=geo(2))
        ENDIF
        IF (geo(18)<=zero) THEN
           CALL ancmsg(msgid=316,
     .                   msgtype=msgerror,
     .                   anmode=aninfo_blind_1,
     .                   i1=ig,
     .                   c1=idtitl,
     .                   r1=geo(18))
        ENDIF
        IF (geo(4)<=zero) THEN
           CALL ancmsg(msgid=317,
     .                   msgtype=msgerror,
     .                   anmode=aninfo_blind_1,
     .                   i1=ig,
     .                   c1=idtitl,
     .                   r1=geo(4))
        ENDIF
        IF(.NOT. is_encrypted)THEN
          WRITE(iout,1300)ig,geo(1),geo(2),geo(18),geo(4),
     .                    ir1x,ir1y,ir1z,ir2x,ir2y,ir2z,ishear,
     .                    geo(16),geo(17)
        ELSE
          WRITE(iout,1399)ig
        ENDIF
        geo(3)=ismstr
C
        ishear = geo(37)
        IF(ishear==0)THEN
          geo(37)=0
        ELSEIF(ishear==1)THEN
          geo(37)=1
        ELSEIF(ishear==2)THEN
          geo(37)=0
        ENDIF
        IF(geo(3)/=zero.AND.igeo(5)== 0) igeo(5)=nint(geo(3))
        IF(geo(171)/=zero.AND.igeo(10)== 0) igeo(10)=nint(geo(171))
C
C-----------------------------
C       PROPERTY BUFFER 
C-----------------------------
C
        prop_tag(igtyp)%G_FOR = 3
        prop_tag(igtyp)%G_MOM = 3
        prop_tag(igtyp)%G_EINT = 2
        prop_tag(igtyp)%G_LENGTH = 1 ! total length
        prop_tag(igtyp)%G_SKEW = 3  ! local skew (RLOC)
        prop_tag(igtyp)%L_STRA = 3
C
C------------------------------
C----
      RETURN
C-----------
 1300 FORMAT(
     & 5x,'BEAM PROPERTY SET'/,
     & 5x,'PROPERTY SET NUMBER . . . . . . . . . .=',i10/,
     & 5x,'BEAM AREA . . . . . . . . . . . . . . .=',1pg20.13/,
     & 5x,'MOMENT OF INERTIA IYY . . . . . . . . .=',1pg20.13/,
     & 5x,'MOMENT OF INERTIA IZZ . . . . . . . . .=',1pg20.13/,
     & 5x,'MOMENT OF INERTIA IXX . . . . . . . . .=',1pg20.13/,
     & 5x,'NODE 1 LOCAL ROTATION RELEASE X DIR.. .=',i10/,
     & 5x,'NODE 1 LOCAL ROTATION RELEASE Y DIR.. .=',i10/,
     & 5x,'NODE 1 LOCAL ROTATION RELEASE Z DIR.. .=',i10/,
     & 5x,'NODE 2 LOCAL ROTATION RELEASE X DIR.. .=',i10/,
     & 5x,'NODE 2 LOCAL ROTATION RELEASE Y DIR.. .=',i10/,
     & 5x,'NODE 2 LOCAL ROTATION RELEASE Z DIR.. .=',i10/,
     & 5x,'SHEAR FORMULATION (0=YES/1=NO). . . . .=',i10/,
     & 5x,'BEAM STRUCTURAL MEMBRANE DAMPING. . . .=',1pg20.13/,
     & 5x,'BEAM STRUCTURAL FLEXURAL DAMPING. . . .=',1pg20.13/)
 1399 FORMAT(
     & 5x,'BEAM PROPERTY SET'/,
     & 5x,'PROPERTY SET NUMBER . . . . . . . . . .=',i10/,
     & 5x,'CONFIDENTIAL DATA'//)
c
      END