hm_read_rbody_lagmul.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
!||====================================================================
!||    hm_read_rbody_lagmul   ../starter/source/constraints/general/rbody/hm_read_rbody_lagmul.F
!||--- called by ------------------------------------------------------
!||    lectur                 ../starter/source/starter/lectur.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||    anodset                ../starter/source/output/analyse/analyse_node.c
!||    fretitl                ../starter/source/starter/freform.F
!||    hm_get_intv            ../starter/source/devtools/hm_reader/hm_get_intv.F
!||    hm_option_read_key     ../starter/source/devtools/hm_reader/hm_option_read_key.F
!||    hm_option_start        ../starter/source/devtools/hm_reader/hm_option_start.F
!||    hm_sz_r2r              ../starter/source/coupling/rad2rad/routines_r2r.f
!||    kinset                 ../starter/source/constraints/general/kinset.F
!||    nodgrnr6               ../starter/source/starter/freform.F
!||    usr2sys                ../starter/source/system/sysfus.F
!||--- uses       -----------------------------------------------------
!||    hm_option_read_mod     ../starter/share/modules1/hm_option_read_mod.F
!||    message_mod            ../starter/share/message_module/message_mod.F
!||    r2r_mod                ../starter/share/modules1/r2r_mod.F
!||    submodel_mod           ../starter/share/modules1/submodel_mod.F
!||====================================================================
      SUBROUTINE hm_read_rbody_lagmul(RBYL    ,NPBYL   ,LPBYL   ,IGRNOD   ,LSUBMODEL ,
     .                                ITAB    ,ITABM1  ,IKINE   ,IKINE1LAG,NOM_OPT)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE groupdef_mod
      USE message_mod
      USE r2r_mod
      USE submodel_mod
      USE hm_option_read_mod
      USE names_and_titles_mod , ONLY : nchartitle, ncharkey
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   A n a l y s e   M o d u l e
C-----------------------------------------------
#include      "analyse_name.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "param_c.inc"
#include      "lagmult.inc"
#include      "scr17_c.inc"
#include      "com04_c.inc"
#include      "r2r_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER NPBYL(NNPBY,*),LPBYL(*), 
     .        itab(*), itabm1(*),ikine(*),ikine1lag(*)
      my_real rbyl(nrby,*)
      INTEGER NOM_OPT(LNOPT1,*)
C-----------------------------------------------
      TYPE (GROUP_)  , DIMENSION(NGRNOD)  :: IGRNOD
      TYPE(submodel_data),INTENT(IN)::LSUBMODEL(*)
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER J,K,NR,MM,ID,IGU,IGS,
     .        nsl,msl,sub_index,nrb,nrb_r2r
      CHARACTER MESS*40
      CHARACTER(LEN=NCHARTITLE) :: TITR
      CHARACTER(LEN=NCHARKEY) :: KEY
      LOGICAL IS_AVAILABLE
      DATA mess/'RIGID BODY DEFINITIONS'/
C-----------------------------------------------
C   E x t e r n a l   F u n c t i o n s
C-----------------------------------------------
      INTEGER  USR2SYS,NODGRNR6
      EXTERNAL usr2sys,nodgrnr6
C-----------------------------------
C   NPBYL(1,N) = MAIN NODE
C   NPBYL(2,N) = NUMBER OF SECONDARY NODES + MAIN
C   NPBYL(3,N) = 
C   NPBYL(4,N) = 
C   NPBYL(5,N) = 
C   NPBYL(6,N) = IDENTIFICATEUR
C   NPBYL(7,N) = 
C   NPBYL(8,N) = 
C======================================================================|
      WRITE(iout,1000)
C---
      is_available = .false.
      CALL hm_option_start('/RBODY')
C---
      k   = 0
      nrb = 0
      nrb_r2r = 0
C
      DO nr=1,nrbody
C
C--------------------------------------------------
C EXTRACT DATAS OF /RBODY/... LINE
C--------------------------------------------------
C
       nrb_r2r = nrb_r2r + 1     
       IF (nsubdom > 0) THEN
         IF(tagrby(nrb_r2r) == 0) CALL hm_sz_r2r(tagrby,nrb_r2r,lsubmodel)
       ENDIF
C
       key=''
       CALL hm_option_read_key(lsubmodel,
     .                       option_id = id,
     .                       option_titr = titr,
     .                       keyword2 = key,
     .                       submodel_index = sub_index)
       IF(key(1:6)=='LAGMUL')THEN     
        nrb = nrb + 1
        IF (nsubdom > 0) THEN ! TAGRBY is allocated only if NSUBDOM>0
          IF(tagrby(nrb) == 0) CALL hm_sz_r2r(tagrby,nrb,lsubmodel)
        ENDIF
C---
        nom_opt(1,nrb)=id
        CALL fretitl(titr,nom_opt(lnopt1-ltitr+1,nrb),ltitr)
C---
        CALL hm_get_intv('node_ID',mm,is_available,lsubmodel)
        mm  = usr2sys(mm,itabm1,mess,id)
C---
        CALL hm_get_intv('grnd_ID',igu,is_available,lsubmodel)
        nsl = nodgrnr6(mm,igu,igs,lpbyl(k+1),igrnod,itabm1,mess,id)
        msl = nsl+1
C---
        lpbyl(k+msl) = mm
C---
        IF (nsl == 0) THEN
          CALL ancmsg(msgid=352,
     .                msgtype=msgwarning,
     .                anmode=aninfo_blind_2,
     .                i1=id,
     .                c1=titr)
        ENDIF
        CALL anodset(mm, check_rb_m)
        DO j=1, nsl
          CALL anodset(lpbyl(j+k), check_rb_s)
        ENDDO
C---
        DO j=1,msl
          CALL kinset(512,itab(lpbyl(j+k)),ikine(lpbyl(j+k)),7,0,
     .                ikine1lag(lpbyl(j+k)))
        ENDDO
C---
        npbyl(1,nrb) = mm
        npbyl(2,nrb) = msl
        npbyl(6,nrb) = id
        lag_ncl = lag_ncl + nsl*6
        lag_nkl = lag_nkl + nsl*21
C---
        WRITE(iout,1100)id,trim(titr),itab(mm),msl
        WRITE(iout,1101)
        WRITE(iout,1102) (itab(lpbyl(j+k)),j=1,nsl)
        k = k + 3*msl
       END IF ! IF(KEY(1:6)=='LAGMUL')THEN  
      ENDDO
C---
      RETURN
C------------------------------
1000  FORMAT(
     . /'      RIGID BODY DEFINITIONS (LAGRANGE MULTIPLIERS)'
     . /'      -------------------------------------------- '/)
1100  FORMAT( /5x,'RIGID BODY ID ',i10,1x,a,
     .       /10x,'PRIMARY NODE                            ',i10
     .       /10x,'NUMBER OF NODES                         ',i10)
1101  FORMAT( 10x,'SECONDARY NODES ')
1102  FORMAT(  9x,10i10)
      END