i1tid2.F

Go to the documentation of this file.

Copyright>        OpenRadioss
Copyright>        Copyright (C) 1986-2025 Altair Engineering Inc.
Copyright>
Copyright>        This program is free software: you can redistribute it and/or modify
Copyright>        it under the terms of the GNU Affero General Public License as published by
Copyright>        the Free Software Foundation, either version 3 of the License, or
Copyright>        (at your option) any later version.
Copyright>
Copyright>        This program is distributed in the hope that it will be useful,
Copyright>        but WITHOUT ANY WARRANTY; without even the implied warranty of
Copyright>        MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
Copyright>        GNU Affero General Public License for more details.
Copyright>
Copyright>        You should have received a copy of the GNU Affero General Public License
Copyright>        along with this program.  If not, see <https://www.gnu.org/licenses/>.
Copyright>
Copyright>
Copyright>        Commercial Alternative: Altair Radioss Software
Copyright>
Copyright>        As an alternative to this open-source version, Altair also offers Altair Radioss
Copyright>        software under a commercial license.  Contact Altair to discuss further if the
Copyright>        commercial version may interest you: https://www.altair.com/radioss/.
C
!||====================================================================
!||    i1tid2                 ../starter/source/interfaces/inter2d1/i1tid2.F
!||--- called by ------------------------------------------------------
!||    inint2                 ../starter/source/interfaces/inter2d1/inint2.F
!||--- calls      -----------------------------------------------------
!||    ancmsg                 ../starter/source/output/message/message.F
!||--- uses       -----------------------------------------------------
!||    format_mod             ../starter/share/modules1/format_mod.F90
!||    message_mod            ../starter/share/message_module/message_mod.F
!||====================================================================
      SUBROUTINE i1tid2(X,IRECT,CRST,MSR,NSV,ILOC,IRTL,NSN,ITAB,ID,TITR,NUMNOD)
C-----------------------------------------------
C   M o d u l e s
C-----------------------------------------------
      USE message_mod
      USE names_and_titles_mod , ONLY : nchartitle
      USE format_mod , ONLY : fmw_5i_f
C-----------------------------------------------
C   I m p l i c i t   T y p e s
C-----------------------------------------------
#include      "implicit_f.inc"
C-----------------------------------------------
C   C o m m o n   B l o c k s
C-----------------------------------------------
#include      "units_c.inc"
#include      "scr03_c.inc"
C-----------------------------------------------
C   D u m m y   A r g u m e n t s
C-----------------------------------------------
      INTEGER,INTENT(IN) :: NUMNOD
      INTEGER NSN
      INTEGER IRECT(4,*), MSR(*), NSV(*), ILOC(*), IRTL(*), ITAB(NUMNOD)
      my_real x(3,numnod), crst(2,*)
      INTEGER ID
      CHARACTER(LEN=NCHARTITLE) :: TITR
C-----------------------------------------------
C   L o c a l   V a r i a b l e s
C-----------------------------------------------
      INTEGER IER1, II, I, J, K, L, M, JJ, IER2
      my_real  n2, n3, ys, zs, t2, t3, xl, ss,ym1,ym2,zm1,zm2
C-----------------------------------------------
C   S o u r c e   L i n e s
C-----------------------------------------------
      ier1=0
      DO ii=1,nsn
        i=nsv(ii)
        j=iloc(ii) ! nearest lag node (main) from secnd node (ale)
        k=msr(j)
        l=irtl(ii)
        m=msr(irect(1,l))
        ym1=x(2,m)
        zm1=x(3,m)
        m=msr(irect(2,l))
        ym2=x(2,m)
        zm2=x(3,m)
        ys =x(2,i)
        zs =x(3,i)
        t2=ym2-ym1
        t3=zm2-zm1
        xl=sqrt(t2**2+t3**2)
        IF(xl == zero)THEN
          CALL ancmsg(msgid=80,msgtype=msgerror,anmode=aninfo,i1=id,c1=titr,i2=l,i3=itab(msr(irect(1,l))),i4=itab(msr(irect(2,l))))
        ENDIF
        t2=t2/xl
        t3=t3/xl
        n2= t3
        n3=-t2
        ss=t2*(ys-ym1)+t3*(zs-zm1)
        ss=ss/xl
        ss=two*ss-one
        crst(1,ii)=ss
        crst(2,ii)=-one
        ier2=0
         IF(ss> onep05 .OR. ss<-onep05)THEN
         ier1=ier1+1
         ier2=1
        ENDIF
        IF(ipri>=1 .OR. ier2>0)THEN
         WRITE(iout,fmt=fmw_5i_f)itab(i), itab(k), l, itab(msr(irect(1,l))), itab(msr(irect(2,l))), ss
        ENDIF
      ENDDO !next II
 
      IF(ier1 > 0)THEN
        ! ** ERROR TIED INTERFACE: SECND NODE OUTSIDE main SEGMENT
        CALL ancmsg(msgid=81,msgtype=msgerror,anmode=aninfo,i1=id,c1=titr)
      ENDIF
C-----------------------------------------------
      RETURN
 
      END